/PREP7
/TITLE, 2016-06-11, Konzentrische Leiter, Wirbelstromverluste, AZ=0 / SF=INF
ET,1,PLANE233                       ! PLANE233, AZ DOF, (FOR AIR)
ET,2,PLANE233,1                     ! PLANE233, AZ VOLT DOF, (FOR CONDUCTOR)
ET,3,PLANE233,1                     ! PLANE233, AZ VOLT DOF, (FOR CONDUCTOR)
ET,4,PLANE233                       ! PLANE233, AZ DOF, (FOR AIR)

ET,5,INFIN110,0,1					! INFIN110, AZ, 8-node quadrilateral

EMUNIT,MKS                          ! DEFINE SYSTEM UNITS

rc 		= 	3e-3 			! outer radius of axial conductor
ri		=	16.33e-3		! inner radius of coaxial conductor
ro		=	19.33e-3		! outer radius of coaxial conductor
Ipeak	=	100.0			! current of axial conductor
f		=	50				! frequency (Hz)
sigma	=	1.0e6			! material conductivity
mur		=	1			! material permeability
MP,MURX,1,1
MP,MURX,2,1
MP,RSVZ,2,1/sigma
MP,MURX,3,1
MP,RSVZ,3,1/sigma

k, 	1,     0, 0,    0	!	center of the circles -> PCENT
k, 10,  1e-3, 0,    0	!	Keypoint for zero degree location -> PZERO
k, 11,     0, 0, 1e-3 	! 	Keypoint defining axis of circle (along with PCENT) -> PAXIS
numstr, KP, 21
numstr, LINE, 21
circle, 1, rc, 11, 10, 360, 4 	! Sets KP 21-24 and Lines 21-24
numstr, KP, 31
numstr, LINE, 31
circle, 1, ri, 11, 10, 360, 4 	! Sets KP 31-34 and Lines 31-34
numstr, KP, 41
numstr, LINE, 41
circle, 1, ro, 11, 10, 360, 4	! Sets KP 41-44 and Lines 41-44
numstr, KP, 51
numstr, LINE, 51
circle, 1, ro+ro/2, 11, 10, 360, 4	! Sets KP 51-54 and Lines 51-54
numstr, KP, 61
numstr, LINE, 61
circle, 1, ro+ro, 11, 10, 360, 4	! Sets KP 61-64 and Lines 61-64
!rectng,-2*ro,2*ro,-2*ro,2*ro
!k, 61,  2*ro,  2*ro, 0		
!k, 62, -2*ro,  2*ro, 0
!k, 63, -2*ro, -2*ro, 0
!k, 64, 	2*ro, -2*ro, 0
!l, 61, 62,
!l, 62, 63,
!l, 63, 64,
!l, 64, 61,

AL, 21, 22, 23, 24 					! 	current-carrying conductor area -> AREA 1
AL, 21, 22, 23, 24, 31, 32, 33, 34 	! 	air area						-> AREA 2
AL, 31, 32, 33, 34, 41, 42, 43, 44 	! 	concentric conductor area		-> AREA 3
AL, 41, 42, 43, 44, 51, 52, 53, 54 	! 	air area						-> AREA 4
AL, 51, 52, 53, 54, 61, 62, 63, 64 	! 	infinite area					-> AREA 5

ASEL,S,AREA,,4
AATT,1,,4                           	! SET ATTRIBUTES FOR AIR
ASEL,S,AREA,,3   
AATT,3,,3                           	! SET ATTRIBUTES FOR CONDUCTOR
ASEL,S,AREA,,2
AATT,1,,1                           	! SET ATTRIBUTES FOR AIR
ASEL,S,AREA,,1   
AATT,2,,2                           	! SET ATTRIBUTES FOR CONDUCTOR

asel,all
lsel,s,line,,61,64,1
lsel,a,line,,51,54,1
lesize,all,,,8
mshape,0,2d          				! mapped mesh with quads
mshkey,2
amesh,5

lsel,s,line,,41,44,1
lesize,all,,,90
mshape,1,2d
mshkey,0
amesh,4

lsel,s,line,,31,34,1
lesize,all,,,90
mshape,0,2d
mshkey,2
amesh,3

lsel,s,line,,21,24,1
lesize,all,,,5
mshape,1,2d
mshkey,0
smrtsize,10
amesh,1,2

ESEL,S,MAT,,2                       	! SELECT ALL NODES IN CONDUCTOR
NSLE,S  
CP,1,VOLT,ALL                       	! COUPLE ALL NODES IN VOLT

*GET,AREA,AREA,1,AREA               	! GET AREA OF CONDUCTOR
*GET,N1,NODE,,NUM,MIN               	! SELECT A NODE IN THE CONDUCTOR
F,N1,AMPS,Ipeak

ESEL,ALL
NSEL,S,EXT
sf,all,inf           					! set infinite surface flag
!D,ALL,AZ,0                          	! SET FLUX PARALLEL B.C.

ESEL,S,MAT,,3                       	! SELECT ALL NODES IN CONDUCTOR
NSLE,S  
CP,2,VOLT,ALL                       	! COUPLE ALL NODES IN VOLT

ESEL,ALL
NSEL,ALL
FINISH

/SOLU    
ANTYPE,HARMIC                       	! HARMONIC ANALYSIS

HARFRQ,f
SOLVE
FINISH

/POST1
SET,1,1                             	! RETRIEVE REAL SOLUTION
ETABLE,JT,NMISC,1                   	! STORE TOTAL CURRENT DENSITY
ESEL,MAT,3                          	! SELECT COPPER ONLY
PLETAB,JT,1                         	! DISPLAY TOTAL CURRENT DENSITY

powerh