finish  
/clear
!/filname , 
/title ,3D; N 40; Leiterpl. CU 2[mm]; Luftspalt 7[mm]; [16Doc]


!--------Geometrieparameter------------------

!--------Magnetparameter [m]--------------

ag=0.007			![m] Luftspalt

xm=0.04				![m] Magnet x-Richtung
ym=0.023			![m] Magnet y-Richtung
zm=0.04				![m] Magnet z-Richtung

x1=ag/2				![m] magnet x1
x2=(ym/2)+ag/2			![m] magnet x2
y=xm/2				![m] magnet y
z=zm/2				![m] magnet z

!--------Geometrie Leiterplatte [l]--------------
xl=0.002			![m] Dicke der Leiterplatte			x
yl=0.08				![m] Länge in Bewegungsrichtung			y
zl=0.08				![m] Breite senkrecht zu Bewegungsrichtung	z 
kappa=56.8e6			![S/m] spez. Widerstand Kupfer
!kappa=3.6e7			![S/m] spez. Widerstand Aluminium

vy=-20				![m/s]Geschwindigkeit der Leiterplatte			!$$$$


!--------Geometrie Umgebung--------------
radius=0.06			![m] Radius-Kugel
mw=radius/5			![m] festlegen der Maschenweite			

			
!------Elementtypen & Elementrandbedingungen-------------
/prep7				 
et,1,solid97		!Luft	 solid97 für quasistationäre elektromagnetische Felder 
et,2,solid97		!Magnet	 solid97 für magnetischen Fluss 
et,3,infin111,1		!3D Generierung Randelementen
et,5,solid97,1,1	!elektrischer Leiter mit Geschwindigkeitsoption (Keypoint 1 und 2 für Velocity) 	!$$$$
		


!-------------Materialeigenschaften-------------
mp,murx,1,1		!Luft 		!--Permeabilität--

mp,murx,2,1.075		!Magnet N40 relative permeabilität	
mp,mgxx,2,-955000	!Magnetiesierungsrichtung--Koerzitivfeldstärke--

mp,murx,5,1			!elektrischer Leiter					!$$$$	
mp,rsvx,5,1/kappa	!leitfähigkeit						!$$$$


!------------Real Constant Definition---------------- 				!$$$$

R,5,				!Real Constante gilt für Elementtyp 5 (leiter)	!$$$$
RMORE, , , ,vy			!RMORE, , ,x,y,z Richtung der Bewegung		!$$$$

!------------Geometrie----------------

block,x1,x2,-y/2,y/2,-z/2,z/2		!magnet re		V1
block,xl/2,-xl/2,yl/2,-yl/2,yl/2,-yl/2	!elektr. Leiter		V2
sphere,radius				!Kugel modellieren Außen V3
vovlap,all				!3D bool'sche Operation					

numcmp,volume			!für systematische Nummerierung der verschnittenen Elemente


!-------------Vernetzung---------------------
!-----Magnet re ----------

type,2 $mat,2			!festlegen des Elementtyps $ Material
meshkey,0
esize,2e-3			!mittlere Vernetzungsgröße
vmesh,1				!zuordnung Geometrie V1

!-----elektr. Leiterplatte----------	
type,5 
mat,5 
real,5,										!$$$$			
esize,1e-3			!mittlere Vernetzungsgröße
vmesh,2	

!-----Luft----------
csys,2
asel,s,loc,x,radius
aesize,all,mw
allsel
type,1 $mat,1
meshkey,0			!freie Vernetzung
mshape,1,3D			!tetraeder Elementvernetzung 			!mittlere Vernetzungsgröße
vmesh,3				!zuordnung Geometrie


!------Randbedingungen der Grenzfläche Luft-------
csys,2					!setzen eines Kugel- Koordinatensystems
type,3					!infin111
esize,,1
asel,s,loc,x,radius
*get,anr1,area,,num,min			! heraussuchen der Umfangsflächen min
*get,anr2,area,,num,max			! heraussuchen der Umfangsflächen max
vext,anr1,anr2,,mw/2			! Außenfläche extrudieren, um 1/4 der Maschenweite

nsel,s,loc,x,radius+mw/4,radius+mw/2 	! Auswählen der Knoten am äußeren Radius (entlang des zyl. Koordinatensystem)
sf,all,inf				
csys,0					! kartesisches koordinatensystem


!----------Solution---------
/solu
allsel
solve