!Fahrbahndecke mit Längs und Querbewehrung, Bewehrung als RUNDSTAHL
!Ausnutzung der Symmetrie 1/4 der Decke wird dargestellt.

finish
/clear
/filname,DECKE_V,1
/view,1,1,2,1
/prep7
et,1,solid70

!~~~~~allgemeine Einstellungen für Erstelleung der Geometrie~~~~~
FALL = 1						!1 ungerade,2 gerade
FALLQ= 1						!1 ungerade,2 gerade
!~~~~~Parameter für die Geometrie~~~~~
!-----Beton-----
BREITE  = 2.5						!Breite Betonblock
TIEFE   = 1.5						!Tiefe Betonblock
DICKE	= 0.2						!Dicke des Betons
!-----Bewehrung-----

!-----Laengsbewehrung-----
ANZAHLL	 = 15						!Anzahl der Laengsbewehrung
RADL     = 0.0075					!Radius des Bewehrungsstabes
SEITEL   = (2*RADL)/(SQRT(2)+1)				!Abmessung der Seite eines Achtecks
RANDL    = 0.05						!Randabstand
ABSTANDL = 1.4/14						!Abstand der Laengsbewehrung untereinander
ABSTANDOL= 0.08						!Abstand der Laengsbewehrung von der Oberflaeche

!-----Querbewehrung-----
ANZAHLQ	 = 9						!Anzahl der Laengsbewehrung
RADQ     = 0.0075					!Radius des Bewehrungsstabes
SEITEQ   = (2*RADQ)/(SQRT(2)+1)				!Abmessung der Seite eines Achtecks
RANDQ    = 0.05						!Randabstand
ABSTANDQ = 2.4/8					!Abstand der Laengsbewehrung untereinander
ABSTANDOQ= ABSTANDOL+RADL+RADQ				!Abstand der Laengsbewehrung von der Oberflaeche

!---------Materialeigenschaften---------
!-----Beton-----
mp,kxx,1,2.1						!Wärmeleitfähigkeit
mp,kyy,1,2.1						!Wärmeleitfähigkeit
mp,kzz,1,2.1						!Wärmeleitfähigkeit
mp,dens,1,2000						!Dichte
mp,c,1,900	
!-----Bewehrung-----
mp,kxx,2,52						!Wärmeleitfähigkeit
mp,kyy,2,52						!Wärmeleitfähigkeit
mp,kzz,2,52						!Wärmeleitfähigkeit
mp,dens,2,7800						!Dichte
mp,c,2,420						!spez. Wärmekapazität

!-----Geometrie-----
block,0,Breite/2,0,-DICKE,0,TIEFE/2

local,20,0,0,-ABSTANDOL,RANDL,,,90
wpcsys,,20
cylind,RADL,,BREITE/2,,90				!Erstellen der Bewehrung 
cylind,RADL,,BREITE/2,,90,180
cylind,RADL,,BREITE/2,,180,270
cylind,RADL,,BREITE/2,,270,360

*IF,FALL,EQ,1,THEN
	local,21,0,0,-ABSTANDOL,TIEFE/2,,,90
	wpcsys,,21
	cylind,RADL,,BREITE/2,,0,90			!Erstellen der Bewehrung 
	cylind,RADL,,BREITE/2,,270,360
	csys,0
	wpcsys,,0
	vsel,s,loc,z,RANDL-RADL,RANDL+RADL
	vgen,(ANZAHLL-1)/2,all,,,,,ABSTANDL
*ELSE
	csys,0
	wpcsys,,0
	vsel,s,loc,z,RANDL-RADL,RANDL+RADL
	vgen,ANZAHLL/2,all,,,,,ABSTANDL
*ENDIF

local,30,0,RANDQ,-ABSTANDOQ
wpcsys,,30
cylind,RADL,,TIEFE/2,,90				!Erstellen der Bewehrung 
cylind,RADL,,TIEFE/2,,90,180
cylind,RADL,,TIEFE/2,,180,270
cylind,RADL,,TIEFE/2,,270,360

*IF,FALLQ,EQ,1,THEN
	local,31,0,BREITE/2,-ABSTANDOQ
	wpcsys,,31
	cylind,RADL,,TIEFE/2,,90,180			!Erstellen der Bewehrung 
	cylind,RADL,,TIEFE/2,,180,270
	csys,0
	wpcsys,,0
	vsel,s,loc,x,RANDQ-RADQ,RANDQ+RADQ
	vgen,(ANZAHLQ-1)/2,all,,,ABSTANDQ
*ELSE
	csys,0
	wpcsys,,0
	vsel,s,loc,x,RANDQ-RADQ,RANDQ+RADQ
	vgen,ANZAHLQ/2,all,,,ABSTANDQ
*ENDIF