/// +-----------------------------------------------------------------+
/// | (c)2000 NigG @on's; Kög 42, 6600 Reutte, Österreich             |
/// | Tel.: +43-(0)5672-65913; Mobil: +43-(0)664-1356898              |
/// | eMail: nigg@eunet.at; URL: http://members.eunet.at/nigg/        |
/// +-----------------------------------------------------------------+
///
///
///

ddtuer : dialog {
  key = "label" ;
  : row {
    : boxed_column {
      label = "Vorschau " ;
	spacer_0 ;
      : image {
        key = "ddtprev" ;
        width = 20 ;
        aspect_ratio = 0.66 ;
        color = graphics_background ;
        fixed_width = true ;
        fixed_height = true ;
      }
	spacer_0 ;
    }
    : boxed_column {
      label = "Türmaße " ;
      : text {
        label = "*** Achtung: Lichte Durchgangsbreite pro Flügel! ***" ;
        key = "tbreite" ;
      }
      : edit_box {
        label = "Lichte &Durchgangsbreite [m]: " ;
        key = "lbreite" ;
        edit_limit = 10 ;
        edit_width = 10 ;
      }
      : popup_list {
        label = "&Standardlichten [m]:" ;
        key = "pop_lbreite" ;
        edit_width = 10 ;
      }
      spacer_1 ;
      : edit_box {
        label = "Lichte Durchgangs&höhe [m]: " ;
        key = "lhoehe" ;
        edit_limit = 10 ;
        edit_width = 10 ;
      }
      : row {
        : text {
          label = "Sturzhöhe [m]:     STUK. " ;
        }
        : text {
          key = "shoehe" ;
          width = 10 ;
          fixed_width = true ;
          alignment = right ;
        }
      }
      spacer_1 ;
      : edit_box {
        label = "&Zargenstärke [m]: " ;
        key = "sbreite" ;
        edit_limit = 10 ;
        edit_width = 10 ;
      }
    }
  }
  : row {
    : column {
      : boxed_column {
        label = "Türart " ;
        : toggle {
          label = "&ohne" ;
          key = "ohne_art" ;
        }
        : radio_column {
          key = "art" ;
          : radio_button {
            label = "&Einfach" ;
            key = "einfach" ;
          }
          : radio_button {
            label = "&Doppelt" ;
            key = "doppelt" ;
          }
        }
      }
      : boxed_column {
        label = "Türrahmen " ;
        : toggle {
          label = "&Zarge" ;
          key = "rahmen" ;
        }
      }
    }
    : boxed_column {
      label = "Türsturz " ;
      : toggle {
        label = "&Keiner" ;
        key = "ohne_sturz" ;
      }
      spacer_1 ;
      : radio_column {
        key = "sturz" ;
        : radio_button {
          label = "&Streiftüre" ;
          key = "nur_sturz" ;
        }
        : radio_button {
          label = "&Anschlag" ;
          key = "anschlag" ;
        }
        : radio_button {
          label = "&Doppelanschlag" ;
          key = "2_anschlag" ;
        }
      }
    }
    : boxed_column {
      label = "Optionen " ;
      : toggle {
        label = "&Beschreibung" ;
        key = "pos" ;
      }
      : boxed_row {
        label = "Beschreibungserweiterung " ;
        : toggle {
          label = "Positions&nummer" ;
          key = "pos50" ;
        }
        : toggle {
          label = "T&30" ;
          key = "t30" ;
        }
      }
      : toggle {
        label = "&Sturzhöhentext" ;
        key = "text" ;
      }
      : toggle {
        label = "&Raumgrenzlinie" ;
        key = "trenn" ;
      }
      spacer_1 ;
      : button {
        label = "&Einstellungen speichern" ;
        key = "optionen" ;
        width = 25 ;
        fixed_width = true ;
      }
    }
  }
  : row {
    : image {
      fixed_width = true ;
      fixed_height = true ;
      color = dialog_background ;
      width = 10 ;
      allow_accept = false ;
      aspect_ratio = 0.66 ;
      key = "nmlogo" ;
    }
    : spacer {
      width = 2 ; 
    }
    ok_cancel_help ;
  }
  errtile ;
}