!Simulation
!aerosimul, 15.11.2017
!Lufttransformator zwei Wicklungen
!harmonische Rechnung

finish  $/clear
*abbr,aerosimul,/input,aerosimul,txt

!-----Parameter-----
abst=30e-3     						!Abstand beider Spulen
radau=120e-3   						!Radius außen Betrachtungsraum
strom=100        					!Speisestrom
frequenz=100e3						!Frequenz

!---Primärspule---
radwiin1=30.5e-3  					!Radius Spule prim innen
radwiau1=35.5e-3  					!Radius Spule prim außen
howi1=12e-3     					!Höhe Spule prim
wizahl1=25	     					!Windungszahl
strdi1=strom*wizahl1/((radwiau1-radwiin1)*howi1)  	!Stromdichte
asp1=(radwiau1-radwiin1)*howi1

!---Sekundärspule---
radwiin2=14.5e-3  					!Radius Spule sek innen
radwiau2=15.5e-3  					!Radius Spule sek außen
howi2=7e-3     						!Höhe Spule sek
wizahl2=100     					!Windungszahl
strdi2=strom*wizahl2/((radwiau2-radwiin2)*howi2)  	!Stromdichte
asp2=(radwiau2-radwiin2)*howi2


/prep7
et,1,plane53,,,1					!Spule prim 
et,2,plane53,3,,1					!Spule sek
et,3,plane53,,,1					!Luft

mp,murx,1,1						!Spule prim
mp,rsvx,1,1/56e6					!Spule prim Kupfer
mp,murx,2,1						!Spule sek
mp,rsvx,2,1/56e6					!Spule sek Kupfer
mp,murx,3,1						!Luft

r,2,awiu,wizahl
real,2


!-----Geometrie-----
rectng,radwiin1,radwiau1,abst/2,abst/2+howi1  		!Spule prim
rectng,radwiin2,radwiau2,-abst/2,-abst/2-howi2  	!Spule sek
pcirc,0,radau,-90,90   					!Umgebungsluft
aovlap,all
numcmp,area
!A1: obere Wicklung A2: untere Wicklung A3: Luft


!-----Vernetzung-----
!---Primärspule---
type,1
mat,1
esize,howi1/2   					!Elementgröße
amesh,1
!---Sekundärspule---
type,2
mat,2
esize,howi2/2   					!Elementgröße
amesh,2
!-----Luft-----
type,3
mat,3
esize,howi1*1	  					!Elementgröße
esize,howi2*1
amesh,3

!-----Randbedingung-----
csys,1  						!Zylinderkoordinaten
nsel,s,loc,x,radau
d,all,az,0
csys,0


!-----Lasten-----
!---Sekundärspule---
esel,s,type,,2
nsle,s
cp,1,emf,all
cp,2,curr,all

!---Primärspule---
esel,s,type,,1
nsle
bfe,all,js,1,i*win1/asp1
allsel

!-----Schaltung-----
*get,nmax,node,,num,max					!höchste Knotennummer
*get,emax,elem,,num,max					!höchste Elementnummer

esel,s,type,,2						!Koppelknoten
nsle,s
*get,nf,node,,num,min

abm=3e-3
n,nmax+1,-abm,0
n,nmax+2,-abm,abm

!-----Koppelelement-----
/icscale,,.05						!Darstellungsgröße
et,4,circu124,5,0					!Elementvereinbarung
r,4,1							!Symmetriefaktor
type,4							!Elementaufruf
real,4
e,nmax+1,nmax+2,nf					!Elementgenerierung

!-----Schaltungsmasse-----
d,nmax+1,volt,0

!-----Randbedingungen-----
allsel
lsel,s,ext
nsll,s,1
d,all,az,0

!-----Lösung-----
/solu
allsel
antype,harm
harfre,frequenz
solve

!-----Auswertung-----
/post1
set,1,1,1,0
*get,real,elem,emax+1,smisc,1				! UR_R

set,1,1,1,1
*get,imag,elem,emax+1,smisc,1				! UR_I
betrag=sqrt(real*real+imag*imag)