!Ermittlung der Potentialverteilung einer zylindrischen Probe MIT Riss


FINISH
/CLEAR,nostart


!-----Parameter----------------------
radius=10e-3		!Radius des Zylinders
hoehe=50e-3		!Höhe des Zylinders

rissTiefe=0.5e-3	!Risslänge
rissOrt=30		!Rissort (Winkel θ im zylindrischen KOS [°])

netzEA=6		!Netzelementanzahl pro Viertelkreis (nur gerade Zahlen erlaubt!)
!netzEA=18		!90°/netzEA = sw (Schrittweite in °) ==> 120° mod(ulo) sw = 0 muss stets erfüllt sein!)

strom=1000		!eingeprägter Strom [A]


!-----Element Type und Material Props festlegen--------
/PREP7
ET,1,mesh200,6
ET,2,solid231
MP,rsvx,1,7.3e-7 	!Material: (EN) 1.4301 / (DIN) X5CrNi18-10 (spezifischer elektrischer Widerstand in Ωm)


!----KOS definieren----
CLOCAL,14,cylin,0,0,0	!Definition eines lokalen, zylindrischen KOS (x=R, y=θ, z=Z)
K,100,0,0,0
K,101,radius,rissOrt,0  
K,102,radius+1e-3,rissOrt,0
K,103,radius,rissOrt+1,0
CSKP,15,cart,101,102,103
CSYS,0

!----Geometrie I------
CYLIND,,radius,-hoehe/2,0,  0, 90
CYLIND,,radius,-hoehe/2,0,270,360

!----Workplane-Verschiebung zum Anrissort----
WPSTYLE,,,,,,,,1
KWPAVE,101

!----Geometrie für Ellipse----
CYL4,0,0,,,rissTiefe,,-hoehe/2
KWPAVE,100
CSYS,15
VLSCALE,3,,,,2,,,1,1       	!Verzerrt den kreisförmigen Zylinder zu einem elliptischen Zylinder
CSYS,0
ALLSEL
VOVLAP,all			!Erzeugt Volumen durch Überlappung
CSYS,14
VSEL,s,loc,x,radius,radius+rissTiefe			
VDELE,all,,,1
CSYS,0
ALLSEL			
NUMCMP,volu
VPLOT

!CSYS,15			!Hiermit würde das halbelliptische Volumen in zwei Viertel zerlegt werden --> Behebt aber den Netzfehler nicht
!K,201,-rissTiefe,0,0
!K,202,-rissTiefe,0,-hoehe/2
!K,203,0,0,-hoehe/2
!A,101,201,202,203
!VSBA,2,1,,Delete,Keep
!CSYS,0

!----Geometrie II------
CYLIND,,radius,-hoehe/2,0, 90,180
CYLIND,,radius,-hoehe/2,0,180,270

VGLUE,all
NUMCMP,volu

!----Vernetzung------
ESIZE,,netzEA
MSHAPE,0,2d
MSHKEY,1
VMESH,all

!-----Spiegelung------
VSYMM,z,all
EPLOT