/COM  ============================================================
/COM  ==                                                        ==
/COM  ==         T A Y L OR    -   C O U E T T E   -            ==
/COM  ==    S T R O E M U N G S S I M U L A T I O N  3 D        ==
/COM  ==                                                        ==
/COM  ============================================================

! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  G r u n d e i n s t e l l u n g e n
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

finish                      	! Beenden und Löschen des vorherigen Modells
/clear,all
/DELETE,Zyl3D,pfl      		! manuelles Löschen der alten *.pfl Datei
/DELETE,Zyl3D,rfl      		! manuelles Löschen der alten Ergebnisdatei 

*abbr,RECHNEN, SOLVE        	! Schaltfläche zum schnellen starten hinzufügen
*abbr,RESTART, /input,_Zylinder_3D.txt	

/filnam,Zyl3D          		! Dateinamen festlegen
/title,Zylinder3D           

/UNITS,SI                   	! SI-Einheiten
*AFUN,DEG                   	! Winkelangaben in Grad
/UDOC,1,DATE,OFF		   	! Logo ausschalten

! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  V a r i a b l e n
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

mm=0.001					! mm->m
PI=3.141592654				! die Zahl Pi
 
ri=100*mm            		! Innenradius
spalt=2.0*mm            		! Spaltbreite
L_z=50*mm					! Zylinderlänge in axialer Richtung
ra=ri+spalt            		! Ausenradius

NSpalt=20					! Anzahl der Unterteilungen des Spaltes
SPACE_r=-5				! Linenunterleilungsverhältnis im Spalt für lesize
alpha=2				   	! Winkel für Segmentgröße
N_z=50                       	! Anzahl Elemente in z-Richtung

NIter=500                   	! Iterationen

FlagTurbu='true'			! 'true' =turbulent 'false'=laminar

Druck=0        			! Referenzdruck am Innenzylinder		[Pa]
V_i=30.0           			! Geschwindigkeit innerer Zylinder		[m/s]
V_a=0               		! Geschwindigkeit äußerer Zylinder		[m/s]
Drehzahl = V_i/ri/2/PI*60    	! 								[U/min]
RHO   = 1.2          		! FLUID Dichte (Luft)				[kg/m^3]
MU    = 17.1e-6     		! dynamische Viskosität (Luft)		[kg/(m*s)], [Pa*s]

Re=RHO/MU*V_i*spalt   		! Reynolds-Nummer
Re_k=41.3*sqrt((ri+ra)/spalt) ! kritische Re-Nummer nach Prandtl für innen rotierenden Zylinder
V_RE=Re/Re_k        		! Verhältnis Re/Re_k
 
*msg,ui,Drehzahl,Re,V_RE  	! Ausgabe von Drehzahl Re und V_Re
n = %I rpm %/ &                   
Re = %I %/ &   
Re/Re_krit = %I


! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
! P r e p r o z e s s o r
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

/PREP7
et,1,fluid141,,,3         	! 2D Fluid-Element
ET,2,FLUID142,,,3  			! 3D Fluid-Element


! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  G e o m e t r i e   e r s t e l l e n 
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

pcirc,ri,ri+spalt,90,270  	! Geometrie aus 2 Halbkreisen erstellen
pcirc,ri,ri+spalt,-90,90
aglue,all       			! Flächen miteinander bekannt machen
nummrg,all    				! Kompriemierung der Numerierung

csys,1					! globales KS aus Zylinderkoordinaten umstellen

lsel,s,loc,y,90			! Linien an den Stoßflächen der Halbkreise auswählen
lsel,a,loc,y,-90   			!
lesize,all,,,NSpalt,SPACE_r 	! und unterteilen

lsel,s,loc,x,ri   			! Linien am Innen- und 
lsel,a,loc,x,ra    			! Ausenradius auswählen
lesize,all,,alpha   		! und unterteilen


! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  V e r n e t z e n 
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

allsel  
type,1					! 2D-Element auswählen
mshape,0,2d				! 0 6-Flächer         1 Tetreader
mshkey,1					! 0 freie Vernetzung  1 mapped mash
amesh,all   				! Auswahl vernetzen


! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  3 .   D i m e n s i o n   E x t r u i e r e n  
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

