WI_ALPHA=13/2			! WINKEL ALPHA (NEIGUNG DES KONUS AM AUSSENRING [°]
WI_BETA=11/2			! WINKEL BETA (NEIGUNG DES KONUS AM INNENRING) [°]
*AFUN, DEG			!
R1=0.5
!
! ***** BELASTUNG *****
KRAFT=1327.1			! [N]
!
!
! ******************** 8. ELEMENT- UND MATERIALDATEN ********************
/PREP7
!
ET, 1, PLANE182		! NR.1: AUSSENRING - STAHL
KEYOPT, 1, 1, 2
!KEYOPT, 1, 1, 0		! 8-NODE QUADRILATERAL
KEYOPT, 1, 3, 1		! AXISYMMETRIC
!
ET, 2, PLANE182		! NR.2: KARBON-BESCHICHTUNG
KEYOPT, 2, 1, 2
KEYOPT, 2, 3, 1
!
ET, 3, PLANE182		! NR.3: INNENRING - STAHL
KEYOPT, 3, 1, 2
KEYOPT, 3, 3, 1
!
!
!
! MPC-CONTACT
!
ET, 4, TARGE169		! NR.4: 2-D TARGET SEGMENT
ET, 5, CONTA171		! NR.5: 2-D 2-NODE SURFACE-TO-SURFACE CONTACT 
KEYOPT, 5, 1, 0		! SELECTS DEGREES OF FREEDOM: 0 = UX,  UY
KEYOPT, 5, 2, 2		! MPC
KEYOPT, 5, 4, 1
KEYOPT, 5, 9, 1
KEYOPT, 5, 12, 5
!
!
! KONTAKT DER REIBFLÄCHEN
!
ET, 6, TARGE169		! NR.6: 2-D TARGET SEGMENT
ET, 7, CONTA171		! NR.7: 2-D 2-NODE SURFACE-TO-SURFACE CONTACT 
KEYOPT, 7, 1, 0		! SELECTS DEGREES OF FREEDOM: 0 = UX,  UY
KEYOPT, 7, 2, 1
KEYOPT, 7, 4, 0
KEYOPT, 7, 5, 4
KEYOPT, 7, 9, 1
KEYOPT, 7, 10, 2	! CONTACT STIFFNESS UPDATE:
!			! 2 - EACH ITERATION BASED ON CURRENT MEAN STRESS OF UNDERLYING ELEMENTS (PAIR BASED).
!
R, 7, , , 1, 1,	! 3 - FKN: NORMAL PENALTY STIFFNESS FACTOR (0.01-1.0)
!			! 4 - FTOLN: PENETRATION TOLERANCE FACTOR
!
!
MAT_DEF2		! MAKRO: MATERIALDATEN
!
!
! ******************** 9. MODELLGEOMETRIE U. VERNETZUNG ********************
!
GEO_MESH		! MAKRO: ERZEUGUNG DER FLÄCHENGEOMETRIE UND DER VERNETZUNG
!
!
! ******************** 10. RANDBEDINGUNGEN ********************
!
/SOLU
!
!===== 10.1 FESTE EINSPANNUNG INNENRING UND KONTAKTINNENRING (KOINRI) =====
!
LSEL,S, , , DL_LINE_1
DL, ALL, , UX
DL, ALL, , UY
ALLS

LSEL,S, , , DL_LINE_2
DL, ALL, , UX
DL, ALL, , UY
ALLS
!
FEDERN			! MAKRO: FEDERERZEUGUNG FÜR STAARKÖRPERBEWEGUNG
!
!
! ******************** 11. LÖSUNG ********************
!
/SOLU
SBCTRAN
ANTYPE, STATIC			! STATISCHE ANALYSE
SOLCONTROL, ON, ON
NROPT, AUTO
LNSRCH, ON
PRED, ON, , ON
NLGEOM, ON
AUTOTS, ON
NSUBST, 60, 1000, 60		! SPECIFIES THE NUMBER OF SUBSTEPS TO BE TAKEN THIS LOAD STEP, 
!				! 30  -  NUMBER OF SUBSTEPS TO BE USED FOR THIS LOAD STEP, 
!				! 500 -  MAXIMUM NUMBER OF SUBSTEPS TO BE TAKEN, 
!				! 30  -  MINIMUM NUMBER OF SUBSTEPS TO BE TAKEN
!
!
CNCHECK,AUTO
!
OUTRES, ALL, LAST
!
NLDIAG, NRRE, ON
!
!
!===== 10.2 DRUCKBELASTUNG AUF AUSSENRING =====
!    
    *DO,MM,1,10,1
        !
        LSEL,S, , , SFL_LINE
        SFL,ALL,PRES,DRUCK*MM/10
        ALLS
        
        /PSF,PRES,NORM,2,0,1
	/PBF,DEFA, ,1   
	/PIC,DEFA, ,1   
	/PSYMB,DOT,1
	/PBC,ALL, ,1
	/REPLOT
        TIME,MM
        SOLVE
        !
    *ENDDO