finish
/clear					!clear the current model in memory

/graphics,full			
				
KEYW,PR_SET,1   		
KEYW,PR_STRUC,1   			!Structural 
/GO 
!*  

/PREP7  				!Start Preprocessor
!*  
ET,1,185				!Element Type
KEYOPT,1,6,1 
!*  

!* 
ET,2,170				!Target Element 1
ET,3,174				!Contact Element 1

!Target Element 1 Properties
KEYOPT,2,2,1				!B.C. for rigid target nodes 

!Contact Element 1 Properties
KEYOPT,3,4,0				!Contact Detection
KEYOPT,3,5,3				!Auto Contact Offset Adjustment
KEYOPT,3,6,2				!Auto Contact Stiffness change
KEYOPT,3,9,1				!Initial penetration/Gap
KEYOPT,3,10,2				!Contact stiffness update
!*

TB,HYPE,1,1,1,NEO   			!Material Type

!Material Properties

TBDATA,1,3.77799012e+6,1.058e-10,   		

!Geometry of D fender

BLC4,0,-0.1,0.1,0.2,-0.35		
CYL4,0.1,0,0.1,90,0,-90,-0.35
VADD,1,2
AADD,13,16
AADD,12,15

BLC4,0.05,-0.05,0.05,0.1,-0.35		
CYL4,0.1,0,0.05,90,0,-90,-0.35
VADD,1,2
AADD,19,22
AADD,18,21
VSBV,3,4
VGEN,,1,,,,,-0.02,,,1

!Geometry of Cylinder

CYL4,0.366,.1,0.184,-180,0,-90,-0.4

!Meshing for D fender

MOPT,VMESH,MAIN
!*
VSEL,,VOLU,,1,,,1
VATT,1,,1,0,

LSEL,S,LINE,,25
LSEL,A,LINE,,37
LSEL,A,LINE,,7
LSEL,A,LINE,,5
LSEL,A,LINE,,17
LSEL,A,LINE,,15
LSEL,A,LINE,,18
LSEL,A,LINE,,8
LSEL,A,LINE,,12
LESIZE,ALL,0.008			!Element Size
VSWEEP,1

!Selection and Meshing for Cylinder(Rigid surface)/Target 1

REAL,3 
TYPE,2
ESIZE,0.01				!Element Size
ASEL,S,,,6,,,1
NSLA,S,1
ESLN,S,0
AMESH,6
TSHAP, QUAD				!Shape of Target Element

!Selection of Contact Surface 1

MAT,1					
TYPE,3
ASEL,S,,,4,,,1 
ASEL,A,,,14,,, 
NSLA,S,1
ESLN,S,0

ESURF
ESEL,ALL
ALLSEL
EPLOT 
!*

!Boundary conditions

DA,5,UY,
DA,5,UZ,


DA,6,ALL,


DA,11,UZ,

!Solution 
/SOLN

ANTYPE,0				!Static Analysis
		
NLGEOM,ON				!Large Deflection Effects On

OUTRES,ALL,ALL				!Output result for all Steps

!Displacement applied

DA,5,UX,0.025

NSUBST,10,100,10
SOLVE