/BATCH
FINISH
/CLEAR
/UNITS,SI
/FILNAME, BoVe,1
/TITLE,Bolzenverbindung						
/COLOR,PBAK,1,3,5
/DEVICE,FONT,1,Calibri
/DEVICE,FONT,2,Calibri
/DEVICE,FONT,3,Calibri
/REPLOT

!############################
! Variable:

d1 	= 0.012		!Innendurchmesser Bolzen
d2 	= 0.024		!Außendurchmesser Bolzen = Innedurchmesser Buchse
d3 	= 0.030		!Außendruchmesser Buchse
F  	= 45322	
k1 	= 0.1		!(halbe) Kantenlängen
k2 	= 0.05
dic	= 0.25e-3	!Dicke der CFK-Lagen
n	= 8		!Anzahl der CFK-Lagen
a	= 0.01
b	= 0.025
c	= a+b
d	= 0.004
e	= a+b+d
g	= e+b

!############################

/PREP7

! 1. Geometrie
!#############

K,1,k1,k1,a
K,2,k1,-k1,a
K,3,-k1,-k1,a
K,4,-k1,k1,a

K,5,0,0,a

A,1,2,3,4
CIRCLE,5,d3/2
AL,5,6,7,8
ASBA,1,2
LCOMB,6,7,0
LCOMB,5,8,0

K,14,0,0,g
L,5,14
VDRAG,3,,,,,,7
nummrg,kp

K,19,k1,k1,c
K,20,-k1,k1,c
K,21,-k1,k1,e
K,22,k1,k1,e
K,23,k1,-k1,c
K,24,-k1,-k1,c
K,25,-k1,-k1,e
K,26,k1,-k1,e

V,19,20,21,22,23,24,25,26
VSBV,1,2
nummrg,kp

WPLANE,1,0,0,a
CYL4,0,0,d2/2,,d3/2,,b

WPLANE,2,0,0,e
CYL4,0,0,d2/2,,d3/2,,b

WPLANE,3,0,0,0
CYL4,0,0,d1/2,,d2/2,,g+a

nummrg,kp
NUMCMP,kp
NUMCMP,LINE
NUMCMP,AREA
NUMCMP,VOLU

WPLANE,4,0,0,e,0,0,0,0,1,e
VSEL,all
VSBW,all

VSEL,s,,,6
VSEL,a,,,8
VSEL,a,,,10
VSEL,a,,,12
VSEL,a,,,14

VDELE,all,,,1
allsel
vplot

nummrg,KP
NUMCMP,KP
NUMCMP,LINE
NUMCMP,AREA
NUMCMP,VOLU

WPSTYLE,,,,,,,,1	!Workingplane sichtbar machen
CSYS,4			!Koordinatensystem nach der WP ausrichten
WPRO,,,90.000000	!WP so drehen, dass die x-y-Ebene durch alle vorhandenen Volumen zeigt
WPRO,,,90.000000
WPRO,,90.000000
VSBW,all		!Volumen mit der WP teilen
CSYS,0			!zurück aufs globale Koordinatensystem
/REPLOT

! 2. Material, Elementtyp, RealConstants
!#######################################

MP,EX,1,210e9		!Stahl
MP,PRXY,1,0.3
MP,EX,2,116e9		!Bronze
MP,PRXY,2,0.3
MP,EX,3,77e9		!CFK (unidirektionale Schicht)
MP,EY,3,3.4e9
MP,PRXY,3,0.78
MP,Gxy,3,17.5e9
MP,EX,4,10e9		!Sperrholz
MP,PRXY,4,0.3

ET,1,SOLID95		!für Metall

ET,2,Shell91		!für Verbund
KEYOPT,2,8,1

ET,3,TARGE170		! für Zielflächen

ET,4,CONTA174		! für Kontaktflächen

R,1
R,2

R,3,6,0,,,,		
RMORE,,,,,
RMORE,3,45,dic,3,-45,dic
RMORE,3,45,dic,3,-45,dic
RMORE,3,45,dic,3,-45,dic
RMORE,3,45,dic,3,-45,dic

allsel
vplot

! 3. Einteilung der Linien für's Mesh up
!#######################################
LDELE,3

LSEL,s,,,28,35
LSEL,a,,,38,45
LSEL,a,,,23,25
LSEL,a,,,4,5
LSEL,a,,,7
LSEL,a,,,9
LSEL,a,,,12
LSEL,a,,,101,102
LSEL,a,,,108,109
LSEL,a,,,113,114
LSEL,a,,,120,121
LESIZE,all,,5,,,,,,1		!Radiale Elementgröße = 5°

