!Transient Earthquake Analysis of a gravity dam
!dimensions and shape are not realistic 

FINISH
/CLEAR, NOSTART
/FILNAME,TransientAnalysisEarthquake

!material properties, gravity dam
ex1 = 24 e9 !N/m²
dens1 = 2550 !kg/m³
prxy1 = 0.19
h = 1 !m
b = 0.2 !m
t = 0.2 !m

!material properties, granite foundation
ex2 = 20 e9 !N/m²
dens2 = 0 !2700 !kg/m³
prxy2 = 0.1

!parameters for calculation [seconds]
TM_START = 0.001 !starting time of calculations 
TM_END = 0.1 !end of calculations 
TM_INCR = 0.01 !time increment

/PREP7
!element type
ET,1,solid185

!material 1: concrete (gravity dam) 
mp,ex,1,ex1
mp,dens,1,dens1
mp,prxy,1,prxy1

!material 2: foundation (granite)
mp,ex,2,ex2
mp,dens,2,dens2
mp,prxy,2,prxy2

!keypoints for gravity dam
k,1,0,0
k,2,b,0
k,3,b,h 
k,4,0,h 

! 2-dimensional dam area >> 3-dimensional dam body
a,1,2,3,4
VOFFST,1,t 

!keypoints for foundation
k,11,-1,0
k,12,-1,-1 
k,13,1,-1
k,14,1,0 

! 2-dimensional foundation area >> 3-dimensional 
a,11,12,13,14,2,1 
VOFFST,7,t 

!merge coincident keypoints, areas,..
NUMMRG,ALL,0.01, , ,LOW 

!1 element in z-direction
LESIZE,9, , ,1, , , , ,0 
LESIZE,10, , ,1, , , , ,0 
LESIZE,11, , ,1, , , , ,0 
LESIZE,12, , ,1, , , , ,0 

LESIZE,24, , ,1, , , , ,0  
LESIZE,25, , ,1, , , , ,0 
LESIZE,26, , ,1, , , , ,0 
LESIZE,27, , ,1, , , , ,0 

!meshing the dam
type,1
mat,1
VSWEEP,1 

!meshing the foundation
type,1 
mat,2
VSWEEP,2

FINISH

/SOLU
ANTYPE,TRANS
TRNOPT,FULL

!displacement of foundation
!version 1: zero displacement at nodes 
!node-set left border
NSEL,s,loc,x,-1
D,all,all,0 
NSEL,all

!node-set right border
NSEL,s,loc,x,1
D,all,all,0 
NSEL,all

!node-set lower border
NSEL,s,loc,y,-1
D,all,all,0 
NSEL,all

!version 2: zero displacement for areas
! DA,9,ALL,0 !left border
! DA,11,ALL,0 !right border
! DA,10,ALL,0 !lower border 

!tabular for acceleration time history
!10 rows,2 columns, 
!primary variable: time
*DIM,TAB1,table,10,1,1,TIME 
*TREAD,TAB1,AccelerationTimeHistory,txt

!node-set for horizontal acceleration: left and right border of foundation 
NSEL,S,LOC,X,-1 
NSEL,A,LOC,X,1

!loop for acceleration time history input from table 
*DO,TM,TM_START,TM_END,TM_INCR
TIME,TM 
D,all,accx,%TAB1%
SOLVE
*ENDDO

ALLSEL
FINISH