finish
/clear,nostart
/clear

/PREP7
SMRTSIZE,OFF
ANTYPE,STATIC

!____Parameter
r=10    ![mm]

ndiv=300
spaced=50

!____Elementdefinition
ET,1,PLANE183,,,3
R,2,3
MP,EX,1,210e3
MP,NUXY,1,0.3
ET,2,TARGE169
ET,3,CONTA172,,,,,3

!____Geometrieeingabe Zylinder 1
LOCAL,11,1,,r+0.5+0.001
K,1
K,2,r,0
K,3,r,-90

A,1,2,3

LSEL,S,LINE,,3
LESIZE,ALL,,,ndiv,spaced
ALLSEL
LSEL,S,LINE,,2
LESIZE,ALL,,,ndiv,1/spaced
ALLSEL

MAT,1
REAL,2
MSHK,1
MSHA,0,2D
AMESH,ALL

!____Geometrieeingabe Ebene
CSYS
K,4
K,5,r
K,6,r,0.5
K,7,0,0.5

A,4,5,6,7

LSEL,S,LINE,,7
LESIZE,ALL,,,0.5/r*ndiv*3
ALLSEL

LSEL,S,LINE,,6
LESIZE,ALL,,,ndiv,1/spaced
ALLSEL
LSEL,S,LINE,,4
LESIZE,ALL,,,ndiv,spaced
ALLSEL

MSHK,1
MSHA,0,2D
AMESH,ALL

!____Eingabe der Kontaktelemente (Ebene)
LSEL,S,,,6             !Auswahl der Kontaktlinie
NSLL,,1                !Auswahl der Knoten auf der Kontaktlinie
CM,CYL1,NODE
TYPE,3
REAL,1
ESURF
ALLSEL

!____Eingabe der Kontaktelemente (Zylinder)
LSEL,S,,,2             !Auswahl der Kontaktlinie
NSLL,,1                !Auswahl der Knoten auf der Kontaktlinie

TYPE,2
REAL,1
ESURF
ALLSEL

!____Symmetrieingabe
CSYS
NSEL,S,LOC,Y,r+0.5+0.001-1e-10,r+0.5+0.001+1e-10
CP,NEXT,UY,ALL
NSEL,R,LOC,X
*GET,NC,NODE,0,NUM,MIN
ALLSEL

NSEL,S,LOC,X
DSYM,SYMM,X
ALLSEL

NSEL,S,LOC,Y
D,ALL,UY
ALLSEL
FINISH
!____Solution
/SOLU
F,NC,FY,-500
!NSUBST,10
ALLSEL

SOLVE

!____Postprocessing
/POST1

lsel,s,line,,3
nsll,s,1

*get,anz,node,0,count
*dim,ergeb,array,anz,9
ergeb(1,1)=node(0,0.5,0)
ergeb(1,2)=NY(ergeb(1,1))
*Get,ergeb(1,3),NODE,ergeb(1,1),S,Y
*Get,ergeb(1,4),NODE,ergeb(1,1),S,X
*Get,ergeb(1,5),NODE,ergeb(1,1),S,XY
*Get,ergeb(1,6),NODE,ergeb(1,1),S,EQV
*Get,ergeb(1,7),NODE,ergeb(1,1),S,1
*Get,ergeb(1,8),NODE,ergeb(1,1),S,2
*Get,ergeb(1,9),NODE,ergeb(1,1),S,3
*do,i,2,anz
    ergeb(i,1)=nnear(ergeb((i-1),1))
     nsel,u,,,ergeb((i-1),1)
*enddo
*do,i,3,anz,2
    ergeb(i,2)=NY(ergeb(i,1))
    *Get,ergeb(i,3),NODE,ergeb(i,1),S,Y
    *Get,ergeb(i,4),NODE,ergeb(i,1),S,x
    *Get,ergeb(i,5),NODE,ergeb(i,1),S,XY
    *Get,ergeb(i,6),NODE,ergeb(i,1),S,EQV
    *Get,ergeb(i,7),NODE,ergeb(i,1),S,1
    *Get,ergeb(i,8),NODE,ergeb(i,1),S,2
    *Get,ergeb(i,9),NODE,ergeb(i,1),S,3

*enddo
allsel

*mwrite,ergeb(1,1),spannungen_%ndiv%_%spaced%,txt,,ji,9,anz
(X,f12.5,X,f12.5,X,f12.5,X,f12.5,X,f12.5,X,f12.5,X,f12.5,X,f12.5,X,f12.5)

FINISH