finish
/clear

*ask,SUBSTEPS,Anzahl der Substeps?,10000

/config,nres,SUBSTEPS+100

/prep7
   et,1,beam188
   et,2,conta178
   et,3,combin14
   
   mp,ex,1,210000
   mp,nuxy,1,0.3
   mp,dens,1,7.8e-9
   
   keyopt,2,1,1         !Cylindrical Gap
   keyopr,2,2,4         !ohne Steifigkeit
   r,1,,0.025           !gesamtes Spiel = 50µm
   
   r,2,10e5
   
   sectype,1,beam,csolid
   secoffset,cent
   secdata,12/2
   
   sectype,2,beam,csolid
   secoffset,cent
   secdata,14/2
   
   n,1,0,0,0
   n,2,0,0,10
   n,3,0,0,20
   n,4,0,0,30
   n,5,0,0,32
   
   type,1
   secnum,1
   mat,1

   *DO,I,1,4,1     !Element 1-32: 32mm
      E,I,I+1
   *ENDDO
   
   type,1
   secnum,2
   mat,1
   
   n,6,0,0,40
   n,7,0,0,50
   n,8,0,0,60
   n,9,0,0,70
   n,10,0,0,80
   n,11,0,0,90
   n,12,0,0,100
   n,13,0,0,108
   
   *DO,I,5,12,1   !Element 33-108: 76mm
      E,I,I+1
   *ENDDO
   
   type,1
   secnum,1
   mat,1

   n,14,0,0,110
   n,15,0,0,120
   n,16,0,0,130
   n,17,0,0,140

   *DO,I,13,16,1  !Element 109-140: 32mm
      E,I,I+1
   *ENDDO
   
   type,2
   real,1
   n,208,0,0,60
   n,210,0,0,80
   e,208,8
   e,210,10
   
   nsel,s,,,8,10
   cerig,9,all,all
   nsel,all
   
   type,3
   real,2
   n,3081,10,0,60
   n,3082,0,10,60
   n,3101,10,0,80
   n,3102,0,10,80
   e,3081,8
   e,3082,8
   e,3101,10
   e,3102,10
   
   d,1,uz,,,,,rotz
   
   nsel,s,,,208,3102
      d,all,all
   nsel,all
   
   
   /view,,1,1,1
   /ang,1
   /rep
   eplot
finish

/solu
   antype,modal
   modopt,lanb,25
   mxpand,25
   
   *ask,p,Proceed?
   
   solve
finish

/post1
   set,first
   plnsol,u,sum,1,1
   set,list
   *ask,p,Proceed?
finish

/solu
   antype,trans
   trnopt,full
   eqslv,sparse
   
   nlgeom,on
   outres,nsol,all
   
   time,0.001
   f,17,fx,1000
   kbc,1
   nsubst,100,100,10
   solve
   
   time,0.101
   fdel,all,all
   kbc,1
   nsubst,SUBSTEPS,SUBSTEPS,SUBSTEPS
   solve
finish

/post26
   nsol,2,17,u,x,UX_at_node_17
   FILLDATA,3,,,,0.,20000/SUBSTEPS      !auf 20kHz "strecken"
   RESP,4,3,2,1
   
   xvar,1
   /axlab,x,Time [s]
   /axlab,y,DOF Amplitude [mm]
   plvar,2
   *ask,p,Proceed?   
   
   xvar,3	
   /axlab,x,Frequency [Hz]
   /axlab,y,DOF Amplitude
   plvar,4
   *ask,p,Proceed?
   
   /GROPT,LOGY,ON
   plvar,4
   
finish