! ---EIGENE PARAMETER---
LAENGE=3				! Elementlänge in z-Richtung
HOEHE=1.0				! Elementhöhe in y-Richtung

DDICKE=0.12				! Dicke der Dämmschicht
SDICKE=0.0006				! Dicke der Deckschicht				[0.4-1.0 mm]
FDICKE=0.010				! Fugentiefe
FHOEHE=0.002				! Höhe der Fuge

KOMBCONV=23				! komb. Wärmeübergangs-/Wärmeabstrahlungszahl	[W/m²K]  
DDICHTE=110				! Dichte der Dämmschicht bei 20°C		[kg/m³]
DEMOD=6e6				! E-Modul der Dämmschicht bei 20°C		[N/m²]
SEMOD=210000e6				! E-Modul Deckschicht bei 20°C			[N/m²]
DGMOD=7e6				! Schubmodul der Dämmschicht			[N/m²]
SGMOD=7.93e10				! Schubmodul der Deckschicht			[N/m²]
DQKZ=DEMOD/(2*DGMOD)-1			! Querkontraktionszahl Dämmschicht
SQKZ=SEMOD/(2*SGMOD)-1			! Querkontraktionszahl Deckschicht

HMESH=25*HOEHE				! Elementanzahl über Höhe (in y-Richtung)
LMESH=25*LAENGE				! Elementanzahl über Länge (in z-Richtung)

! ---EIGENE MACROS---
*CREATE,DEATH				! Elementzerfall für TKRIT
TKRIT=800				! krit. Temperatur, bei der Dämmstoff zu zerfallen beginnt
nsel,s,temp,,TKRIT			! Auswahl aller Knoten mit krit. Temperatur
esln,s,1				! Auswahl zugehöriger Elemente
ekill,all				! Ausschalten dieser Elemente
alls					! Selektierung aufheben
*END

*CREATE,BRDGRNZ
alls					! Selektion aufheben
esel,u,live				! Elementauswahl aller Elemente die nicht "lebend" sind
nsle,s,all				! Auswahl aller Knoten der ausgewählten Elemente
*END

! ---PREPROCESSOR---
/prep7

!Elementtypen
et,1,solid185								! 8-Knoten Volumenelement
et,2,shell181								! 4-Knoten Schalenelement

!Sectype
sectype,,shell								! Zuweisung der Schalendicke
secdata,SDICKE

!Definition Material 1 [Dämmschicht]
mp,ex,1,DEMOD								! E-Modul Dämmschicht
mp,nuxy,1,DQKZ								! Querkontraktion Dämmschicht
mp,alpx,1,0								! Wärmeausdehnungskoeffizient Dämmschicht zu null gesetzt
mp,reft,1,20								! Referenztemperatur Dämmschicht zu 20°C gesetzt
mptemp,1,20,100,200,300,400,500						! Temperaturtabelle für tem.abhängige Eigenschaften
mptemp,7,600,700,800,925,1000,1200
mpdata,dens,1,1,1*DDICHTE,1*DDICHTE,0.985*DDICHTE,0.981*DDICHTE,0.978*DDICHTE,0.976*DDICHTE		! temperaturabhängige Dichte der Dämmschicht
mpdata,dens,1,7,0.972*DDICHTE,0.97*DDICHTE,0.97*DDICHTE,0.957*DDICHTE,0.94*DDICHTE,0.887*DDICHTE	! zugeordnet zu Tabellenwerten
mpdata,c,1,1,880,1040,1160,1220,1280,1320								! temperaturabhängige spez. Wärmekapazität der
mpdata,c,1,7,1355,1390,1430,1477,1510,1580								! Dämmschicht zu Tabellenwerten zugeordnet
mptemp													! Löschen der vorherigen Temperaturtabelle (Fehlermeldung...)
mptemp,1,20,100,400,600,800,925										! Temperaturtabelle für temp.abhängige Eigenschaften
mptemp,7,1200
mpdata,kxx,1,1,0.044,0.112,0.215,0.360,0.549,0.718							! temperaturabhängige Wärmeleitfähigkeit der
mpdata,kxx,1,7,1.091											! Dämmschicht zu Tabellenwerten zugeordnet

								
!Definition Material 2 [Deckschicht]

