!eine bis mehrere  Windungen (Kupfer) stromdurchflossen
!zweidimensional axialsysmmetrisch
!Ausnutzung von Symmetrie
!schaltungsgespeist (Sinus-Wechselspannungsquelle)
!massiver Leiter
!Berechnung der Induktivität und des ohmschen Verlustwiderstandes der Spule

fini  $/clear

!------Parameter--------
wianz=4          !Windungs-Anzahl
wiradin=14.02e-3    !Windungs-Radius innen der äußersten Windung
wiradau=14.309e-3    !Windungs-Radius außen der äußerten Windung
abst_zw_Wind=0.578e-3      !Abstand zwischen 2 Windungen der Primärspule

rad_1te_Wind = (wiradau+wiradin)/2    !Radius Mitte äußerste Windung
di_Draht = wiradau-wiradin            !Dicke der Leiterbahn

wiho=0.035e-3       !Windungs-Höhe
beradin=30e-3    !Bereichs-Radius innen
beradau=50e-3   !Bereichs-Radius außen
gacu=57e6        !Gamma Kupfer
mw=.5e-3

!Schaltung
V0 = 3             !Amplitude des Sinussignals der Eingangsspannung
freq = 10e1      !Frequenz des Eingangssignals
rvor=1e0         !Vorwiderstand

pi=4*atan(1)
my0=4e-7*pi
et=sqrt(1/(pi*freq*gacu*my0))  !Eindringtiefe  

/prep7  
et,1,plane53,,,1     !Luft
et,2,plane53,4,,1    !Leiter massiv
et,3,infin110,,,1    !Randelement
mp,murx,1,1          !Luft 
mp,murx,2,1          !Kupfer
mp,rsvx,2,1/gacu
r,1,(wiradau-wiradin)*wiho/2 !Wicklungsdaten

!----Geometrie------
/color,outl,blac
pcirc,0,beradau,0,90
pcirc,0,beradin,0,90

!Spule
*do,i,1,wianz
rectng,rad_1te_Wind-(i-1)*abst_zw_Wind-di_Draht/2,rad_1te_Wind-(i-1)*abst_zw_Wind+di_Draht/2,0,wiho/2
*enddo
aovlap,all

numcmp,area
/PNUM,AREA,1    !Flächennummerierung anzeigen

!A1:Bereich außen A2-A(wianz+1):Leiter A(wianz+2):Bereich innen 
!/eof

!-------Vernetzung-Leiter------
mshape,0,2d  !Vernetzen mit Vierecken
mshkey,1
esize,et/2.5  !Maschenweite
type,2  $mat,2 $real,1
amesh,2,wianz+1
!----Vernetzung---Luft------
csys,1
lsel,s,loc,x,beradin,beradau
lsel,u,loc,x,beradin
lsel,u,loc,x,beradau
lesize,all,,,4,1/4
esize,,8
type,1   $mat,1
amesh,1
mshkey,0
esize,wiho*10
type,1  $mat,1
amesh,wianz+2
!----Rand-----
nsel,s,loc,x,beradau
esln
emodif,all,type,3
sf,all,inf
allsel

!------------
csys,0
!/eof

!---speisende Schaltung-----


et,4,circu124,4   !Eingangsspannung
r,4,V0
et,5,circu124,0   !Widerstand
r,5,rvor
et,6,circu124,6   !Koppelelement
r,6,0.5

abm=0.05  !Abmessung für Schaltungsdarstellung

!Knoten definieren
n,,-2*abm,0
n,,-2*abm,abm
*do,i,1,wianz
  n,,-abm,abm-abm*(i-1)/wianz
*enddo
n,,-abm,0


type,4  $real,4
e,node(-2*abm,abm,0),node(-2*abm,0,0),node(-abm,0,0)

type,5  $real,5
e,node(-2*abm,abm,0),node(-abm,abm,0)

type,6  $real,6
*do,i,1,wianz
  n2=node(wiradin-(i-1)*abst_zw_Wind,0,0)
  e,node(-abm,abm-abm*(i-1)/wianz,0),node(-abm,abm-abm*i/wianz,0),node(wiradin-(i-1)*abst_zw_Wind,0,0)
*enddo

eplot

!---Kopplung-------------
esel,s,mat,,2
nsle
*get,nanf,node,,num,min
*get,nanz,node,,count
merk=nanz
narb=ndnext(nanf)
cp,1,curr,all
cp,2,emf,all


!---Spannungsvorgabe bez. Masse----------
!bfe,all,vltg,,spannung
nsel,s,loc,x,-2*abm,-abm
nsel,r,loc,y,0
d,all,volt,0
nsel,s,loc,x,0
!d,all,az,0
allsel
!/eof


!---Lösung---
/solu
antype,harm
harfrq,freq
solve

/post1
set,1,1    ! RT
presol,elem

set,1,1,,1
presol,elem  ! IT


/post26
esel,s,type,,5
*get,er,elem,,num,min
esel,all
esol,2,er,,smisc,2,Strom
prva,2

*get,real_i0,vari,2,rtime   ! RT & IT des Stromes
*get,imag_i0,vari,2,itime

esel,s,type,,6
*get,er,elem,,num,min
esel,all
esol,3,er,,smisc,1,Spannung
prva,3

*get,real_uL,vari,3,rtime   ! RT & IT der Spannung an der Spule
*get,imag_uL,vari,3,itime

uL = (real_uL**2+imag_uL**2)**0.5  ! Betrag der Spannung an der Spule

i0=(real_i0**2+imag_i0**2)**0.5  ! Betrag des Stromes

esel,s,type,,6
*get,er,elem,,num,min
esel,all
esol,4,er,,nmisc,1,Leistung
prva,4

*get,real_p,vari,4,rtime  ! RT & IT der Leistung an der Spule
*get,imag_p,vari,4,itime

R=(uL/i0)*1/(((imag_p/real_p)**2+1)**0.5)  ! ohmscher Verlustwiderstand der Spule

L=(R/(2*pi*freq))*(imag_p/real_p)  ! Spuleninduktivität