!	www.onlinefea.com	ANSYS Tutorials
! 	1D Beam Analysis
!	Adapted from Mac Donald, Practical Stress Analysis with Finite Elements (2nd Edition), Glasnevin, 2011, page 112-114)
!
/COM,   
/COM,Preferences for GUI filtering have been set to display:
/COM,  Structural   
!*  
FINISH
/CLEAR,START
/PREP7  
!
!	Define Element Type - 3D Beam
! Werte
ForceV = 40000
h = 0.0832358
Aflaeche = h*h
laenge = 2
Em = 200e9
nu = 0.3

! Berechnungen
I = h**4/12
gSchub = (1/(2*(1+nu)))*Em
uBernoulli = ForceV*(laenge**3)/(3*Em*I)

sz = (12 + 11*nu)/(10*(1+nu))
ks = 1/sz
uTimo = ForceV*laenge**3/(3*Em*I) + ForceV*laenge/(ks*Aflaeche*gSchub)
!
et,1,beam188
!
!	Define section properties for the beam cross section
!
sectype,1,beam,rect,		! Using a rectangular beam
secdata,h,h 	! set B and H = 0.0832358 m
!  
!	Define material model
!
mp,ex,1,Em
mp,prxy,1,nu
!
!	Define nodes and their coordinates
!
N,1,0,		! Node 1 has x coordinate = 0
N,2,laenge/2,		! Node 2 has x coordinate = 1
N,3,laenge,		! Node 3 has x coordinate = 2
!
!	Define Elements
!
E,1,2		! Element 1 joins nodes 1 and 2
E,2,3		! Element 2 joins nodes 2 and 3
!
!	Supress the UX, UZ, ROTX and ROTY degrees of freedom for all nodes
!
D,all,,0,,,,UZ,ROTX,ROTY,
!
!	Constrain node 1 in all DOF
D,1,,0,,,,ALL,
!
!	Load Case 1
F,2,FY,ForceV
!
!	Save the model and sovle
SAVE
/sol
SOLVE
FINISH
!
!	Post Processing
!
/POST1
!
!	Plot the deformed Shape
!
PLDISP,0
!
! Knotenauslenkung Numerisch 
*get,uNum,node,3,U,y