mp,nuxy,2,SQKZ								! Querkontraktion Deckschicht
mp,reft,2,20								! Referenztemperatur Deckschicht zu 20°C gesetzt
mptemp,1,20,100,200,300,400,500						! Temperaturtabelle für temperaturabhängige
mptemp,7,600,700,800,900,1000,1050					! Materialeigenschaften
mpdata,dens,2,1,7837,7813,7782,7748,7713,7577				! temperaturabhängige Dichte zugeordnet zu
mpdata,dens,2,7,7639,7602,7612,7590,7541,7514				! den Werten aus Temperaturtabelle
mpdata,kxx,2,1,40.4,41.6,41.7,40.9,39.3,37.5				! temperaturabhängige Wärmeleitfähigkeit zu
mpdata,kxx,2,7,35.4,31.8,32.8,33.8,34.2					! den Werten aus Temperaturtabelle zugeordnet
mpdata,alpx,2,1,11.8e-6,12.6e-6,13.1e-6,13.6e-6,14e-6,14.4e-6		! Wärmeausdehnungskoeffizient zu den Werten
mpdata,alpx,2,7,14.8e-6,15e-6,12.5e-6,12.2e-6,13.2e-6,13.7e-6		! aus Temperaturtabelle zugeordnet
mpdata,alpy,2,1,11.8e-6,12.6e-6,13.1e-6,13.6e-6,14e-6,14.4e-6		! Wärmeausdehnungskoeffizient zu den Werten
mpdata,alpy,2,7,14.8e-6,15e-6,12.5e-6,12.2e-6,13.2e-6,13.7e-6		! aus Temperaturtabelle zugeordnet
mpdata,alpz,2,1,11.8e-6,12.6e-6,13.1e-6,13.6e-6,14e-6,14.4e-6		! Wärmeausdehnungskoeffizient zu den Werten
mpdata,alpz,2,7,14.8e-6,15e-6,12.5e-6,12.2e-6,13.2e-6,13.7e-6		! aus Temperaturtabelle zugeordnet
mptemp,1,20,100,200,300,400,500						! Temperaturtabelle für temperaturabhängige
mptemp,7,600,700,780,900,1000,1200					! Materialeigenschaften
mpdata,c,2,1,440,480,520,570,600,660					! temperaturabhängige spez. Wärmekapazität
mpdata,c,2,7,750,1000,2000,570,600,680					! zugeordnet zu Temperaturtabelle
mptemp,1,20,50,100,150,200,250
mpdata,ex,2,1,202513e6,196663e6,212260e6,208710e6,206659e6,191849e6
tb,miso,2,8,7,								! Definiert multilineares Werkstoffgesetz
tbtemp,20								! für T=20°C
tbpt,defi,0,0								! Spannungs-Dehnungspunkte definieren
tbpt,defi,0.001658,335.738e6
tbpt,defi,0.150,554.518e6
tbpt,defi,1,964.380e6
tbpt,defi,1.125,964.380e6
tbtemp,50								! für T=50°C
tbpt,defi,0,0								! Spannung-Dehnungspunkte definieren
tbpt,defi,0.001648,324.088e6
tbpt,defi,0.150,544.515e6
tbpt,defi,1,946.982e6
tbpt,defi,1.125,946.982e6
tbtemp,100								! für T=100°C
tbpt,defi,0,0								! Spannungs-Dehnungspunkte definieren
tbpt,defi,0.001514,321.292e6
tbpt,defi,0.150,530.133e6
tbpt,defi,1,921.970e6
tbpt,defi,1.125,921.970e6
tbtemp,150								! für T=150°C
tbpt,defi,0,0								! Spannungs-Dehnungspunkte definieren
tbpt,defi,0.001497,312.461e6
tbpt,defi,0.150,519.208e6
tbpt,defi,1,902.970e6
tbpt,defi,1.125,902.970e6
tbtemp,200								! für T=200°C
tbpt,defi,0,0								! Spannungs-Dehnungspunkte definieren
tbpt,defi,0.001424,294.334e6
tbpt,defi,0.15,539.753e6
tbpt,defi,1,938.700e6
tbpt,defi,1.125,938.700e6
tbtemp,250								! für T=250°C
tbpt,defi,0,0								! Spannungs-Dehnungspunkte definieren
tbpt,defi,0.001544,296.154e6
tbpt,defi,0.15,572.718e6
tbpt,defi,1,996.032e6
tbpt,defi,1.125,996.032e6

