!Piezo_Aktor
!15.11.2011

*afun,deg

/UNITS,SI

/view,1,1,1,1

/PREP7

!Elementtyp:
et,1,solid5,3

!Material: Piezokeramik (PIC255):

tb,piez,1		      !Material-Tabelle Piezoeigenschaften
tbdata,3,-7.15		!e13
tbdata,6,-7.15		!e23
tbdata,9,13.70		!e33
tbdata,14,11.90		!e52
tbdata,16,11.90		!e61

EMUNIT,epzro,8.85e-12 	!define free-space permittivity
mp,perx,1,930		        !eps11Sr
mp,pery,1,930
mp,perz,1,857		        !eps33Sr

!Material-Tabelle anisotrop-elastische Eigenschaften: Steifigkeit c
tb,anel,1		
tbdata,1,12.3e10,7.67e10,7.025e10
tbdata,7,12.3e10,7.025e10		
tbdata,12,9.711e10
tbdata,16,2.315e10
tbdata,19,2.226e10
tbdata,21,2.226e10

!Geometrie:

block,5,-5,10,-10,1,-1

!Elementierung

lsel,s,line,,1,3,2
lsel,a,line,,6,8,2

lesize,all,,,10

allsel

lsel,s,line,,2,4,2
lsel,a,line,,5,7,2

lesize,all,,,5

allsel

lsel,s,line,,9,12

lesize,all,,,1

allsel

!Vernetzung:

vsweep,1

!Kopplung:

nsel,s,loc,z,1

cp,1,volt,all

allsel

*get,Aktor,node,0,num,min     !Definiere Knoten fuer Signaleingang

nsel,s,loc,z,-1

cp,2,volt,all

allsel

!Grounden und Festhalten der Hinterseite

nsel,s,loc,z,-1

d,all,all,0

allsel

/solu

antype,trans

trnopt,full           !transient analysis option: full method

alpha=0.25
delta=0.5
theta=0.5

tintp,,alpha,delta,theta  !Transient integration parameters (notw. bei Piezos)

!Belastung aufbringen:

!Frequenz

om=30.

!Elektrische Spannung (Stellgroesse)

vmax=0.5e-3            !Betrag Volt (max.)
 
!Lastschritt-Tabelle:

tend=0.2              !Endzeit [s]

schritte=100          !Anzahl der Zeitinkremente

dt=tend/schritte      !Zeitdelta (1 Inkrement)

*dim,volts,table,schritte,1

*do,s,1,schritte
  volts(s,0)=s*dt
  volts(s,1)=vmax*sin(om*s*dt)
*enddo 

*do,s,1,schritte
  time,dt*s+1e-12
  d,Aktor,volt,volts(dt*s)
  allsel
  solve
*enddo

allsel

/post26

nsol,2,Aktor,u,y,uy          !Verschiebungen
nsol,3,Aktor,u,x,ux
realvar,4,2,,,uyr           !Realteil von der Verschiebung 
realvar,5,3,,,uxr
prod,6,4,4,,uyr_2           !Quadrat des Realteils der Verschiebung
prod,7,5,5,,uxr_2
add,8,6,7,,uyr_2+uxr_2      !Addiere die Quadrate
sqrt,9,8,,,Verschiebung [m] !Wurzel ziehen

nsol,10,Aktor,volt,z,Spannung [V]

/gropt,ascal,on
/grtyp,2                    !2-y-Achsen
/gthk,curve,1               !duenne Kurvenlinien

/axlab,x,Zeit [s]                           !Bezeichnung x-Achse
/axlab,y,Auslenkung [m] & el Spannung [V]   !Bezeichnung y-Achse

plvar,9,10