TYPE,2 					! 3D-Element auswählen
ESIZE,,N_z, 				! Anzahl der Elemente in z-Richtung festlegen
asel,all
csys,0					! kurzer KS-Wechsel um Warnmeldung von VEXT zu unterdrücken
VEXT,all, , ,0,0,L_z,,,,		! 2D-Fläche in z-Richtung extruieren
csys,1
ACLEAR,all				! 2D-Elemente löschen


! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  R a n d b e d i n g u n g e n
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

asel,s,loc,x,ri			! Zylinderinnenfläche auswählen
nsla,s,1					! zugehörige Knoten auswählen und Randbedingugen zuweisen
nsel,r,loc,z,0,L_z
D,ALL,VX,0				! Geschwindigkeit radial
D,ALL,VY,V_i				! Geschwindigkeit tangential
d,all,vz,0				! Geschwindigkeit axial
d,all,enke,-1				! -1 bei Freiheitsgrad ENKE bedeutet FLAG als bewegte Wand
d,all,pres,Druck			! Referenzdruck

asel,s,loc,x,ra			! Zylinderausenfläche auswählen
nsla,s,1					! zugehörige Knoten auswählen und Randbedingungen zuweisen
nsel,r,loc,z,0,L_z
D,ALL,VX,0				! Geschwindigkeit radial
D,ALL,VY,V_a				! Geschwindigkeit tangential
d,all,vz,0				! Geschwindigkeit axial

asel,s,loc,z,0				! Zylinderstirnflächen auswählen
asel,a,loc,z,L_z			!
nsla,s,1					! zugehörige Knoten selektieren und Randbedingungen zuweisen
!D,ALL,VX,0				! Geschwindigkeit radial
!D,ALL,VY,0				! Geschwindigkeit tangential
d,all,vz,0				! Geschwindigkeit axial

allsel


! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  S O L V E R
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -

/solu

FLDATA1,SOLU,TURB,FlagTurbu	! laminares oder turbulentes Modell
FLDATA1,SOLU,TRAN,0 
FLDATA1,SOLU,FLOW,1 
FLDATA1,SOLU,TEMP,0 
FLDATA1,SOLU,COMP,0 
FLDATA1,SOLU,VOF,0  
FLDATA1,SOLU,SFTS,0 
FLDATA1,SOLU,IVSH,0 
FLDATA1,SOLU,SWRL,0 
FLDATA1,SOLU,SPEC,0 
FLDATA1,SOLU,ALE,0  
FLDATA1,SOLU,RDSF,0 

FLDATA2,ITER,EXEC,NIter		! Anzahl der Iterationen pro Schleife   
FLDATA2,ITER,OVER,0
FLDATA2,ITER,APPE,0

FLDATA3,TERM,PRES,1e-005,   

FLDATA5,OUTP,SUMF,100		! Anzahl der Iterationen bevor Zusammenfassung in pfl-Datei geschrieben wird
FLDATA5,OUTP,TAUW,TRUE        ! Scherspannung an der Begrenzung in Ergebnisdatei schreiben
FLDATA5,OUTP,YPLU,TRUE 		! dito für Y+
FLDATA5,OUTP,RESI,false		! Residual-File *.rdf erstellen?

FLDATA6,CONV,OUTP,Bloc		! Art der Ausgabe der Ergebnisse des Konvergenzmonitors
FLDATA6,CONV,ITER,100		! aller wievieler Iterationen erfolgt die Ausgabe?

FLDATA7,PROT,DENS,AIR-SI
FLDATA7,PROT,VISC,AIR-SI
FLDATA7,PROT,COND,AIR-SI
FLDATA7,PROT,SPHT,AIR-SI

FLDATA24,TURB,MODL,0		! Turbulenzmodell 0...k-epsilon-Modell

FLDATA34,MIR,MOME,0			! Sets modified inertial relaxation factors
FLDATA34,MIR,TURB,0.0		! Empfohlen 0,1...1,0


allsel
solve					! Lösen
save						! Speichern


! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
!  P O S T P R O Z E S S O R
! - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 

/post1
rsys,1					! Ergebnis-KS --> Zylinder
set,last					! letzten Datensatz lesen

PATH,v-schnit,2,30,50  		! radialen Pfad mit Koordinatenfestlegen
PPATH,1,,ri,0,l_z/2			!
ppath,2,,ra,0,l_z/2			!
PDEF,V_y,V,Y,noAV			! tangentiale Geschwindigkeit zuordnen
PLPATH,V_Y  				! und plotten