fini  
/clear

pi=4*atan(1)			                   	!Kreiszahl Pi
muZero=pi*4e-7                        !Feldkonstante

!Daten Windung
turn=1
turnDia=5e-3                          !Durchmesser
turnArea=pi*(turnDia/2)**2            !Flaeche

turnRadius=5e-3
turnLength=2*pi*5e-3


I=10                                  !Strom
fmax=10e3                             !Frequenz
currDens=I/turnArea                   !Stromdichte

!Luft-Bereich
airIn=10e-3                           !Bereichs-Radius innen
airOut=2*airIn                        !Bereichs-Radius auáen

!Daten Kupfer
roCu=1/57e6                           !spezifischer Widerstand
murCu=1                               !relative permeabilitaet

resistanceDC=roCu*turnLength/turnArea
U=resistanceDC*I

!Netz
skinDepth=sqrt(roCu/(pi*fmax*muZero*murCu))
gridCu=skinDepth/3	                	!Maschenweite Spule


/prep7

et,1,plane53,,,1   			              !Luft
et,2,plane53,1,,1  			              !Leiter: DOF AZ und VOLT
!et,2,plane53,2,,1                    !Leiter: DOF AZ und CURR  
et,3,infin110,,,1			                !Randwert-Luft

r,2,turnArea,turn

mp,murx,1,1
mp,murx,2,murCu
mp,rsvx,2,roCu


CYL4,5e-3,0,turnDia/2
pcirc,0,airOut,-90,90
pcirc,0,airIn,-90,90
aovlap,all


mshape,0,2d
mshkey,0
esize,gridCu
mat,2 $type,2 $real,2 
amesh,1

!Windung-Freiheitsgrad-Kopplung
CP,1,VOLT,ALL
!CP,1,CURR,ALL                  

*get,turnNode,node,,num,min               

allsel
csys,1                                            
lsel,s,loc,x,airIn                              
lsel,a,loc,x,airOut                            
lesize,all,,,30                       
esize,,10                           
mat,1 $type,1 
amesh,4

allsel
mshape,0,2d
mshkey,0
esize,gridCu*5
mat,1 $type,1
amesh,5

nsel,s,loc,x,airOut
esln
emodif,all,type,3
sf,all,inf
csys,0
allsel
aplot

F,turnNode,amps,I                       
!F,turnNode,vltg,,U

allsel

/solu    
antype,harmic
harfrq,fmax
solve
finish

/POST1
SET,1,1                             
ETABLE,JE,NMISC,6                   
ESEL,MAT,2                         
PLETAB,JE,1