<!--
This stylesheet is used to convert an Teamcenter classification structure to NX Routing
Part Library View file (.plv) and related Part Table Files (.ptb)
It requires an xml file, previously export from Teamcenter via the icsxml 2Tier tool

The command line will looks like this:
icsxml -u=infodba -p=*** -g=dba -file=d:\temp\TeamcenterClassificationExport.xml -filter=all -export -class=Routing -subclass -subclassviews -subclassinstance

It was designed as XSLT 2.0 version for SAXON 9.2
It works with Teamcenter 8.3 and NX 7.5

2011-11-30 Matthias Ahrens
GEA Farm Technologies GmbH
-->
<xsl:stylesheet version="2.0"
	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
	xmlns:p="http://www.ugs.com/in-CLASS/1.0">
	<xsl:output method="text" encoding="iso-8859-1" indent="no"/>
	<!--
		Using the Template Method on all nodes
	-->
	<xsl:template match="/">
		<xsl:apply-templates/>
	</xsl:template>
	<!--
		Start Template Assignment on the InClass Root Node
	-->
	<xsl:template match="/p:InClassAdminPackage">
		<!--
			Activate the different Templates, based on the subnode type
		-->
		<xsl:apply-templates select="/p:InClassAdminPackage/p:ICSDictionaryAttribute" />
		<xsl:apply-templates select="/p:InClassAdminPackage/p:ClassPackage" />
		<xsl:apply-templates select="/p:InClassAdminPackage/p:ClassPackage/p:ICSInstance" />
		<!--
			Collect all classified instances and sort them by their class assignment
		-->
		<xsl:for-each-group select="/p:InClassAdminPackage/p:ClassPackage/p:ICSInstance" group-by="./p:ClassId">
			<!--
				Use the ClassId attribute also as name of the group
			-->
			<xsl:variable name="CurrentClassGroupID">
				<xsl:value-of select="./p:ClassId"/>
			</xsl:variable>
			<!--
				Create .ptb table file for each group found
			-->
			<xsl:result-document href="file:////machine/path_level_1/path_level_2/table_library\{$CurrentClassGroupID}.ptb">
				<!--
					Prepare the COLUMNS header for the .ptb file
				-->
				<xsl:text>VERSION 120</xsl:text><xsl:text>&#xA;</xsl:text>
				<xsl:text>COLUMNS</xsl:text><xsl:text>&#xA;</xsl:text>
				<!--
					Create General Teamcenter access Attributes
				-->
				<!-- Alternative if the access parameters should be hidden -->
				<!--
				<xsl:text>   STRING/HIDE PART_NAME</xsl:text><xsl:text>&#xA;</xsl:text>
				<xsl:text>   STRING/HIDE MEMBER_NAME</xsl:text><xsl:text>&#xA;</xsl:text>
				<xsl:text>   STRING/HIDE PART_NUMBER</xsl:text><xsl:text>&#xA;</xsl:text>
				-->
				<xsl:text>   STRING PART_NAME</xsl:text><xsl:text>&#xA;</xsl:text>
				<xsl:text>   STRING MEMBER_NAME</xsl:text><xsl:text>&#xA;</xsl:text>
				<xsl:text>   STRING PART_NUMBER</xsl:text><xsl:text>&#xA;</xsl:text>
				<!--
					Process the first instance to get the order of the properties
				-->
				<xsl:for-each select="current-group()[position() = 1]/p:Property">
					<!--
						step:call sub to get Name of Attribute by its ID
					-->
					<xsl:variable name="AttrName">
						<xsl:call-template name="ICSDictionaryAttributes-Name">
							<xsl:with-param name="ICSDictionaryAttributes-Id" select="./@attributeId"/>
						</xsl:call-template>
					</xsl:variable>
					<!--
						step:call sub to get Type of Attribute by its ID
					-->
					<xsl:variable name="AttrType">
						<xsl:call-template name="ICSDictionaryAttributes-Type">
							<xsl:with-param name="ICSDictionaryAttributes-Id" select="./@attributeId"/>
						</xsl:call-template>
					</xsl:variable>
					<!--
						Create a line in the header for the property
					-->
					<xsl:text>   </xsl:text><xsl:value-of select="$AttrType"/><xsl:text> </xsl:text><xsl:value-of select="$AttrName"/><xsl:text>&#xA;</xsl:text>
				</xsl:for-each>
				<!--
					Prepare the COLUMNS footer for the .ptb file
				-->
				<xsl:text>END_OF_COLUMNS</xsl:text><xsl:text>&#xA;</xsl:text>
				<!--
					Prepare the DATA header for the .ptb file
				-->
				<xsl:text>DATA</xsl:text><xsl:text>&#xA;</xsl:text>
				<!--
					Process each classified instance in the group
				-->
				<xsl:for-each select="current-group()/p:ICSId">
					<!--
						Load the Current Instance ID into a variable
					-->
					<xsl:variable name="InstanceID">
						<xsl:value-of select="."/>
					</xsl:variable>
					<!--
						add an appearance prefix in line of the instance DATA
					-->
					<xsl:text>   </xsl:text>
					<!--
						Create General Teamcenter access Attributes
						These are hard coded and not maintained via
						the Teamcenter classification
					-->
					<!-- PART_NAME Value = Item ID to load the part file-->
					<xsl:text>"</xsl:text><xsl:value-of select="$InstanceID"/><xsl:text>"</xsl:text>
					<!-- MEMBER_NAME Value = Item ID for non Part Familiy Parts-->
					<xsl:text> "</xsl:text><xsl:value-of select="$InstanceID"/><xsl:text>"</xsl:text>
					<!-- PART_NUMBER Value = Value show in the preview dialog. In this case it will be combined-->
					<xsl:text> "</xsl:text><xsl:value-of select="$InstanceID"/><xsl:text> </xsl:text><xsl:value-of select="current-group()/p:Property[@attributeId='1009']/p:Value"/><xsl:text>"</xsl:text>
					<!--
						Process the first instance to get the correct order of the properties again
					-->
					<xsl:for-each select="current-group()[position() = 1]/p:Property">
						<!--
							step:call sub to get Name of Attribute by its ID
						-->
						<xsl:variable name="CurrentAttr">
								<xsl:value-of select="./@attributeId"/>
						</xsl:variable>
						<!--
							step:call sub to get a instance specific attribute value
						-->
						<xsl:variable name="InstAttrValue">
							<xsl:call-template name="InstanceAttribute-Value">
								<xsl:with-param name="Instance-Id" select="$InstanceID"/>
								<xsl:with-param name="Attribute-Id" select="$CurrentAttr"/>
							</xsl:call-template>
						</xsl:variable>
						<!--
							Add the instance specific attribute value to the DATA line
						-->
						<xsl:text> </xsl:text><xsl:value-of select="$InstAttrValue"/>
					</xsl:for-each>
					<!--
						Close the data line with a line break
					-->
					<xsl:text>&#xA;</xsl:text>
				</xsl:for-each>
				<!--
					Prepare the footer for the DATA section in the .ptb files
				-->
				<xsl:text>END_OF_DATA</xsl:text><xsl:text>&#xA;</xsl:text>
			</xsl:result-document>
		</xsl:for-each-group> 
	</xsl:template>
	<!--
		An alternative process template
		In this case everything is hidden
	-->
	<xsl:template match="/p:InClassAdminPackage/p:ClassPackage/p:ICSInstance">
	</xsl:template>
	<!--
		An alternative process template
		In this case everything is hidden
	-->
	<xsl:template match="/p:InClassAdminPackage/p:ICSDictionaryAttribute">
	</xsl:template>
	<!--
		This Template processes the Classification structure.
		The classes are defined in the GlassPackage nodes.
	-->
	<xsl:template match="/p:InClassAdminPackage/p:ClassPackage">
		<!--
			Load the class ID into a variable
		-->
		<xsl:variable name="CurrentClassID">
			<xsl:value-of select="./@classId"/>
		</xsl:variable>
		<!--
			Start with a line feed
		-->
		<xsl:text>&#xA;</xsl:text>
		<!--
			Prepare the NODE header for each class in the .plv file
		-->
		<xsl:text>NODE </xsl:text><xsl:value-of select="./@classId"/><xsl:text>&#xA;</xsl:text>
		<!--
			The display name of the class is copied from the Teamcenter display name 
		-->
		<xsl:text>   NAME     </xsl:text><xsl:value-of select="./p:ICSClass/p:Name"/><xsl:text>&#xA;</xsl:text>
		<!--
			Alternative the Name can be set to the Teamcenter internal InClass ID (DEBUG)
		-->
		<!--
		<xsl:text>   NAME     </xsl:text><xsl:value-of select="./@classId"/><xsl:text>&#xA;</xsl:text>
		-->
		<!--
			step:call template to collect all classes, which are sub classes of the current one
		-->
		<xsl:call-template name="ClassPackage-Childs">
			<xsl:with-param name="ClassPackage-Name" select="./@classId"/>
		</xsl:call-template>
		<!--
			Check if instances exists in class
		-->
		<xsl:if test="./p:ICSInstance">
			<!--
				If instances exists a table reference to .ptb file will be added
			-->
			<xsl:text>   TABLE    </xsl:text><xsl:value-of select="./@classId"/><xsl:text>.ptb</xsl:text>
			<xsl:text>&#xA;</xsl:text>
		</xsl:if>
		<!--
			If no instances and no further sub classes exists a FILTER (File selection) line is added
			NX requires at least a SUBNODES, TABLE or FILTER definition in each NODE block
		-->
		<xsl:choose>
			<xsl:when test="./p:ICSInstance">
			</xsl:when>
			<xsl:when test="/p:InClassAdminPackage/p:ClassPackage[./p:ICSClass/p:Parent=$CurrentClassID]">
			</xsl:when>
			<xsl:otherwise>
				<xsl:text>   FILTER "C:temp"</xsl:text><xsl:text>&#xA;</xsl:text>
			</xsl:otherwise>
		</xsl:choose>
		<!--
			Prepare the NODE footer for each class in the .plv file
		-->
		<xsl:text>END_OF_NODE</xsl:text><xsl:text>&#xA;</xsl:text>
	</xsl:template>
	<!--
		FUNCTION - Templates, which are called from different
		point in the process block above.
		These templates have to be called with a parameter
	-->
	<!--
		Function: Return SUBNODES lines which contains all child classes of a given one
	-->
	<xsl:template name="ClassPackage-Childs">
		<xsl:param name="ClassPackage-Name" />
			<xsl:for-each select="/p:InClassAdminPackage/p:ClassPackage[./p:ICSClass/p:Parent=$ClassPackage-Name]/@classId">
				<xsl:text>   SUBNODES </xsl:text><xsl:value-of select="."/>
				<xsl:text>&#xA;</xsl:text>
			</xsl:for-each>
	</xsl:template>
	<!--
		Function: Return a name of a given Attribute
	-->
	<xsl:template name="ICSDictionaryAttributes-Name">
		<xsl:param name="ICSDictionaryAttributes-Id" />
			<xsl:for-each select="/p:InClassAdminPackage/p:ICSDictionaryAttribute[@attributeId=$ICSDictionaryAttributes-Id]/p:Name">
				<xsl:value-of select="."/>
			</xsl:for-each>
	</xsl:template>
	<!--
		Function: Return a .plv parameter type for a given Attribute
		These block has to be adjusted to map various Teamcenter formats
		into the .ptb formats.
		
		Possible .ptb formats are
		STRING		Define a string characteristic.
		INTEGER		Define an integer characteristic.
		REAL		Define a floating-point characteristic.
		
		With HIDE (e.g. REAL/HIDE) an attribute can be hidden in NX selection box
	-->
	<xsl:template name="ICSDictionaryAttributes-Type">
		<xsl:param name="ICSDictionaryAttributes-Id" />
		<!--
			step:call sub to get Name of Attribute by its ID
		-->
		<xsl:variable name="AttributeName">
			<xsl:call-template name="ICSDictionaryAttributes-Name">
				<xsl:with-param name="ICSDictionaryAttributes-Id" select="$ICSDictionaryAttributes-Id"/>
			</xsl:call-template>
		</xsl:variable>
		<!--
			Return different formats
		-->
		<xsl:choose>
			<!--
				Alternative A:
				Based on the attribute name return different formats
			-->
			<!--
			<xsl:when test="$AttributeName='WEIGHT'">
			-->
			<!--
				Alternative B:
				Based on the Format Subnode return different formats
			-->
			<xsl:when test="/p:InClassAdminPackage/p:ICSDictionaryAttribute[@attributeId=$ICSDictionaryAttributes-Id]/p:Format/p:ICSFormatFloat">
				<xsl:text>REAL</xsl:text>
			</xsl:when>
			<!--
				If no spefic one was found return STRING
			-->
			<xsl:otherwise>
				<xsl:text>STRING</xsl:text>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
	<!--
		FUNCTION: Return instance attribute value
	-->
	<xsl:template name="InstanceAttribute-Value">
		<xsl:param name="Instance-Id" />
		<xsl:param name="Attribute-Id" />
		<!--
			step:call sub to get type of attribute by its ID
		-->
		<xsl:variable name="AttrType">
			<xsl:call-template name="ICSDictionaryAttributes-Type">
				<xsl:with-param name="ICSDictionaryAttributes-Id" select="$Attribute-Id"/>
			</xsl:call-template>
		</xsl:variable>
		<!--
			If the attribute type is REAL the value is returend only
			Other a string format is assumed
		-->
		<xsl:choose>
			<xsl:when test="$AttrType='REAL'">
				<xsl:value-of select="current-group()[./p:ICSId=$Instance-Id]/p:Property[@attributeId=$Attribute-Id]/p:Value"/>
			</xsl:when>
			<xsl:otherwise>
				<xsl:text>"</xsl:text><xsl:value-of select="current-group()[./p:ICSId=$Instance-Id]/p:Property[@attributeId=$Attribute-Id]/p:Value"/><xsl:text>"</xsl:text>
			</xsl:otherwise>
		</xsl:choose>
	</xsl:template>
</xsl:stylesheet>