DEFINE Loesche_leere_teile
  LOCAL Zaehler
  LOCAL Gesamt
  LOCAL Zeile
  LOCAL Suchpos
  LOCAL Teilename
  LOCAL Elements
  LOCAL Durchlauf
  LOCAL Jn
  LOCAL J
  LOCAL I
  LOCAL N
  LET J 'j'
  LET N 'n'
  LOOP
    READ STRING
    'Zeichnung gesichert? Wenn ja, dann Bereinigen starten mit "j" (j/n)' Jn
  EXIT_IF (((LWC Jn)='j') OR ((LWC Jn)='n'))
    BEEP
  END_LOOP
  IF ((LWC Jn)='j')
    CHANGE_GLOBAL_INFO 'PDP*' '' END
    LET Durchlauf 0
    LET Gesamt 0
    REPEAT
      LET Durchlauf (Durchlauf+1)
      LET Zaehler 0
      EDIT_PART TOP
      CREATE_LTAB 'TMPLTAB'
      PARTS_LIST TREE LTAB 'TMPLTAB'
      LET I 1
      WHILE (I <= (LTAB_ROWS 'TMPLTAB'))
        LET Zeile (READ_LTAB 'TMPLTAB' I 1)
        LET Suchpos (POS Zeile '[~')
        LET Teilename (SUBSTR Zeile (Suchpos+1) ((LEN Zeile) - Suchpos))
        LET Teilename (SUBSTR Teilename 1 ((POS Teilename ']') -1))
        EDIT_PART Teilename
        INQ_SELECTED_ELEM SELECT ALL CONFIRM
        LET Elements (INQ 14)
        IF (Elements=0)
          DELETE ALL CONFIRM
          LET Zaehler (Zaehler+1)
          LET Gesamt (Gesamt+1)
          EDIT_PART PARENT
        END_IF
        LET I (I+1)
      END_WHILE
      DELETE_LTAB 'TMPLTAB'
    UNTIL ((Zaehler=0) OR (Durchlauf>20))
    EDIT_PART TOP
    BEEP
    DISPLAY ('Teilebaum '+STR Durchlauf+' mal durchlaufen, '+STR Gesamt+' Teile gelÎscht!')
  END_IF
END_DEFINE