!Berechnung der Kopplung zwischen zwei Spiralspulen mit Cu-Scheibe in 5 mm Abstand zu Primärwicklung
!axialsymmetrisch
!28.04.2011

finish $/clear

!----- Parameter -----
rad_1te_Wind=14.1645e-3   !Radius der äußersten Windung der Primärspule
rad_2te_Wind=14.1645e-3   !Radius der äußersten Windung der Sekundärspule

di_Draht=0.289e-3         !Dicke der Leiterbahn der Primärspule
di_Draht2=0.289e-3        !Dicke der Leiterbahn der Sekundärspule

abst_zw_Wind=0.578e-3     !Abstand zwischen 2 Windungen der Primärspule
abst_zw_Wind2=0.578e-3    !Abstand zwischen 2 Windungen der Sekundärspule
hoe_Draht=0.025e-3        !Höhe der Cu-Bahn der Primärspule
hoe_Draht2=0.025e-3       !Höhe der Cu-Bahn der Sekundärspule

wianz=8                                      !Windungszahl Primärspule
wianz2=3                                     !Windungszahl Sekundärspule
radau=rad_1te_Wind*4                         !Radius des Randes
distanz=3e-3                                 !Distanz zwischen beiden Spulen

radcu = 15.5e-3               !Radius der Cu-Scheibe
di_cu = 0.2e-3                !Dicke der Cu-Scheibe
abst_cu = 5e-3!              !Abstand Cu-Scheibe zu Primärwicklung

freq=12e6           !Frequenz

strom=0.01       !Strom
pi=4*atan(1)
kappa=56e6
my0=4e-7*pi
ed=sqrt(1/(pi*freq*kappa*my0))  !Eindringtiefe  ca. 20 um


!----- Aufruf des Preprozessors -----
/prep7
et,1,plane53, ,,1    !Luft
et,2,plane53,1,,1    !Draht, Cu-Scheibe
et,3,infin110,,,1    !Rand
!-------Material-----
mp,murx,1,1    !Luft
mp,murx,2,1    !Wicklung 1
mp,rsvx,2,1/kappa  !Wicklung 1
mp,murx,3,1    !Wicklung 2
mp,rsvx,3,1/kappa  !Wicklung 2
mp,murx,4,1    !Cu-Scheibe
mp,rsvx,4,1/kappa  !Cu-Scheibe

!--------Geometrie---------
cyl4,0,0,0,-90,radau,90

! Primärwicklung
*do,i,1,wianz
rectng,rad_1te_Wind-(i-1)*abst_zw_Wind-di_Draht/2,rad_1te_Wind-(i-1)*abst_zw_Wind+di_Draht/2,-distanz/2-hoe_Draht,-distanz/2
*enddo

! Sekundärwicklung
*do,i,1,wianz2
rectng,rad_2te_Wind-(i-1)*abst_zw_Wind2-di_Draht2/2,rad_2te_Wind-(i-1)*abst_zw_Wind2+di_Draht2/2,distanz/2,distanz/2+hoe_Draht2
*enddo

!Cu-Scheibe
rectng,0,radcu,-distanz/2-hoe_Draht-abst_cu-di_cu,-distanz/2-hoe_Draht-abst_cu

aovlap,all
aplot
numcmp,area
!---------Vernetzung-Drähte----

!primär
esize,di_Draht/1
type,2  $mat,2      
amesh,1,wianz

!sekundär
esize,di_Draht2/1
type,2  $mat,3      
amesh,wianz+1,wianz+wianz2

!-----Vernetzung Cu-Scheibe-----
esize,di_Draht/2
type,1  $mat,4 
amesh,wianz+wianz2+1


!-----Vernetzung Luft-----
esize,di_Draht*10
type,1  $mat,1  
amesh,wianz+wianz2+2

!-----Vernetzung Rand---------
csys,1
nsel,s,loc,x,radau
esln
emodif,all,type,3
sf,all,inf
csys,0
allsel

!---Symmetrieachse----
nsel,s,loc,x,0
d,all,az,0
nsel,all

!------Kopplung-in-Wicklung, Primärwicklung wird Strom eingeprägt----
*do,i,1,wianz
asel,s,,,i
nsla,s,1
*get,nwi,node,,num,max
cp,i,volt,all
f,nwi,amps,strom
*enddo
allsel

!------------------
/solu
antype,harmic
harfrq,freq
solve
!------------------
/post1
set,1,1
plf2d

/triad,off
/plopts,minm,0

!-----Induktivität berechnen primär------
pi=3.1415
esel,s,mat,,2
*get,eanz,elem,,count
etable,az,a,z
etable,radius,cent,x
smult,ephi,az,radius,2,pi
ssum
*get,phisum,ssum,,item,ephi
phimit=phisum/eanz
l1=phimit*wianz/strom

!-----Koppelinduktivität berechnen------
pi=3.1415
esel,s,mat,,3
*get,eanz,elem,,count
etable,az,a,z
etable,radius,cent,x
smult,ephi,az,radius,2,pi
ssum
*get,phisum,ssum,,item,ephi
phimit=phisum/eanz
l21=phimit*wianz2/strom



!------Kopplung-in-Wicklung, Sekundärwicklung wird Strom eingeprägt----

!Stromeinprägung primär auf Null setzen
/solu
!esel,s,type,,2
!bfedele,all,all

*do,i,1,wianz
asel,s,,,i
nsla,s,1
*get,nwi,node,,num,max
cp,i,volt,all
f,nwi,amps,0
*enddo
allsel


!Stromeinprägung sekundär
*do,i,wianz+1,wianz+wianz2
asel,s,,,i
nsla,s,1
*get,nwi,node,,num,max
cp,i,volt,all
f,nwi,amps,strom
*enddo
allsel
!------------------
/solu
antype,harmic
harfrq,freq
solve
!------------------
/post1
set,1,1
plf2d

/triad,off
/plopts,minm,0


!-----Induktivität berechnen sekundär------
pi=3.1415
esel,s,mat,,3
*get,eanz,elem,,count
etable,az,a,z
etable,radius,cent,x
smult,ephi,az,radius,2,pi
ssum
*get,phisum,ssum,,item,ephi
phimit=phisum/eanz
l2=phimit*wianz2/strom

!----- Koppelinduktivität berechnen ------
pi=3.1415
esel,s,mat,,2
*get,eanz,elem,,count
etable,az,a,z
etable,radius,cent,x
smult,ephi,az,radius,2,pi
ssum
*get,phisum,ssum,,item,ephi
phimit=phisum/eanz
l12=phimit*wianz/strom


!----- Kopplung berechnen ------
k=l12/sqrt(l1*l2)
k=l21/sqrt(l1*l2)