fini  
/clear

pi=4*atan(1)			                     	!Kreiszahl Pi
muZero=pi*4e-7                          !Feldkonstante

!Daten Windung
turn=1
turnDia=3.3e-3                          !Drahtdurchmesser
turnArea=pi*(turnDia/2)**2              !Querschnittsflaeche
turnRadius=turnDia/2                    !Drahtradius

disO=85e-3                              !Abstand zum Koordinatenursprung
turnlength=2*pi*disO                    !Drahtlaenge

I=1e3                                   !Strom
fmax=50                                 !Frequenz

!Luft-Bereich
airIn=100e-3                            !Bereichs-Radius innen
airOut=1.5*airIn                        !Bereichs-Radius auáen

!Daten Kupfer
roCu=1/57e6                             !spezifischer Widerstand
murCu=1                                 !relative permeabilitaet

!Referenz Windung
Rref=roCu*turnlength/turnArea

!http://www.circuits.dk/calculator_flat_spiral_coil_inductor.htm
!oder Tabellenbuch:Taschenbuch Elektrotechnik Band 1 Grundlagen(Eugen Philippow)
Lref=3.98e-7                            

!Netz
skinDepth=sqrt(roCu/(pi*fmax*muZero*murCu))
gridCu=turnDia/10	                   	!Maschenweite Spule


/prep7
et,1,plane53,,,1   			              !Luft
et,2,plane53,1,,1  			              !Leiter: DOF AZ und VOLT
et,3,infin110,,,1			                !Randwert-Luft


mp,murx,1,1
mp,murx,2,murCu
mp,rsvx,2,roCu


CYL4,disO,0,turnDia/2
pcirc,0,airOut,-90,90
pcirc,0,airIn,-90,90
aovlap,all


mshape,0,2d
mshkey,0
esize,gridCu
mat,2 $type,2 $real,2 
amesh,1

!Windung-Freiheitsgrad-Kopplung
CP,1,VOLT,ALL
*get,turnNode,node,,num,min               


allsel
csys,1                                            
lsel,s,loc,x,airIn                              
lsel,a,loc,x,airOut                            
lesize,all,,,20                       
esize,,4                           
mat,1 $type,1 
amesh,4

allsel
mshape,1,2d
mshkey,0
esize,gridCu*100
mat,1 $type,1
amesh,5

nsel,s,loc,x,airOut
esln
emodif,all,type,3
sf,all,inf
csys,0
allsel
aplot


F,turnNode,amps,I                     
allsel


/solu    
antype,harmic
harfrq,fmax
solve
finish
                        
!---------------Auswertung------
!--------------------------------------Realteil
/post1
set,last
plf2d

set,1,1      !Realteil
/plopts,minm,0
set,1,1 !real

!Induktivität uebers zeitint. potenzial berechnen
vr=volt(turnNode)
L=vr/I

dL=L-Lref

!----------Realteil der gesamt Energie
presol,elem
esel,all
etable,energie,sene
ssum
*get,sumener,ssum,,item,energie
energieRe=sumener


esel,s,mat,,2
etable,jtr,nmisc,7 !Stromdichtebetrag
pletab,jtr,avg


!-----------------------------------Imaginärteil
set,1,1,,1 
presol,elem

!Widerstand uebers zeitint. potenzial berechnen
vi=volt(turnNode)
R=-2*pi*fmax*vi/I

!----------Imaginärteil der gesamt Energie
esel,all
etable,energie,sene
ssum
*get,sumener,ssum,,item,energie
energieIm=sumener
esel,s,mat,,2
etable,jti,nmisc,7 !Stromdichtebetrag
pletab,jti,avg



!Induktivität ueber den Betrag der Energie berechnen
energieRe2=energieRe*energieRe
energieIm2=energieIm*energieIm
energie2=energieRe2+energieIm2
energieBetrag=energie2**0.5
Le=2*energieBetrag/(I)**2