!Geometrie erzeugen
block,0,FDICKE,HOEHE/2+FHOEHE,3/2*HOEHE+FHOEHE,0,LAENGE			! oberer Block 1 der Dämmschicht
block,FDICKE,DDICKE,HOEHE/2+FHOEHE,3/2*HOEHE+FHOEHE,0,LAENGE		! oberer Block 2 der Dämmschicht
block,FDICKE,DDICKE,HOEHE/2,HOEHE/2+FHOEHE,0,LAENGE			! Zwischenblock zwischen oben und mitte
block,0,FDICKE,-HOEHE/2,HOEHE/2,0,LAENGE				! mittlerer Block 1 der Dämmschicht
block,FDICKE,DDICKE,-HOEHE/2,HOEHE/2,0,LAENGE				! mittlerer Block der Dämmschicht
block,FDICKE,DDICKE,-HOEHE/2-FHOEHE,-HOEHE/2,0,LAENGE			! Zwischenblock zwischen mitte und unten
block,0,FDICKE,-3/2*HOEHE-FHOEHE,-HOEHE/2-FHOEHE,0,LAENGE		! unterer Block 1 der Dämmschicht
block,FDICKE,DDICKE,-3/2*HOEHE-FHOEHE,-HOEHE/2-FHOEHE,0,LAENGE		! unterer Block 2 der Dämmschicht
vglue,all								! Alle Volumen miteinander verkleben


!Meshing
mshkey,1								! mapped-meshing, nur quaderförmige Elemente
lesize,5,FDICKE/2							! Linie 5 unterteilt mit Elementlänge FDICKE/2
lesize,6,,,HMESH							! Linie 6 unterteilt mit Elementzahl HMESH
lesize,10,,,LMESH							! Linie 10 unterteilt mit Elementzahl LMESH
lesize,99,FDICKE/2							! Linie 99 unterteilt mit Elementlänge FDICKE/2
lesize,102,,,1								! Linie 102 unterteilt mit einem Element
lesize,29,FDICKE/2							! Linie 29 unterteilt mit Elementlänge FDICKE/2
lesize,108,,,HMESH							! Linie 108 unterteilt mit Elementzahl HMESH
lesize,33,,,LMESH							! Linie 33 unterteilt mit Elementzahl LMESH
lesize,112,FDICKE/2							! Linie 112 unterteilt mit Elementlänge FDICKE/2
lesize,114,,,1								! Linie 114 unterteilt mit einem Element
lesize,65,FDICKE/2							! Linie 65 unterteilt mit Elementlänge FDICKE/2
lesize,69,,,LMESH							! Linie 69 unterteilt mit Elementzahl LMESH
lesize,120,,,HMESH							! Linie 120 unterteilt mit Elementzahl HMESH
lesize,124,FDICKE/2							! Linie 124 unterteilt mit Elementlänge FDICKE/2
vmesh,all								! Vernetzung ausführen

!Komponente BLECH erstellen und Elementieren
asel,s,area,,5								! Auswahl Fläche 5
asel,a,area,,23								! zus. Auswahl Fläche 23
asel,a,area,,41								! zus. Auswahl Fläche 41
nsla,s,1								! Auswahl aller Knoten dieser Flächen
nsel,a,loc,y,HOEHE/2,HOEHE/2+FHOEHE					! zus. Auswahl Knoten mit y zwischen HOEHE/2 und HOEHE/2+FHOEHE 
nsel,a,loc,y,-HOEHE/2,-HOEHE/2-FHOEHE					! zus. Auswahl Knoten mit y zwischen -HOEHE/2 und -HOEHE/2-FHOEHE
nsel,u,loc,x,FDICKE-1e-6,DDICKE						! Abwählen der ausgewählten Knoten mit x zwischen FDICKE+1e-6 und DDICKE	
cm,BLECH,node								! ausgewählte Knoten zusammengefasst unter Komponente BLECH
type,2									! Elemente von Typ2 (shell131) werden erstellt
esurf									! Auftragen des Elementtyp2 auf die Auswahl BLECH
alls									! Auswahl aufheben

!Komponente FRONT erstellen
nsel,s,loc,x,DDICKE							! Auswahl aller Knoten bei x = DDICKE
cm,FRONT,node								! ausgewählte Knoten zusammengefasst zu Komponente FRONT
alls

!Zuweisung Materialdaten
esel,s,type,,1								! Auswahl aller Elemente von Typ1 (solid70)
emodif,all,mat,1							! Zuweisung Materialsatz 1 (Dämmstoff)
alls									! Auswahl aufheben

