FINI
/CLEAR, NOSTART
/FILENAME, Bacherlorarbeit
/TITLE, Bacherlorarbeit

!================================ Materialparameter ================================

/prep7

! Elementtypen  
	ET, 1, SOLID185
	ET, 2, TARGE170, , 1
	ET, 3, CONTA174
	keyopt, 3, 10, 2
   
! Materialmodelle
  ! Bogen (MAT 1 - linear)
	MP, EX, 1, 210000
	MP, PRXY, 1, 0.3
  ! Hinterfüllung (MAT 2 - linear)
	MP, EX, 2, 210000
	MP, PRXY, 2, 0.3
  ! Kontakte
	MP, MU, 3, 0.1			! Reibungskoeffizient der Kontakte = 0.1

! Realconstants
	R, 1
	R, 2

!================================ Geometrievereinbarung ================================

! Maße
	a=2		!breite
	b=1		!höhe
	c=1		!länge

! Quader 1
	blc4, 0, 0, a, b, c

! Quader 2
	blc4, a/4, b, a/2, b, c


!======================================= Mesh =======================================

! Quader 1 (linear)
	type, 1
	mat, 1
	real, 1
	mshky, 1
	esize, 0.125
	vmesh, 1
	eplo

! Quader 2 (linear)
	type, 1
	mat, 2
	real, 1
	mshky, 1
	esize, 0.125
	vmesh, 2
	eplo

!===================================== Kontakte ==================================

!---die Kontakte werden doppelt definiert, aber mit vertauschtem Contact und Target
!dies ist wichtig um eine Übertragung in beide Richtungen gleichmäßig zu haben
!dabei bekommt jedes Paar eine eigene realkonstante

	asel, s, , , 4		!Quader 1 A4
	nsla, s, 1 	
	type, 2		!Target
	mat, 3
	real, 2
	esurf

	asel, s, , ,9		!Quader 2 A9
	nsla, s, 1
	type, 3		!Contact
	esurf
	allsel	
	
	asel, s, , , 4		!Quader 1 A4
	nsla, s, 1 	
	type, 3		!Contact
	mat, 3
	real, 3
	esurf

	asel, s, , , 9		!Quader 2 A9
	nsla, s, 1
	type, 2		!Target
	esurf
	allsel	

!================================ Randbedingungen ================================

	asel, s, , ,3
	nsla, s,1
	d, all, all
	allsel

!================================ Solution-Einstellungen ================================

/solu

	antype, static, new	!statische Analyse
	eqslv, spar		!Specifies the type of equation solver
	nlgeom, on		!nichtlineare Geometrie
	pred, -1		!Praediktor Method
				!chosen by Program for all DOFs

	outres, nsol, last
	nsub, 1, 10, 1


!=============================== 1.Lastfall - Initialisierung ============================ 

	time, 1
	asel, s, , , 10		!der kontakt wird initialisiert durch eine kleine Verschiebung
	nsla, s, 1
	d, all, uy, -0.005
	allsel
	solve

	time, 2	
	asel, s, , , 10		!nach der ini wird die verschiebung gelöscht
	nsla, s, 1
	ddele, all, all
	allsel
	solve

!=============================== 2.Lastfall - Druck ============================ 

	asel, s, , , 10		!aufbringen von druck
	nsla, s, 1
	sf, all, pres, 500
	/psf, pres, norm, 2, 0, 1

allsel
eplo
solve

fini

!===================================== POSTPROC===============================

/POST1

PLNSOL, S, Y, 2