Sub CATMain()
    Dim sInputFile As String
    sInputFile = CATIA.FileSelectionBox("Verzeichnis der abzuarbeitenden cgr-Dateien per cgr-Datei auswaehlen", "*.cgr", CatFileSelectionModeOpen)
    Dim iFolder As Folder
    Set iFolder = CATIA.FileSystem.GetFolder(Left(sInputFile, InStrRev(sInputFile, CATIA.FileSystem.FileSeparator) - 1))
    Dim iFiles As Files
    Set iFiles = iFolder.Files
    Dim iFile As File
    For Each iFile In iFiles
        Dim sInputFileExt As String
        sInputFileExt = Mid(iFile.Name, InStrRev(iFile.Name, "."))
        If LCase(sInputFileExt) = ".cgr" Then
            sInputFile = iFile.Path
            Dim sInputFileName As String
            sInputFileName = Left(sInputFile, InStrRev(sInputFile, ".") - 1)
            Dim sInputFileNameV4 As String
            If Len(sInputFileName) > 72 Then
                sInputFileNameV4 = Left(sInputFileName, 72) & ".model"
            Else
                sInputFileNameV4 = sInputFileName & ".model"
            End If
            Dim oDoc As Document
            Set oDoc = CATIA.Documents.Read(sInputFile)
            oDoc.ExportData sInputFileNameV4, "model"
            oDoc.Close
            Set oDoc = CATIA.Documents.Open(sInputFileNameV4)
            Dim docSel As Selection
            Set docSel = oDoc.Selection
            If CATIA.SystemConfiguration.Release < "16" Then
                docSel.Search "Name=CAT_1000_1"
            Else
                docSel.Search "V4Model.MASTER"
            End If
            docSel.Copy
            Dim iPartNumber As String
            iPartNumber = Mid(sInputFileName, InStrRev(sInputFileName, CATIA.FileSystem.FileSeparator) + 1)
            Set oDoc = CATIA.Documents.Add("Part")
            Dim iProduct As Product
            Set iProduct = oDoc.Product
            iProduct.PartNumber = iPartNumber
            Set docSel = oDoc.Selection
            docSel.Add iProduct
            docSel.Paste
            iProduct.Update
            oDoc.SaveAs sInputFileName & ".CATPart"
            oDoc.Close
            Set oDoc = CATIA.Documents.Item(CATIA.Documents.Count)
            oDoc.Close
        End If
    Next
End Sub