!Kabel Olaf6
!einadrige Leitung nach Katja
!Wärmestromdichte
finish  $/clear


/filename,kabel6		!Definition von Dateiname und Titel
/Title,Waermestromdichte

lang=0.25	!Länge des Kabels


/prep7

et,2,solid70 !Isolierung
et,1,solid69 !Ader

!-----Material-----------
!-----Isolation-----
mp,kxx,2,0.092 !Wärmeleitfähigkeit
mp,c,2,1040 !spez. Wärmekapazität
mp,dens,2,1500 !Dichte
!-----Leiter------
mp,c,1,419 !spez. Wärmekapazität
mp,dens,1,8300 !Dichte
mptemp,1,0,100,200
mpdata,rsvx,1,1,1/62309935.0,1/44885765.9,1/34829110.1  !spezifischer elektrischer Widerstand
mpdata,kxx,1,1,332.20,326.96,321.72 !Wärmeleitfähigkeit (isotropic)
!mp,kxx,1,350
!mp,rsvx,1,1/56000000

!-----Geometrie----------
/view,,1,2,3
cyl4,,,0.003,0,0.001,90,lang
cyl4,,,0.001,0,,90,lang
cyl4,,,0.003,90,0.001,180,lang
cyl4,,,0.001,90,,180,lang
cyl4,,,0.003,180,0.001,270,lang
cyl4,,,0.001,180,,270,lang
cyl4,,,0.003,270,0.001,360,lang
cyl4,,,0.001,270,,360,lang
vglue,all

!Nach Zusammenkleben:Achtung Volumennummern


!-----Vernetzung----------
!-----Ader----

esize,,16
type,1

mat,1
vmesh,9

mat,1
vmesh,10

mat,1
vmesh,11

mat,1
vmesh,12


!-----Isolation----
type,2

mat,2
vmesh,1

mat,2
vmesh,13

mat,2
vmesh,14

mat,2
vmesh,15

!----Lösung----------------------
/solu

!----Randbedingungen thermisch----
asel,s,area,,46
asel,a,area,,50
asel,a,area,,54
asel,a,area,,58
asel,a,area,,2
asel,a,area,,67
asel,a,area,,61
asel,a,area,,64
sfa,all,,hflux,40000
sbctran

/psf,hflux,,1

alls

!----Randbedingungen thermisch----
csys,1
nsel,s,loc,x,0.003
sf,all,conv,10,20
csys
!nsel,s,loc,z,0
!nsel,a,loc,z,lang
!sf,all,conv,10,20		!Wärmeübergangskoeffizient,Mediumtemp
alls

allsel
tunif,20			!Umgebungstemperatur

solve
!----Auswertung-------------------
/post1
plns,temp

/ctype,1			!Isosurfaceplot der Temperaturverteilung
/replot

lpath,node(0,0,lang),node(0,0,0)
pdef,,temp
/reset
/grid,1
/yrange,0,110
/axlab,y,TEMP [°c]
/axlab,x,Länge [m]
plpath,temp			!Diagramm Tempdarstellung längs


lpath,node(0,0,lang),node(0.003,0,lang)
pdef,,temp
/reset
/grid,1
/yrange,0,280
/axlab,y,TEMP [°c]
/axlab,x,Länge [m]
plpath,temp			!Diagramm Tempdarstellung quer