LSEL,s,,,88,97
LSEL,a,,,80,83
LSEL,a,,,72,75
LESIZE,all,0.001	!Elementgröße über die Bolzen und Buchsendicken

LSEL,s,,,84,87
LSEL,a,,,46,47
LSEL,a,,,76,79
LSEL,a,,,68,71
LSEL,a,,,36,37
LSEL,a,,,26,27
LSEL,a,,,15,16
LSEL,a,,,20,21
LSEL,a,,,103
LSEL,a,,,115
LESIZE,all,0.001,,,,,,,1	! Elementgröße für Plattenbreite und Bolzenlänge

LSEL,s,,,18,19
LSEL,a,,,58,59
LSEL,a,,,48,49
LSEL,a,,,13,14
LSEL,a,,,100
LSEL,a,,,112
LESIZE,all,,,5,,,,,1

LSEL,s,,,104,105
LSEL,a,,,116,117
LESIZE,all,0.005,,,0.05	!Mittelinie

LSEL,s,,,60,63
LSEL,a,,,50,53
LESIZE,all,0.005,,,20,,,,1	!Linien der Symmetrieebene

allsel
lplot

! 4. Mesh-Up
!############
NUMCMP,AREA
NUMCMP,VOLU

VSEL,s,,,5,6		!Bolzen
TYPE,1
MAT,1
REAL,1
VSWEEP,all

VSEL,s,,,1,4		!Buchse
TYPE,1
MAT,2
REAL,1
VSWEEP,all

VSEL,s,,,7,10		!Sperrholz
TYPE,1
MAT,4
REAL,1

VSWEEP,7,1,44
VSWEEP,8,44,2
VSWEEP,10,6,53
VSWEEP,9,53,5

! 5. Bildung der Kontaktflächen
!##############################
 
! Bolzen / Buchse links:     	o24,u23	/ o19,u20
! Bolzen / Buchse rechts:	o24,u23	/ o13,u14
! Buchse / Platte links:	o18,u17 / o57,u52
! Buchse / Platte rechts:	o12,u11 / o43,u48

! 5.1. Kontaktpaar Platten/Buchsen

!Contact = Platte
ASEL,s,,,52
ASEL,a,,,57
ASEL,a,,,43
ASEL,a,,,48
NSLA,s,1
TYPE,4
MAT,4
REAL,1
ESURF

!Target = Buchse
ASEL,s,,,17,18
ASEL,a,,,11,12
NSLA,s,1
TYPE,3
MAT,2
REAL,1
ESURF

ALLSEL
RMODIF,1,7
RMODIF,1,8
KEYOPT,4,7,1	! Element level time incrementation control = automatic
KEYOPT,4,10,2	! Contact stiffness update
KEYOPT,4,12,3	! Bonded Kontakt (verklebt)

! 5.2. Kontaktpaar Buchsen/Bolzen

!Contact = Buchse
ASEL,s,,,13,14
ASEL,a,,,19,20
NSLA,s,1
TYPE,4
MAT,2
REAL,2
ESURF

!Target = Bolzen
ASEL,s,,,23,24
NSLA,s,1
TYPE,3
MAT,1
REAL,2
ESURF
ALLSEL

! 6. Randbedingungen, Kräfte
!###########################

NSEL,s,loc,x,0
DSYM,symm,x,0
allsel

ASEL,s,loc,y,k1
ASEL,u,loc,z,e
NSLA,s,1
D,all,all
ALLSEL

ASEL,s,loc,y,-k1
ASEL,u,loc,z,e
NSLA,s,1
D,all,all
ALLSEL

ASEL,s,loc,y,k1
ASEL,u,loc,z,e,0.5
NSLA,s,1
SF,all,pres,2*F/(45*b*k1)
ALLSEL
EPLOT
FINISH

! 7. Lösung
!##########

/SOLU
/PSF,PRES,2,0,on
/PBC,all,,1

ANTYPE,0
NLGEOM,on
AUTOTS,on
NSUB,10,100,5
OUTRES,all,all			!Alle Zwischenergebnisse speichern
RESCONTROL,define,all,all,0	!Dateien für einen Restart herausschreiben

SOLVE
finish
/POST1
finish
/eof


