finish
/clear,start

/sys,mkdir C:\ANSYS\bolted_plate_strains\3D\sym\nocrack_plastic_lastgesteuert
/cwd,C:\ANSYS\bolted_plate_strains\3D\sym\nocrack_plastic_lastgesteuert
*set,JName,'3D_plastic_lastgesteuert_nocrack_sym'
/filname,JName,0

/title, Schraubenloch in Blechmitte, plastisch, lastgesteuert

!/unit,si

! Einheiten
! Masse        [kg]
! Längen       [mm]
! E-Modul      [N/mm²]
! Flächen      [mm²]
! Spannungen   [N/mm²]
! Querdehnzahl [-]


/VIEW,  1, -0.217341817295    , -0.872958677897    ,  0.436698615912
/ANG,   1,   35.1695878049
/REPLO

*ASK,t,Blechdicke (Default = 20 mm),20
*ASK,w,Blechbreite (Default = 260 mm),260
*ASK,l,Blechlänge (Default = 600 mm),600
*ASK,r,Durchmesser des Lochs (Default = 32 mm),32/2
*ASK,F,Aufbebrachte Spannung in N/mm² (Default = 3000),3000

C=0.001       !"2C = Höhe des Risses "

/Prep7

SMRTSIZE,off

!Elementauswahl
ET,1,solid45

!Material Eigenschaften
MP,EX,1,2.1e5
MP,ALPX,1,1.2E-5
MP,KXX,1,25.0
MP,DENS,1,7850.0
MP,PRXY,1,0.3
MP,C,1,600
MP,REFT,1,50
MP,HF,1,10

!## Spannungs-Dehnungs-Diagramm
TB,KINH,1,1,20
TBTEMP,  20.000000    ,   1
TBPT,,1.932953333E-03,405.920200
TBPT,,2.023295333E-02,405.920200
TBPT,,2.683295333E-02,444.266900
TBPT,,3.203295333E-02,464.157200
TBPT,,4.203295333E-02,500.435400
TBPT,,5.203295333E-02,526.501600
TBPT,,6.183295333E-02,548.949300
TBPT,,7.203295333E-02,567.335400
TBPT,,8.203295333E-02,581.840800
TBPT,,9.213295333E-02,594.250500
TBPT,,9.933295333E-02,601.005400
TBPT,,1.786329533E-01,651.473400
TBPT,,2.531329533E-01,702.834100
TBPT,,3.568329533E-01,753.399500
TBPT,,5.109329533E-01,828.107300
TBPT,,6.530329533E-01,884.099900
TBPT,,7.998329533E-01,940.558700
TBPT,,9.448329533E-01,998.436500
TBPT,,1.097632953E+00,1047.152600
TBPT,,1.239932953E+00,1086.608000

/AXLAB,X,Dehnung [-]
/AXLAB,Y,Spannung [N/mm^2]

TBPLOT,KINH,1

!Geometrie der Platte

*AFUN,deg

K,1,r,0,0
K,2,w/2,0,0
K,3,w/2,l/2,0
K,4,0,l/2,0
K,5,0,r,0


K,11,r,0,t
K,12,w/2,0,t
K,13,w/2,l/2,t
K,14,0,l/2,t
K,15,0,r,t

!Punkte werden zu Linien zusammengefasst
CSYS,0
L,1,2                                               !untere Linien z = 0
L,2,3
L,3,4
L,4,5

CSYS,1
L,5,1

CSYS,0                                               !obere Linien z = t
L,11,12
L,12,13
L,13,14
L,14,15

CSYS,1
L,15,11

L,1,11                                                 !vertikale Linien
L,2,12
L,3,13
L,4,14
L,5,15

!fürs Meshen erforderliche Unterteilung der Linien
LESIZE,1,,,w/15,3
LESIZE,2,,,l/20
LESIZE,3,,,w/20
LESIZE,4,,,l/15,0.5
LESIZE,5,,,r,0.1

LESIZE,6,,,w/15,3
LESIZE,7,,,l/20
LESIZE,8,,,w/20
LESIZE,9,,,l/15,0.5
LESIZE,10,,,r,0.1

LESIZE,11,,,1
LESIZE,12,,,1
LESIZE,13,,,1
LESIZE,14,,,1
LESIZE,15,,,1

!Fläche zur Beschreibung der Geometrie
AL,1,2,3,4,5
AL,6,7,8,9,10

AL,1,11,12,6
AL,2,12,13,7
AL,3,13,14,8
AL,4,14,15,9
AL,5,15,11,10

!Volumen zur Beschreibung der Geometrie
VA,1,2,3,4,5,6,7

!Lagerung an den unteren Rändern
!DA,3,UY,0
!DA,3,ROTX,0
!DA,3,ROTY,0
!DA,3,ROTZ,0
DA,3,SYMM
DA,6,SYMM

SFA,5,1,pres,-F           !Specifies surface loads on lines of an area.

!Zuweisung der Eigenschaften zu den Flächen
VATT,1,1,1

!Meshen
VSWEEP,1,1,2

ALLS

FINISH

/COM                  !Places a comment in the output
/OUTPUT,SCRATCH       !Redirects text output to a file or to the screen.


