FINI
/CLEAR, NOSTART
/FILENAME, Bacherlorarbeit
/TITLE, Bacherlorarbeit

!================================ Materialparameter ================================

/prep7

! Elementtypen  
	ET, 1, SOLID185
	ET, 2, TARGE170, , 1
	ET, 3, CONTA174
	keyopt, 3, 10, 2
   
! Materialmodelle
  ! Bogen (MAT 1 - linear)
	MP, EX, 1, 31000000
	MP, PRXY, 1, 0.333
  ! Hinterfüllung (MAT 2 - nichtlinear)
	MP, EX, 2, 26670
	MP, PRXY, 2, 0.333
	TB, DP, 2, , , , 1
	TBDATA, 0, , 0.1, 30, 0
  ! Kontakte
	MP, MU, 3, 0.1

! Realconstants
	R, 1, , , 10
	R, 2, , , 10


!================================ Geometrievereinbarung ================================

! Maße
	a=2		!breite
	b=1		!höhe
	c=1		!länge

! Quader 1
	blc4, 0, 0, a, b, c

! Quader 2
	blc4, a/4, b, a/2, b, c


!======================================= Mesh =======================================

! Quader 1 (linear)
	type, 1
	mat, 1
	real, 1
	mshky, 1
	esize, 0.125
	vmesh, 1
	eplo

! Quader 2 (nichtlinear)
	type, 1
	mat, 2
	real, 1
	mshky, 1
	esize, 0.125
	vmesh, 2
	eplo

!===================================== Kontakte ==================================

!---die Kontakte werden doppelt definiert, aber mit vertauschtem Contact und Target
!dies ist wichtig um eine Übertragung in beide Richtungen gleichmäßig zu haben
!dabei bekommt jedes Paar eine eigene realkonstante

	asel, s, , , 4		!Quader 1 A4
	nsla, s, 1 	
	type, 2		!Target
	mat, 3
	real, 2
	esurf

	asel, s, , ,9		!Quader 2 A9
	nsla, s, 1
	type, 3		!Contact
	esurf
	allsel	
	
	asel, s, , , 4		!Quader 1 A4
	nsla, s, 1 	
	type, 3		!Contact
	mat, 3
	real, 3
	esurf

	asel, s, , , 9		!Quader 2 A9
	nsla, s, 1
	type, 2		!Target
	esurf
	allsel	

!================================ Randbedingungen ================================

	asel, s, , ,3
	nsla, s,1
	d, all, all
	allsel

!=============================== Solution-Einstellungen ============================

/solu

! Solution Controls
  ! BASIC
    ! Analysis Options
	ANTYPE, STATIC, NEW
    ! Time Control
      !Substeps (NSUBST, NSBSTP, NSBMX, NSBMN, Carry)
	NSUBST, 1, 10, 1, OFF
  ! NONLINEAR
    !Line search 
	LNSRCH, ON
  ! ADVANCED NL
    ! Termination Criteria
      !Behavior upon nonconvergence
	NCNV, 2

! weitere Einstellungen
	EQSLV, SPAR
	PRED, -1
	OUTRES, NSOL, LAST
	nlgeom, on		!nichtlineare Geometrie


!=============================== 1.Lastfall - Initialisierung ============================ 

	time, 1
	asel, s, , , 10		!der kontakt wird initialisiert durch eine kleine Verschiebung
	nsla, s, 1
	d, all, uy, -0.005
	allsel
	solve

	time, 2	
	asel, s, , , 10		!nach der ini wird die verschiebung gelöscht
	nsla, s, 1
	ddele, all, all
	allsel
	solve

!=============================== 2.Lastfall - Druck ============================ 

! Zeitspanne und -interval bestimmen
	TIME = 20
	TM_START = 3
	TM_END = 3+TIME
	TM_INCR = 1
	PRESSURE = 500
	PRESSURE_INCR = PRESSURE/TIME

! Schleife
	*DO,TM,TM_START,TM_END,TM_INCR
	 TIME,TM
	 asel, s, , , 10
	 nsla, s, 1
	 sf, all, pres, PRESSURE_INCR*TM
	 ALLSEL
	 SOLVE
	*ENDDO

allsel
eplo
solve

fini

!===================================== POSTPROC===============================

/POST1

PLNSOL, S, Y, 2