finish
/clear

/RGB,INDEX,100,100,100,0
/RGB,INDEX,0,0,0,15

!Analyse Sanwichelement auf Biegung - Komplettes Element

!---------------------------------------------------------------------------------
!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!Element: T 080!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!---------------------------------------------------------------------------------

!Eingabe in: N, mm, sek,

!Preprozessor: Eingabe von Material, Geometrie, Vernetzung, etc.
/prep7

!---------------------------------------------------------------------------------
!Parameter
!---------------------------------------------------------------------------------

!Deckbleche - Stahl
ED=210000	!N/mm^2
GD=81000	!N/mm^2
vD=0.3		!Querdehnzahl

!Kern - PUR-Schaum
EK=3.5273

GKXY=3.0482	
GKYZ=4.5878
GKXZ=3.0482
vK=0.3

!Abmessungen in m
B=900
L=4000
D=80

DD=0.4905
DK=D-2*DD
DL=10		!Dicke der Bleche am Lager

!Maximale Kraft
P=4000
PSF=P/(3900*B)

!Verschiedene Faktoren zur Teilung des Netzes
DIVX=80
DIVY=12
DIVK=6

!---------------------------------------------------------------------------------
!Elemente definieren!
!---------------------------------------------------------------------------------

ET,1,SHELL181
			
ET,2,SOLID185		!3-D 8-Node Structural Solid
!KEYOPT,2,2,3		!KEYOPT(2)=3: Simplified enhanced strain formulation

!---------------------------------------------------------------------------------
!Materialparameter
!---------------------------------------------------------------------------------

!1. Material - Stahl
UIMP,1,EX,EY,EZ,ED,ED,ED
UIMP,1,PRXY,PRYZ,PRXZ,vD,vD,vD	!Querdehnzahl
UIMP,1,GXY,GYZ,GXZ,GD,GD,GD

!2.Material - PUR-Schaum
UIMP,2,EX,EY,EZ,EK,EK,EK
UIMP,2,PRXY,PRYZ,PRXZ,vK,vK,vK	!Querdehnzahl
UIMP,2,GXY,GYZ,GXZ,GKXY,GKYZ,GKXZ

!Lokales Koordinatensystem
LOCAL,11,0		!Ist theoretisch genau das Globale Sytsem oder?
ESYS,11			!Richtet Elementen-KS nach KS11 aus


!---------------------------------------------------------------------------------
!Kernvolumen und Deckschichten mit PARTITION Kommando erzeugen
!---------------------------------------------------------------------------------

!Deckbleche
RECTNG,0,L,0,B
AGEN,2,ALL,,,,,-DD-DK,,0

!Kern
BLOCK,0,L,0,B,0,-DD-DK	!Kern wird mit einer Dicke bis zu SP der DS erzeugt
ALLSEL,ALL

ASEL,S,LOC,Z,0
ASEL,A,LOC,Z,-DD-DK
APTN,ALL		!Partition des Plattenvolumens
ALLSEL,ALL

!---------------------------------------------------------------------------------
!Schalenelemennte definieren
!---------------------------------------------------------------------------------

SECTYPE,1,SHELL
SECDATA,DD,1

!---------------------------------------------------------------------------------
!Vernetzung des Volumens und der Areas
!---------------------------------------------------------------------------------

!Linien teilen
ALLSEL,ALL
LSEL,S,LOC,X,L/2
LESIZE,ALL,,,DIVX

ALLSEL,ALL
LSEL,S,LOC,Y,B/2
LESIZE,ALL,,,DIVY

ALLSEL,ALL
LSEL,S,LOC,Z,-DD/2-DK/2
LESIZE,ALL,,,DIVK
ALLSEL,ALL

!Vernetzen
!Kern
VSEL,S,VOLU,,1
TYPE,2
MAT,2
MSHKEY,1		!1 Mapped Mashing
VMESH,ALL
ALLSEL,ALL

!Oberes Deckblech
ASEL,S,LOC,Z,0
TYPE,1
MAT,1
REAL
ESYS,11
SECNUM,1 
MSHKEY,1		!1 Mapped Mashing
AMESH,ALL
ALLSEL,ALL

!Unteres Deckblech
ASEL,S,LOC,Z,-DD-DK
TYPE,1
MAT,1
REAL
ESYS,11
SECNUM,1 
MSHKEY,1		!1 Mapped Mashing
AMESH,ALL
ALLSEL,ALL

NUMMRG,NODE
!NUMMRG,KP

FINISH

!---------------------------------------------------------------------------------
!Lagerung
!---------------------------------------------------------------------------------
/SOLU

ALLSEL,ALL
NSEL,S,LOC,X,50
NSEL,R,LOC,Z,-DD-DK
D,ALL,UZ
D,ALL,UX
D,ALL,UY

ALLSEL,ALL
NSEL,S,LOC,X,3950
NSEL,R,LOC,Z,-DD-DK
D,ALL,UZ
D,ALL,UY

!---------------------------------------------------------------------------------
!Belastung und Lösung
!---------------------------------------------------------------------------------

NSEL,S,LOC,Z,0
NSEL,R,LOC,X,50,3950
SF,ALL,PRES,-PSF

AUTOST,ON		!Do not use automatic time stepping.
KBC,0			!0=Linear & 1=Stepped
NSUBST,5
OUTRES,ALL,ALL
LSWRITE
ALLSEL,ALL
FINISH

/SOL
SOLVE
FINISH