!Simulation der Indentation einer planen Oberfläche durch einen konischen Indenter !mit abgeflachter Spitze

!Überprüfung der Berechnung durch gleichzeitige Simulation eines Zugversuchs

!Alle Werte sind in SI-Einheiten, also [N] und [m] eingegeben

reib1=0.2 			!Reibungskoeffizient für Material1 (S235JR)

hoz=60E-3 			!Kantenlänge Probe
hoh=2.76165	E-3		!Höhe des konischen Indenters
abst=0 E-3  			!Abstand des Indenters zu  Oberfläche
bweg=1.7 E-3		!Bewegung des Indenters
weg=bweg-abst 		!Eindringweg 

fkp=1E-3			!Feinheit des Netzes um Eindringpunkt
fdge=5E-3			!Feinheit des Netzes in der Probe
zst=5E-3			! Feinheit des Netzes im Zugstab			

fzst=9000			!Kraft auf den Zugstab

/PREP7		!Preprocessor

!---Elementtypen---

ET,1, plane182,,,2 		! Plane strain (Z strain = 0.0)
REAL, 1			! Sets the element real constant set attribute pointer.
R, 1, , , , , , 			! Defines the element real constants.
KEYOPT,1,1,2		! Enhanced strain formulation, suggestion by ansys


ET,4, plane182,,,3		! Plane stress with thickness input
REAL, 2
R, 2, 5E-3, , , , ,		! thickness input = 5[mm] 
KEYOPT,1,1,2		! Enhanced strain formulation, suggestion by ansys


ET,2,CONTA171 !,,,1,,,,,,1,,,2

KEYOPT, 2, 3, 1

KEYOPT, 2, 5, 3
!keyopt5/3 Close gap/reduce penetration with auto CNOF 

KEYOPT, 2, 9, 1
! keypt9/1 Exclude both initial geometrical penetration or gap and offset

KEYOPT, 2, 12, 2
 !keypt12/2 means no seperation but sliding permitted

REAL, 3


ET,3,TARGE169
REAL, 3


!---Materialkennwert Stahl---

MP, EX,1,2.1E11			!E-Modul
MP,PRXY,1,0.3			!Querkontraktionszahl
MP, MU,1,reib1, 			!Reibungskoeffizient 


!Spannungs-DehnungsDiagramm

TB,MISO,1,1,7                			! Activate a data table
TBTEMP,20                			! Temperature = 20
TBPT,DEFI,1.12E-3, 2.35E8    		! Strain, stress at temperature = 20
TBPT,DEFI,5E-2, 2.60 E8    
TBPT,DEFI,10E-2, 3.10 E8    
TBPT,DEFI,15E-2, 3.50 E8    
TBPT,DEFI,17.5E-2, 3.60 E8    
TBPLOT,MISO,1



!---Geometrie----

!---Indenter---
K, 1, 0, 0+abst, 
K, 2, 0, hoh+abst, 
K, 3, 2.5172989 E-3, hoh+abst, 
K, 4, 0.2 E-3, 0+abst, 
!---Lines
LSTR, 1, 4
LSTR, 4, 3
LSTR, 3, 2
LSTR, 2, 1
!Areas
AL, 1, 2, 3, 4, 

!---Probe---
rectng,0,hoz,0,-hoz 

!---Zugstab---
rectng,-20E-3 ,-15E-3,50E-3,25E-3 


!----Vernetzung------Probe---
esize, fdge		!element size
kesize,8,fkp		!element size around first kontakt-node 
type,1
real,1	
mat,1
amesh,2


!----Vernetzung------Zugstab---
esize, zst		!element size
type,4
real,2
mat,1
amesh,3

!----Randbedingung----- 

!----Randbedingung-----Zugstab
nsel,s,loc,y,50E-3 
d,all,uy,0

!----Randbedingung-----Probe
nsel,s,loc,y,-hoz 
d,all,uy,0
nsel,s,loc,x,0
d,all,ux,0			!gilt auch für Pilotnode=pilot1


!---Kontakte----

!--------------------TARGETELEMENT
type,3	
real,3	
TSHAP, LINE
lmesh, 1,2

*GET,NMAX,NODE,,NUM,max
TNM= NMAX
Nsel,s,node,, TNM-2, TNM	!selects targetnodes

*GET,NMAX,NODE,,NUM,max
Pilot1= NMAX+1
n, Pilot1,, 0.25E-3
TSHAP,PILOT
e,Pilot1 
d,pilot1,ux,0

/PNUM, NODE, 1	! Node numbers on node and element plots.
nsel,s,node,,all
DOFSEL, s, disp 	!SELECTS DOFS
dlist,all		!LIST ALL DOFS

!-------------------CONTACTELEMENT
lsel,s,,,7
nsll,s,1
type,2
real,3	
esurf



!---Lasten----- 
nsel,s,node,,pilot1
d,pilot1,uy,-weg	!d=dof s for pilot1: y-movement  = -weg
ALLSEL, , 

!---Lasten----- Zugstab
nsel,s,loc,y,25E-3
F, all, FY, -fzst/2, 


/SOLU		!Solution

NROPT,UNSYM

SOLCON,ON

CUTCONTROL, PLSLIMIT, 0.10,

EQSLV,FRONT	! Frontal direct equation solver

NSUBST, 1000,	! Specifies the number of substeps to be taken this load step. 
!CNCHECK, detail, 1, , 

OUTRES,ALL,all
CSYS 
ALLSEL, ,
SOLVE 

/POST1		!Postprocessor

/EDGE,,1

/DSCA,,1

!Contours zur Indentation
! /CVAL, 1, 1.5E8, 2E8,2.34E8, 2.35E8,2.36E8, 2.4E8, 2.5E8, 3.6E8

!Contours zur Indentation II
! /CVAL, 1,1E8, 2E8, 2.1E8, 2.3E8, 2.4E8, 2.5E8, 3E8, 3.6E8

!Contours zum Zugversuch
! /CVAL, 1, 2E8,3.3E8,3.4E8,3.58E8, 3.59E8, 3.595E8, 3.6E8


PLNSOL,S,EQV	!plnsol,s equivalent stress (wtf),nodal sol v mise