!Biegebalken mit Piezo-Sensor
!05.11.09

fini
/CLEAR

/UNITS,SI


/title, Biegebalken mit Piezo

/PREP7

!! Elementtyp auswählen
 
ET,1,SOLID45

!! Materialeigenschaften Balken (Stahl)

MP,EX,1,2.1E11		!Elastizitätsmodul in x-Richtung [N/m^2]
MP,NUXY,1,0.3		!Querkontraktionszahl xy-Richtung
MP,DENS,1,7.850E3	!Dichte [kg/m^3]


!! Erstellung der Geometrie

! Definition der geometrischen Parameter [m]

l=0.5			!Balkenlaenge
b=0.03			!Balkenbreite
h=0.005			!Balkenhoehe

lp=0.1			!Abstand Einspannung - Piezokante
bp=0.03			!Breite und Laenge des Piezos
hp=0.002		!Hoehe des Piezos

! Definiere die Balken-Geometrie 

BLOCK,0,l,-h/2,h/2,-b/2,b/2	!x1,x2,y1,y2,z1,z2

VATT,1,,1		!Material,Real,Type,Esys

vsel,none


! Definiere einen Piezo-Patch

ET,2,SOLID226,1001

!Materialeigenschaften Piezo PIC255
!Daten von PI

mp,dens,2,7800		!Dichte

tb,piez,2		!Material-Tabelle Piezoeigenschaften
tbdata,3,-7.15		!e13
tbdata,6,-7.15		!e23
tbdata,9,13.70		!e33
tbdata,14,11.90		!e52
tbdata,16,11.90		!e61


mp,perx,2,930		!eps11Sr
mp,pery,2,930
mp,perz,2,857		!eps33Sr

tb,anel,2		!Material-Tabelle anisotrop-elastische Eigenschaften: Steifigkeit c
tbdata,1,12.3e10,7.67e10,7.025e10
!tbdata,7,12.3e10,7.025e10		!->habe ich nicht im Datenblatt!
tbdata,12,9.711e10
tbdata,16,2.315e10
tbdata,19,2.226e10
tbdata,21,2.226e10



!Definiere Patch-Geometrie

BLOCK,lp,lp+bp,h/2,h/2+hp,b/2,-b/2

VATT,2,,2		!Material,Real,Type,Esys

vsel,all
vplot,all

!Verbinden der Balkenoberseite mit Piezounterseite

vglue,all

! Vernetzen
esiz,10e-3
vswe,all

!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!


!! Loesungsabschnitt

/SOLU
ANTY,TRANS

TRNOPT,FULL

OUTRES,all,all

!! Freiheitsgrade; 1. Einspannung


NSEL,S,LOC,X,0
D,ALL,ALL			!Knoten am linken Rand (0) auswaehlen für Einspannung


!! Freiheitsgrade; 2. Elektr. Spannung am Piezo freigeben (zu Beginn 0; soll berechnet werden)

/com,Elektroden oben und unten
esel,s,type,,2
nsle
nsel,r,loc,y,h/2
d,all,volt,0
nsle
nsel,r,loc,y,h/2+hp
cp,next,volt,all
ALLS

!! Kraft auf Balkenende aufbringen (annähernd harmonisch durch Stufenlast)



NSEL,S,LOC,X,l-0.005,l
NSEL,R,LOC,Y,h/2

TIMINT,On

!Lastschritt 1: linearer Anstieg der Kraft auf 100N in 1s

TIME,1

DELTIM,0.005

F,all,FY,100		

KBC,0

outres,all,all

lswrite,1

lsclear,all




!Lastschritt 2: linearer Abfall der Kraft auf -100N während 2s

TIME,3

DELTIM,0.005

F,all,FY,-100

KBC,0

outres,all,all

lswrite,2

lsclear,all




!Lastschritt 3: linearer Anstieg der Kraft auf 100N während 2s

TIME,5

DELTIM,0.005

F,all,FY,100

KBC,0

outres,all,all

lswrite,3

lsclear,all



!Lastschritt 4: linearer Abfall der Kraft auf -100N während 2s

TIME,7

DELTIM,0.005

F,all,FY,-100

KBC,0

outres,all,all

lswrite,4

lsclear,all



!Lastschritt 5: linearer Anstieg der Kraft auf 0N während 1s

TIME,8

DELTIM,0.005

F,all,FY,0

KBC,0

outres,all,all

lswrite,5

lsclear,all

save




lssolve,1,5










/POST26


NSOL,2,NODE(l,h/2,0),U,Y
NSOL,3,NODE(lp+bp/2,h/2+hp,0),VOLT

/AXLAB,Y,Verschiebung und el Spannung
/GRTYP,2
PLVAR,2,3

!/POST1

!path,position,2,,100
!ppath,1,,0,h/2
!ppath,2,,l,h/2
!pdef,UY,u,y
!plpath,UY