! offene Leiterschleife in einem
! homogenen Magnetfeld

finish
/clear

/filename,leiter
/title,Leiter in Magnetfeld

ri=0      ! Torus Radius innen
ra=0.01   ! Torus Radius außen
tr=0.5    ! Schleifenradius
ws=5      ! Startwinkel
we=355    ! Endwinkel

volx=1.5
voly=1.5
volz=1.5

Bz=0.001   !Flussdichte in z-Richtung

!------Modellerstellung-----------------
/prep7  
et,1,solid97  
et,2,solid97,1     !Rohr

!------Luft-------
mp,murx,1,1  
!------Rohr-------
mp,murx,2,1
mp,rsvx,2,1/58e6    !Kupfer

!----Geometrie-----
/view,,1,2,3

!------Luft-------
block,-volx,volx,-voly,voly,-volz,volz
!------Rohr-------
torus,ri,ra,tr,ws,we
vovlap,all
numcmp,volu

!----Vernetzung----------------
type,2  $mat,2  !Rohr
mshape,1
esize,(ra-ri)/2
vmesh,1

type,1  $mat,1  !Luft
mshape,1
esize,volx/3
vmesh,2

!----Randbedingungen----
nsel,s,ext
*get,nanz,node,,count
*get,nmin,node,,num,min
narb=nmin

*do,i,1,nanz
  d,narb,ax,1*(-bz/2)*ny(narb),0  
  d,narb,ay,1*(+bz/2)*nx(narb),0  
 narb=ndnext(narb)
*enddo

!-----------------------------
allsel
/solu
antyp,harm
harfre,50
solve

!----------------------
/post1
set,1,1
esel,s,mat,,2

plns,b,sum

/wait,10
plns,volt