*afun,deg

/UNITS,SI

/view,1,1,1,1

/PREP7


et,8,beam188

!Stahl:

mp,ex,1,2.06e11		  !E-Modul
mp,nuxy,1,0.3		    !Poisson-Zahl
mp,dens,1,7850	   	!Dichte

!---Welle

csys,0

local,40,0,0,0,0,0,0,270
esys,40

Pi=3.1415927

bsch=30/1000            !Scheibendicke [m]

lw=1090/1000            !Wellenlaenge [m]

ltw=(lw-3*bsch)/4       !Laenge der Wellenteilabschnitte zwischen Scheiben

!Eigenschaften der Wellenabschnitte:

dw=25/1000			        !Wellendurchmesser [m]

dw2=dw*dw

dw4=dw2*dw2

R,2,Pi*dw2/4,Pi*dw4/64,Pi*dw4/64,dw,dw
RMORE,0,0,0,0,0

!Eigenschaften der kleinen Scheiben:

dsk=115/1000    !Scheibendurchmesser [m]

dsk2=dsk*dsk

dsk4=dsk2*dsk2

R,222,Pi*dsk2/4,Pi*dsk4/64,Pi*dsk4/64,dsk,dsk
RMORE,0,0,0,0,0

!Eigenschaften der grossen Scheibe:

dsg=158/1000    !Scheibendurchmesser [m]

dsg2=dsg*dsg

dsg4=dsg2*dsg2

R,22,Pi*dsg2/4,Pi*dsg4/64,Pi*dsg4/64,dsg,dsg
RMORE,0,0,0,0,0

!Elementierung:

elw=25/1000      !Elementlaenge Welle

elzahlw=ltw/elw   !Anzahl der Wellenelemente (pro Abschnitt) 

!1. Wellenstueck

k,1,0,0,0
k,2,elw*elzahlw,,
k,3,0,1,1

sectype,1,beam,csolid,Welle
secdata,dw/2,20,3
secnum,1

l,1,2
latt,1,2,8,,3,,1

lesize,1,,,elzahlw
lmesh,1

!Grosse Scheibe:

k,4,ltw+bsch,0,0

sectype,2,beam,csolid,Scheibegross
secdata,dsg/2,20,3
secnum,2

l,2,4
latt,1,22,8,,3,,2

lesize,2,,,2
lmesh,2

!2.Wellenstueck

k,5,2*ltw+bsch,0,0

l,4,5
latt,1,2,8,,3,,1

lesize,3,,,elzahlw
lmesh,3

!Kleine Scheibe:

k,6,2*ltw+2*bsch,0,0

sectype,3,beam,csolid,Scheibeklein
secdata,dsk/2,20,3
secnum,3

l,5,6
latt,1,222,8,,3,,3

lesize,4,,,2
lmesh,4

!3. Wellenstueck

k,7,3*ltw+2*bsch,0,0

l,6,7
latt,1,2,8,,3,,1

lesize,5,,,elzahlw
lmesh,5

!Grosse Scheibe:

k,8,3*ltw+3*bsch,0,0

l,7,8
latt,1,22,8,,3,,2

lesize,6,,,2
lmesh,6

!4. Wellenstueck:

k,9,4*ltw+3*bsch,0,0

l,8,9
latt,1,2,8,,3,,1

lesize,7,,,elzahlw
lmesh,7


/eshape,1
eplot


!Randbedingungen:

nsel,s,loc,x,0
nsel,a,loc,x,lw
d,all,all,0
allsel

!Solution:

/solu

antype,modal

modopt,lanb,20

mxpand,20

solve

!Postprozessor:

/post1

set,list

set,,1

pldisp,2

anmode,10,.1