!Kragarm (Balken) mit aufgeklebtem Piezo

fini
/CLEAR

/UNITS,SI


/title, Biegebalken mit Piezo

/PREP7

!! Elementtyp auswählen
 
ET,1,SOLID45

!! Materialeigenschaften Balken (Stahl)

MP,EX,1,2.1E11		!Elastizitätsmodul in x-Richtung [N/m^2]
MP,NUXY,1,0.3		!Querkontraktionszahl xy-Richtung
MP,DENS,1,7.850E3	!Dichte [kg/m^3]


!! Erstellung der Geometrie

! Definition der geometrischen Parameter [m]

lB=0.5			!Balkenlaenge
bB=0.03			!Balkenbreite
hB=0.005		!Balkenhoehe

lP=0.03			!Abstand Einspannung - Piezokante
bP=0.03			!Breite und Laenge des Piezos
hP=0.002		!Hoehe des Piezos

lK=0.05			!Abstand Einspannung - Beginn Piezo

! Definiere die Balken-Geometrie 

BLOCK,0,lB,-hB/2,hB/2,-bB/2,bB/2	!x1,x2,y1,y2,z1,z2

VATT,1,,1		!Material,Real,Type,Esys

vsel,none


! Definiere einen Piezo-Patch

!ET,2,SOLID226,1001
ET,2,SOLID5

!Materialeigenschaften Piezo PIC255
!Daten von PI

mp,dens,2,7800		!Dichte

tb,piez,2		!Material-Tabelle Piezoeigenschaften
tbdata,3,-7.15		!e13
tbdata,6,-7.15		!e23
tbdata,9,13.70		!e33
tbdata,14,11.90		!e52
tbdata,16,11.90		!e61


mp,perx,2,930		!eps11Sr
mp,pery,2,930
mp,perz,2,857		!eps33Sr

tb,anel,2		!Material-Tabelle anisotrop-elastische Eigenschaften: Steifigkeit c
tbdata,1,12.3e10,7.67e10,7.025e10
tbdata,7,12.3e10,7.025e10		!->habe ich nicht im Datenblatt!
tbdata,12,9.711e10
tbdata,16,2.315e10
tbdata,19,2.226e10
tbdata,21,2.226e10



!Definiere Patch-Geometrie

BLOCK,lK,lK+lP,hB/2,hB/2+hP,bP/2,-bP/2

VATT,2,,2		!Material,Real,Type,Esys

vsel,all
vplot,all

! Netzgenerierung

/VIEW,,1,1,1
/PNUM,LINE,1
LPLOT


LESIZE,11,,,2			!Balkenbreite
LESIZE,5,,,50			!Balkenlänge
LESIZE,6,,,2			!Balkenhöhe
LESIZE,18,,,2			!Piezohöhe
LESIZE,17,,,3			!Piezolänge
LESIZE,22,,,2			!Piezobreite

VMESH,1				!Vernetzen des Balkens
VMESH,2				!Vernetzen des Piezos

!Kontaktbedingungen 


allsel

ET,3,TARGE170			!fuer solid5 und solid45
ET,4,CONTA173

 !Targetoberflaechen (Balken)

VSEL,S,VOLU,,1
ASEL,S,loc,y,hB/2
ASEL,R,loc,x,0,lB
ASEL,R,loc,z,-bB/2,bB/2
ESLA
TYPE,3
ESURF


  !Kontaktoberflaechen (Piezo)

ALLSEL
VSEL,S,VOLU,,2
ASEL,S,LOC,y,hB/2 	
ESLA
TYPE,4
ESURF


vsel,s,1			!Balken
nsel,s,loc,y,hB/2
CM,Balkenklebeflaeche,node
 
allsel

vsel,s,2			!Piezo
nsel,s,loc,y,hB/2
CM,Piezoklebeflaeche,node


nsel,all
gcgen,Balkenklebeflaeche,Piezoklebeflaeche
gcgen, Piezoklebeflaeche, Balkenklebeflaeche	!Symmetrische Kontaktflaeche