Anbei die Lösung für dein/euer Problem.
Vorgehensweise
1) Vor dem Plotmakro oder innerhalb (Plot_start), folgendes Makro eintragen.
Frs_m_find_frame
Nach dem Plot_Start Makro folgendes Makro ausführen.
Frs_m_clear_info_stamp
Der Stempeltext ist '!!! NICHT FREIGEGEBEN !!!'
kann jedoch innerhalb des Makros beliebig verändert werden.
Nun die Makros.
**************************************************************
{Startmakro}
DEFINE Frs_m_find_frame
LOCAL i
LOCAL imax
LOCAL uq_partname
LOCAL nowpart
TRAP_ERROR
INQ_ENV 7
RESET_PART_NUMBER
EDIT_PART TOP
LET i 0
LET imax (LTAB_ROWS 'PBT_LTAB')
PB_LTAB_UPDATE
LOOP
LET i (i+1)
EXIT_IF (i>imax)
LET uq_partname (READ_LTAB 'PBT_LTAB' i 1)
LET find (POS (uq_partname) '.sfeld')
IF
(find <> 0)
LET nowpart (('~'+(STR i)))
EDIT_PART (STR (nowpart))
Frs_m_find_and_check_status
END_IF
END_LOOP
TRAP_ERROR OFF
END_DEFINE
{Hilfsmakro}
DEFINE Frs_m_find_and_check_status
INQ_SELECTED_ELEM SELECT TEXTS ALL CONFIRM END
LOOP
INQ_NEXT_ELEM
LET I_f_1 (INQ 900)
LET I_f_2 (INQ 901)
LET suchstr (POS (I_f_2) 'TR:tb:STATUS:')
IF
(suchstr <> 0)
INQ_ELEM (INQ 901)
LET status_str (INQ 902)
IF
(UPC (status_str) = 'ARBEIT')
{d 'KEINE FREIGABE'}
Frs_m_make_sign_keine_fertigung
END_IF
END_IF
END
EXIT_IF
(I_f_1 = 'END-OF-LIST')
END_LOOP
END_DEFINE
{****************Stempel erstellen*********************}
DEFINE Frs_m_make_sign_keine_fertigung
Frs_m_store_system
EDIT_PART TOP
INQ_ENV 7
LET Frs_v_max1 (INQ 101)
LET Frs_v_max2 (INQ 102)
LET Frs_v_maxres ((Frs_v_max1+Frs_v_max2)/2)
LET fd1 (X_OF Frs_v_max1)
LET fd2 (X_OF Frs_v_max2)
LET fomax (fd2-fd1)
INQ_ENV 12
LET txorg (INQ 3)
TEXT_ADJUST 5
TEXT_ANGLE 35
CURRENT_FONT ' hp_i3098_v'
TEXT_FILL ON
TEXT_SIZE 10 TEXT_FRAME BOX
COLOR WHITE
INIT_PART 'dummy'
TEXT '!!! NICHT FREIGEGEBEN !!!' Frs_v_maxres END
INQ_ENV 7
LET Frs_v_tmax1 (INQ 101)
LET Frs_v_tmax2 (INQ 102)
LET Frs_v_max1 (PNT_XY (X_OF Frs_v_max1 + 20) (Y_OF Frs_v_max1 + 10))
LET Frs_v_max2 (PNT_XY (X_OF Frs_v_max2 - 20) (Y_OF Frs_v_max2 - 10))
MODIFY DEL_OLD ASSIST SIMILAR Frs_v_tmax1 Frs_v_tmax2
(Frs_v_max1) (Frs_v_max2) SELECT ALL CONFIRM END
TEXT_TO_GEO TEXTS ALL CONFIRM END
CHANGE_LINESIZE 1 SELECT ALL CONFIRM END
CHANGE_LINETYPE SOLID SELECT ALL CONFIRM END
Frs_m_recall_system
END_DEFINE
{***********Stempel nach dem Plot löschen************}
DEFINE Frs_m_clear_info_stamp
TRAP_ERROR
EDIT_PART TOP
DELETE 'dummy' END
REDRAW END
CHECK_ERROR
END_DEFINE
{Text store}
DEFINE Frs_m_store_system
INQ_ENV 8
LET Frs_vg_old_txtfont (INQ 301)
INQ_ENV 9
LET Frs_vg_old_txtsize (INQ 3)
INQ_ENV 3
LET Frs_vg_old_geo_color (INQ 201)
INQ_ENV 12
LET Frs_vg_old_txtfill (INQ 602)
END_DEFINE
{Text set}
DEFINE Frs_m_recall_system
COLOR RGB_COLOR Frs_vg_old_geo_color END
CURRENT_FONT Frs_vg_old_txtfont END
TEXT_SIZE Frs_vg_old_txtsize END
TEXT_FILL Frs_vg_old_txtfill END
END_DEFINE
Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP
Foren auf CAD.de
| 
)
