/PREP7
ET,1,PLANE182              !* 2D 4-NODE STRUCTURAL SOLID ELEMENT
KEYOPT,1,1,2               !* ENHANCE STRAIN FORMULATION
KEYOPT,1,3,2               !* PLANE STRAIN
ET,2,PLANE182
KEYOPT,2,1,2
KEYOPT,2,3,2
ET,3,TARGE169              !* 2D TARGET ELEMENT
ET,4,CONTA171              !* 2D CONTACT ELEMENT
KEYOPT,4,12,5              !* BONDED ALWAYS CONTACT
MP,EX,1,1.353E5            !* E11 = 135.3 GPA
MP,EY,1,9.0E3              !* E22 =   9.0 GPA
MP,EZ,1,9.0E3              !* E33 =   9.0 GPA
MP,GXY,1,5.2E3             !* G12 =   5.2 GPA
MP,PRXY,1,0.24
MP,PRXZ,1,0.24
MP,PRYZ,1,0.46
KOPEN  = 1.E6
TB,CZM,2,1,1,CBDE
TBDATA,1,1.7,0.28,,,1.E-8
RECTNG,0,100,0,1.5         !* DEFINE AREAS
RECTNG,0,100,0,-1.5
LSEL,S,LINE,,2,8,2         !* DEFINE LINE DIVISION
LESIZE,ALL,0.75
LSEL,INVE
LESIZE,ALL, , ,200
ALLSEL,ALL
TYPE,1                     !* MESH AREA 2
MAT,1
LOCAL,11,0,0,0,0
ESYS,11
AMESH,2
CSYS,0
TYPE,2                     !* MESH AREA 1
ESYS,11
AMESH,1
CSYS,0
NSEL,S,LOC,X,30,100
TYPE,3
MAT,2
REAL,3
ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,Y
ESURF                      !* TARGET ELEMENTS
TYPE,4
REAL,3
RMODIF,3,3,-KOPEN
RMODIF,3,12,-KOPEN
ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,Y
NSEL,R,LOC,X,30,100
ESURF                      !* CONTACT ELEMENTS
ALLSEL,ALL
NSEL,S,LOC,X,100           !* APPLY CONSTRAINTS
D,ALL,ALL
NSEL,ALL
FINISH
/SOLU
ESEL,S,TYPE,,2
NSLE,S
NSEL,R,LOC,X
NSEL,R,LOC,Y,1.5           !* APPLY DISPLACEMENT LOADING ON TOP
D,ALL,UY,10
NSEL,ALL
ESEL,ALL
ESEL,S,TYPE,,1
NSLE,S
NSEL,R,LOC,X
NSEL,R,LOC,Y,-1.5          !* APPLY DISPLACEMENT LOADING ON BOTTOM
D,ALL,UY,-10
NSEL,ALL
ESEL,ALL
NLGEOM,ON
TIME,1
NSUBST,100,100,100
OUTRES,ALL,ALL
SOLVE                      !* PERFORM SOLUTION
FINISH



/post1

esel,s,type,,4
nsle,s,all
*get,nanz,node,,count
set,last
alls
csys,0
PATH,Test,2,30,70,  
PPATH,1,node(30,0,0)
PPATH,2,node(130,0,0)

/PBC,PATH,1 
nplot 
PDEF,Cont_sta,CONT,STAT,AVG

PLPATH,CONT_STA 

/header,off,off,off,off,off,off,off
alls
!---------Makro----------------------------
*create,ausgabe                  !Makro generieren
/output,Cont_Debo,txt,,append
PrPATH,CONT_STA 
/output
*end                              !Makro beenden


! /show,png
set,last
*get,ENDSUBS,active,,set,SBST
i=1
*do,i,1,ENDSUBS
set,1,i

PDEF,Cont_sta,CONT,STAT,AVG
*use,ausgabe               !Makro ausführen
*enddo

! esel,s,type,,4
! nsle,s,all
! plnsol,cont,stat


/post26
numvar,200



alls
NSEL,S,LOC,Y,1.5
NSEL,R,LOC,X,0
*GET,NTOP,NODE,0,NUM,MAX
NSEL,ALL
NSOL,2,NTOP,U,Y,UY
RFORCE,3,NTOP,F,Y,FY
PROD,4,3, , ,RF, , ,20
ANSOL,5,319,CONT,STAT,CONTSTAT_5




/TITLE,VM255, DCB: REACTION AT TOP NODE VERSES PRESCRIBED DISPLACEMENT
/AXLAB,X,DISP U (mm)
/AXLAB,Y,REACTION FORCE R (N)
/YRANGE,0,60
XVAR,2
PLVAR,4