!Berechnung
/Solu

/nerr,5,99999999        !Limitiert die Anzahl von Warnungen pro Kommando

!geometrisch nichtlineare Berechnung
antype,static
solcontrol,on,on!Specifies whether to use optimized nonlinear solution
                !defaults and some enhanced internal solution algorithms

NROPT,AUTO          !Specifies the Newton-Raphson options in a static or
                    !full transient analysis.
                    !AUTO —  Let the program choose the option (default)

!AUTOTS,ON                                  !Use automatic time stepping.

NEQIT,50            !Specifies the max. number of equilibrium iterations
                    !for nonlinear analyses.

NLGEOM,ON

*ASK,N,Anzahl der Substeps (Voreingestellt sind 50 substeps),50
NSUBST,N                                        !Anzahl der Lastschritte

OUTPR,ALL
OUTRES,ALL,ALL

ALLSEL

SOLVE

SAVE

FINISH


!-----------------------------------------------------------------------
!-----------------------------------------------------------------------
!------------- Dehnungen und Spannungen in der Rissspitze --------------
!-----------------------------------------------------------------------
!-----------------------------------------------------------------------

/POST1

SET,First

PLNSOL,eppl,1,0,-1
/REPLOT

*DIM,epsilon,array,N,2,,,,,,

*DO,q1,1,N,1

       *GET,SY,NODE,1139,S,Y               !Spannungen in der Rissspitze
       *GET,EPS,NODE,1139,EPTO,Y            !Dehnungen in der Rissspitze

       *VFILL,epsilon(q1,1),data,EPS
       *VFILL,epsilon(q1,2),data,SY

       SET,NEXT

*ENDDO

PARSAV,ALL,C:\ANSYS\bolted_plate_strains\3D\sym\nocrack_plastic_lastgesteuert\spannung_t60_r32_w260,txt,



!-----------------------------------------------------------------------
!-----------------------------------------------------------------------
!------------- Ausgabe der Dehnungen über die Breite -------------------
!------------- Lage 1: y = L/2 -----------------------------------------
!------------- Lage 2: y = L/4 -----------------------------------------
!-----------------------------------------------------------------------
!-----------------------------------------------------------------------

/POST1

SET,First

PLNSOL,epel,1,0,-1
/REPLOT

*DIM,epsilon,array,25,10,N,,,,

*DO,q1,1,N,1

       *DO,q2,1,20,1

       !Pfad 1(y=0 und z=0)
       PATH,Pfad1,2,30,20
       PPATH,1,,r,0,0
       PPATH,2,,w/2,0,0
       PDEF,Pfad1,eppl,1
       PLPATH,Pfad1
       PRPATH,Pfad1
       *GET,Eps1,PATH,0,ITEM,Pfad1,PATHPT,q2
       *VFILL,epsilon(q2,1,q1),data,(F/N)*q1
       *VFILL,epsilon(q2,2,q1),data,q2*(((w/2)-r)/20)+r
       *VFILL,epsilon(q2,3,q1),data,Eps1

       !Pfad 2 (y=L/2 und z=0)
       PATH,Pfad2,2,30,20
       PPATH,1,,0,l/4,0
       PPATH,2,,w/2,l/4,0
       PDEF,Pfad2,eppl,1
       PLPATH,Pfad2
       PRPATH,Pfad2
       *GET,Eps2,PATH,0,ITEM,Pfad2,PATHPT,q2
       *VFILL,epsilon(q2,4,q1),data,Eps2

       !Pfad 3(y=0 und z=t)
       PATH,Pfad3,2,30,20
       PPATH,1,,r,0,t
       PPATH,2,,w/2,0,t
       PDEF,Pfad3,eppl,1
       PLPATH,Pfad3
       PRPATH,Pfad3
       *GET,Eps3,PATH,0,ITEM,Pfad3,PATHPT,q2
       *VFILL,epsilon(q2,5,q1),data,Eps2
       
       !Pfad 2 (y=L/2 und z=t)
       PATH,Pfad4,2,30,20
       PPATH,1,,0,l/4,t
       PPATH,2,,w/2,l/4,t
       PDEF,Pfad4,eppl,1
       PLPATH,Pfad4
       PRPATH,Pfad4
       *GET,Eps2,PATH,0,ITEM,Pfad4,PATHPT,q2
       *VFILL,epsilon(q2,6,q1),data,Eps2

       !Spannungen in der "Rissspitze"
       *GET,SY,NODE,1122,S,Y
       *GET,EPS,NODE,1122,EPTO,Y
       *VFILL,epsilon(1,7,q1),data,EPS
       *VFILL,epsilon(1,8,q1),data,SY
       
       *GET,SY,NODE,1139,S,Y
       *GET,EPS,NODE,1139,EPTO,Y
       *VFILL,epsilon(1,9,q1),data,EPS
       *VFILL,epsilon(1,10,q1),data,SY

       *ENDDO
       
       SET,NEXT

*ENDDO

PARSAV,ALL,C:\ANSYS\bolted_plate_strains\3D\sym\nocrack_plastic_lastgesteuert\epsilon_r36_t20_w260,txt,