finish
/clear,all
/filename,simple_campbell

pi = acos(-1)
R = 3.175e-3/2	!Radius
L = 18e-3 		!length

Kyy = 1e+6
Kzz = 1e+6
Kyz = -0.1e+6
Kzy = 0.1e+6
Cyy = 30
Czz = 30
Cyz = 10
Czy = -10			

!-------------Preprocessing-------------
/PREP7

	!-------------Geometry-------------
	k,1,0,0,0 	!creating key points to define geometry
	k,2,L,0,0
	k,3,L,R,0
	k,4,0,R,0
	a,1,2,3,4 	
	
	!-------------Material properties of tungsten carbide-------------
	MP,EX,1,6e+11 	!MAT,1
	MP,PRXY,1,0.31 
	MP,DENS,1,14950
	
	!-------------Element Types-------------
	ET,1,SOLID273,,3 	!TYPE,1 !with circumferential fourrier planes (max are 12, min are 3)
	
	!-------------Mesh-------------
	esize,L/10 			!length of element on boundary lines
	numstr,node,3
	
	TYPE,1
	MAT,1
	amesh,1 			!meshing area 1 with quads

	!-------------Symmetry Axis along x-------------	
	sectype,1,axis   
	secdata,1, 0,0,0, L,0,0
	
	naxis 						!ceating 3D model
	
	!-------------Selecting the rotating components-------------
	esel,,ename,,273 	!selecting all SOLID273 elements
	cm,Rotor,elem    	!creating Rotor component
	esel,all
	
	!-------------Bearings-------------
	ET,3,COMBI214!,,1,1 !TYPE,3  	!YZ-Plane and not symmetric
	
	r,3,Kyy,Kzz,Kyz,Kzy,Cyy,Czz $rmore,Cyz,Czy 	!relating real constant values REAL,1 (rmore for more than 6 values)
	
	n,1,0,5e-3,0 		!creating extra nodes to visualize bearing
	n,2,L,5e-3,0
	
	TYPE,3
	REAL,3
	e,node(0,0,0),1 		!creating bearing elements of TYPE 3 over two nodes
	e,node(L,0,0),2
	
	!-------------Boundary Conditions-------------
	d,all,UX 	!supress axial movement
	d,1,all 	!no movement at all for the bearing stators
	d,2,all  
	
	!-------------Solution-------------	
/SOLU
	
	antype,MODAL 
	modopt,QRDAMP,6,1.0,,on 	!QRDAMP eigensolver (10 modes) with complex eigenvalues = on 
	QRDOPT,on 						!reuse Block Lanczos eigenvectors from first loadstep (faster)
	CORIOLIS,on,,,on 				!stationary reference frame = on
	mxpand,6		 			!expand and write all modes
	
	cmomega,Rotor,1*2*pi
	solve
	cmomega,Rotor,1000*2*pi
	solve	
	cmomega,Rotor,3000*2*pi
	solve	
	
	finish
	save,simple_campbell,db
	
!-------------Results-------------	
/POST1

	cmsfile,clear 			!clear all previously added component results files
	file,simple_campbell,rst

	set,list 				!all rigid body modes have real part = 0 of the complex freq
	
	!-------------campbell diagramm-------------
	PLCAMP,1,1,rpm,,Rotor 	!plot with 1st order excitation
	PRCAMP,1,1,rpm,,Rotor 	!print