abma=20e-3		!Abmessung Aussen
rand=4e-3		!Rand

/prep7
et,1,mesh200,6		!Hilfselement für die Vernetzung
et,2,solid70

!----Materialvereinbarung-----
mp,kxx,1,54
mp,dens,1,7850
mp,c,1,461

!-----Erstellung der Geometrie------

k,1,0,0,0
k,2,abma,0,0
k,3,0,abma,0
k,4,abma,abma,0

k,5,rand,rand,0
k,6,rand,abma-rand,0
k,7,abma-rand,rand,0
k,8,abma-rand,abma-rand,0

a,1,3,6,5
a,1,2,7,5
a,3,6,8,4
a,2,4,8,7
a,5,7,8,6
aglue,all

!-----Vernetzung der Fläche----------

lesize,3,,,120
lesize,7,,,120
lesize,12,,,120
lesize,5,,,120
lesize,11,,,120
lesize,10,,,120
lesize,1,,,120
lesize,8,,,120
lesize,2,,,10,0.2
lesize,9,,,10,5
lesize,6,,,10,0.2
lesize,4,,,10,5
type,1
amesh,all

!-----Netz um 0.005 in die Tiefe extrudieren mit 5 Elementen----

abmz=1e-3		!Abmessung in die Z-Richtung
esize,,5
type,2
mat,1
vext,all,,,,,-abmz
aclear,all			!Hilfselemente löschen

r=(4.07e9*0.12)		!Wärmestromdichte mit der Absorption multipliziert

vv=7.5e-5		!Vorschubweg    0.075mm
spu=1.5e-4		!Spurabstand

finish
/config,nres,30000

/solu
antype,trans
kbc,1
tunif,293
time,1e-12
outres,all,all
solve

time,0.0001
Spur=1
*do,n,0,Spur

!----Schleife zum Einschalten des Laserpuls----

time,(0.0005+(n*2.56))
Pulse=127
*do,i,0,Pulse

time,(0.0005+(i*0.01)+(i*2.56))
sfdele,all,all,all
local,11,1,(0.005+(i*vv)),(0.015-(2*n*spu)),0,0,0,0
nsel,s,loc,x,0,0.00025
nsel,r,loc,z,0
sf,all,hflux,r
nsub,1
allsel
outres,all,all
solve

!-----Ausschalten des Laserpuls-----

time,(0.001+(i*0.01)+(n*2.56))
sfdele,all,all,all
nsub,9
allsel
outres,all,all
solve
*enddo

!----Schleife zum Einschalten des Laserpuls für die Rückbahn----

time,(1.2815+(n*2.56))
*do,i,0,Pulse
time,(1.2815+(n*2.56)+(i*0.01))
sfdele,all,all,all
local,11,1,(0.0146-(i*vv)),(0.0148485-(2*n*spu)),0,0,0,0
nsel,s,loc,x,0,0.00025
nsel,r,loc,z,0
sf,all,hflux,r
nsub,1
allsel
outres,all,all
solve

!----Ausschalten des Laserpuls Rückbahn----

time,(1.282+(i*0.01)+(n*2.56))
sfdele,all,all,all
nsub,9
allsel
outres,all,all
solve
*enddo
*enddo