esel,s,type,,2								! Auswahl aller Elemente von Typ2 (Shell131)
emodif,all,mat,2							! Zuweisung Materialsatz 2 (Deckschicht)
alls									! Auswahl aufheben

! --- AUSRISSTRICHTER---
nropt,full								! use full Newton-Raphson

nsel,s,loc,x,DDICKE-1.5*FDICKE,DDICKE					! oberer Ausrisstrichter
nsel,r,loc,y,HOEHE/2+FHOEHE/2-5*FDICKE,HOEHE/2+FHOEHE/2+5*FDICKE
esln,s,1	
ekill,all								! Aussschalten der Elemente
alls

nsel,s,loc,x,DDICKE-1.5*FDICKE,DDICKE					! unterer Ausrisstrichter
nsel,r,loc,y,-HOEHE/2-FHOEHE/2-5*FDICKE,-HOEHE/2-FHOEHE/2+5*FDICKE
esln,s,1
ekill,all								! Aussschalten der Elemente
alls
								
! ---SOLUTION---
/solu
antype,static								! strukturmechanische Analyse
nlgeom,on
pstres,on

!Anbringung von Lagern an Seite z=0
!Lager 1 - oberes Element,oben
nsel,s,loc,z,0								! Auswahl z-Koordinate Lager
nsel,r,loc,x,5*FDICKE							! Auswahl x-Koordinate Lager
nsel,r,loc,y,HOEHE*3/2+FHOEHE-0.04					! Auswahl y-Koordinate Lager
d,all,ux								! Festhalterung in x-Richtung
d,all,uy								! Festhalterung in y-Richtung
d,all,uz								! Festhalterung in z-Richtung
alls
!Lager 2 - oberes Element,mitte
nsel,s,loc,z,0
nsel,r,loc,x,5*FDICKE
nsel,r,loc,y,HOEHE+FHOEHE+0.02
d,all,ux
d,all,uy
d,all,uz
alls
!Lager 3 - oberes Element,unten
nsel,s,loc,z,0
nsel,r,loc,x,5*FDICKE
nsel,r,loc,y,HOEHE/2+FHOEHE+0.04
d,all,ux
d,all,uy
d,all,uz
alls
!Lager 4 - mittleres Element,oben
nsel,s,loc,z,0
nsel,r,loc,x,5*FDICKE
nsel,r,loc,y,HOEHE/2-0.04
d,all,ux
d,all,uy
d,all,uz
alls
!Lager 5 - mittleres Element,mitte
nsel,s,loc,z,0
nsel,r,loc,x,5*FDICKE
nsel,r,loc,y,0.02
d,all,ux
d,all,uy
d,all,uz
alls
!Lager 6 - mittleres Element,unten
nsel,s,loc,z,0
nsel,r,loc,x,5*FDICKE
nsel,r,loc,y,-HOEHE/2+0.04
d,all,ux
d,all,uy
d,all,uz
alls
!Lager 7 - unteres Element,oben
nsel,s,loc,z,0
nsel,r,loc,x,5*FDICKE
nsel,r,loc,y,-HOEHE/2-FHOEHE-0.04
d,all,ux
d,all,uy
d,all,uz
alls
!Lager 8 - unteres Element,mitte
nsel,s,loc,z,0
nsel,r,loc,x,5*FDICKE
nsel,r,loc,y,-HOEHE-FHOEHE-0.02
d,all,ux
d,all,uy
d,all,uz
alls
!Lager 9 - unteres Element,unten
nsel,s,loc,z,0
nsel,r,loc,x,5*FDICKE
nsel,r,loc,y,-HOEHE*3/2-FHOEHE+0.04
d,all,ux
d,all,uy
d,all,uz
alls

!Symmetrie Randbedingungen anbringen
nsel,s,loc,z,LAENGE
dsym,symm,z
alls

!Lastaufbringung aus Temperaturberechnung
ldread,temp,,,5400,,,rth							! Temperaturen von t=5400s werden auf Knoten als Lasten aufgebracht

!Lastaufbringung Ofendruck
sfgrad,pres,0,y,-HOEHE*3/2-FHOEHE,8.5
nsel,s,loc,x,DDICKE
sf,all,pres,0
alls

!Lastaufbringung Erdbeschleunigung
acel,,9.81

solve