//Datei: wt_dbox.dcl
//Dialogbox zum Programm 'Wtreppe.lsp'


wtreppe : dialog {
                    label = "WENDELTREPPENMODUL (c) 1997 Rainer Kuhn";
  : column {
   : row {
    : boxed_column {
      label = "Einstellungen";
                   : boxed_radio_column {
                     label = "Treppenrichtung:";
                     key ="richt"; 
                     : radio_button {
                       label = "rechtsdrehend";
                        key ="re";
                     }
                     : radio_button {
                        label = "linksdrehend";
                        value = "1";
                        key ="li";
                     }
                   }
                   : boxed_radio_column {
                      label = "Treppentyp:";
                      key ="trtyp";
                     : radio_button {
                     label = "Spindeltreppe";
                       key ="sp";
                        value = "1";
                     }
                     : radio_button {
                      label = "Wendeltreppe";
                       key ="wt";
                     }
                   }
                   : boxed_radio_column {
                   label = "Zeichnungsart:";
                     key ="znart"; 
                     : radio_button {
                      label = "mit Geländer";
                       key ="mg";
                       value = "1";
                     }
                     : radio_button {
                      label = "ohne Geländer";
                       key ="og";
                     }
                   }
  }
  : boxed_column {
    label = "Vorgabewerte";
                : edit_box {
                label = "Treppe Gesamthöhe     [cm]:";
                  key ="h";
                  value = "270";
                }
                : edit_box {
                label = "Treppe Durchmesser     [cm]:";
                  key ="d";
                  value = "200";
                }
                : edit_box {
                label = "Spindel/TrAuge Durchm.[cm]:" ;
                  key ="di";
                  value = "10";
                }
                : edit_box {
                 label = "Stufen-/Podestdicke     [cm]:" ;
                  key ="hs";
                  value = "5";
                }
                : edit_box {
                label = "Podestwinkel     [Grad]:" ;
                  key ="wpg";
                  value = "60";
                }
                : edit_box {
                label = "Geländerhöhe     [cm]:";
                  key ="hg";
                  value = "90";
                }
                : edit_box {
                label = "Steigungshöhe (*)     [cm]:"; 
                  key ="s0";
                  value = "18";
                }
  }
  : boxed_column {
    label = "Mittelpunkt";
                : button {
                  key ="pw"; label = "Punktwahl <";
                }
                : spacer_1
                : text {
                  label = "oder";
                }
                : text {
                  label = "Koordinaten:";
                }
                : edit_box {
                  key ="x"; label = "X :"; value = "0";
                }
                : edit_box {
                  key ="y"; label = "Y :"; value = "0";
                }
                : edit_box {
                  key ="z"; label = "Z :"; value = "0";
                }
    }
    
  : boxed_column {
        label = "Zeichnungsdaten      ";
      : boxed_column {
        label = "Treppenlayer";
                  : edit_box {
                  label = "Name   :";
                    key ="lname";
                    value = "treppe";
                  }
                  : edit_box {
                  label = "Farbe :";
                    key ="lfarb";
                    value = "40";
                  }
    }
//    : spacer_0
    : boxed_column {
      label = "Blockname für...";
                : edit_box {
                 label = "Stufen:";
                  key ="blnst";
                  value = "Stufe";
                }
                : edit_box {
                label = "Podest:";
                  key ="blnpo";
                  value = "Podest";
                }
  }
 }
}
//: spacer_1
: row {
 : boxed_column {
   label = "Berechnungsweg (optional)";
  : row {
               : boxed_radio_column {
                 key ="vorg1"; label = "Vorgabeoption1";
                  : radio_button {
                    key ="vew"; label = "eingeschlossener Winkel"; value = "1";
                    action = "(DVEW)";
                  }
                  : radio_button {
                    key ="vgt"; label = "Grundrißteilung";
                    action = "(DVGT)";
                  }
                  : radio_button {
                    key ="vtm"; label = "Treppenmaß (2s + a=) 63cm";
                    action = "(DVTM)";
                  }
              }
               : boxed_radio_column {
                    key ="vorg2"; label = "Vorgabeoption 2";
                     : text { label = "vorgegebener Winkel:"; }
                     : radio_button {
                       key ="anw"; label = "Antrittswinkel";
                       action = "(DANW)";
                     }
                     : radio_button {
                       key ="auw"; label = "Austrittswinkel"; value = "1";
                       action = "(DAUW)";
                     }
                 }
  }
  : boxed_column {
    label = "Optionale Vorgabewerte";
               : edit_box {
                 key ="weig"; value = "300";
                 label = "eingeschlossener Winkel (abs./ w > 0) [Grad]:";
               }
               : edit_box {
                 key ="gt"; value = "" ;
                 label = "Grundrißteilung (Stufen pro voller Wendelung):";
               }
               : edit_box {
                 key ="wang"; value = "0";
                 label = "Antrittswinkel (rel./ Bezug x-Achse) [Grad]:";
               }
               : edit_box {
                 key  ="waug"; value = "";
                 label = "Austrittswinkel (rel./ Bezug x-Achse) [Grad]:";
               }
  }
  : row {
               : boxed_radio_column {
                 key ="anp1"; label = "Anpassungsoption 1";
                  : text { label = "(*) Steigung:"; }
                  : radio_button {
                    key ="sgr"; label = "ggf.steiler"; value = "1";
                  }
                  : radio_button {
                    key ="skl"; label = "ggf.flacher";
                  }
               }
               : boxed_radio_column {
                 key ="anp2"; label = "Anpassungsoption 2";
                 : radio_button {
                   key ="ewfi"; label = "eingeschlossener Winkel fix"; value = "1";
                 }
                 : radio_button {
                   key ="agr"; label = "eing.Winkel/Auftritt ggf.groeßer";
                 }
                 : radio_button {
                   key ="akl"; label = "eing.Winkel/Auftritt ggf.kleiner";
                   }
              }
    }
  }
  : boxed_column {
    label = "Treppenvorschau mit Anpassungen";
                : button {
                  key ="vs"; label = "*Werte neu berechnen *";
                }
                : concatenation {
                         : text_part  { label = "Steigungshöhe            [cm]: ";}
                         : text_part  { key ="s"; label= "       ";}
                }
                : concatenation {
                         : text_part  { label = "Auftritt (Lauflinie)            [cm]: ";}
                         : text_part  { key ="a"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "Treppenmaß (2s+a)      [cm]: ";}
                         : text_part  { key ="trm"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "eing.Winkel (abs.)    [Grad]: ";}
                         : text_part  { key ="weig_vs"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "Grundrißteilung             : ";}
                         : text_part  { key ="gt_vs"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "Antrittswinkel (->x)   [Grad]: ";}
                         : text_part  { key ="wang_vs"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "Austrittswinkel (->x) [Grad]: ";}
                         : text_part  { key ="waug_vs"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "Anzahl Steigungen        : ";}
                         : text_part  { key ="anz"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "Anzahl Auftritte (Stufen)   : ";}
                         : text_part  { key ="anz1"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "Stufenwinkel           [Grad]: ";}
                         : text_part  { key ="wsg"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "Stufenlänge               [cm]: ";}
                         : text_part  { key ="ls"; label = "       ";}
                }
                : concatenation {
                         : text_part  { label = "Durchgangshöhe        [cm]: ";}
                         : text_part  { key ="hd"; label = "       ";}
                }
                : boxed_row {
                  label = "WARNMELDUNGEN";
                                  : text { key ="warn"; label = "       ";}
                }
          }
        }
      }
//      : spacer_1 
      ok_cancel_help;
    }