Hilfe bei einem Macro zum Speichern unter ME 9.0/10.0 (PTC/PTC Creo Elements/Programmierung)

Hallo

vielleicht kann mir einer weiter helfen. ich habe mir in meinem macro datei 1 zum Speichern eine Zeile eingefügt.

MENU Colo0 Bcol2 '6.11 Unkom' 'ENTER_TOP ENTER_LAST_ZNAME1' 21 2

mit dem befehl speichere ich meine zeichnungen ab. wen ich speichere dann nimmt er mir den aktuellen zeichnungsnamen ( der in der Obersten Baugruppe steht ) und speicher die zeichnung mit dem namen ab. falls sie schon vorhanden ist fragt er nach mit Datei Überschreiben ( j/n ) falls sie vorhanden ist drücke ich irgend eine taste und es erscheint in der staus zeile Žn` ( als vorgabe ) und wen ich sie überschreiben möchte trage ich nur ein j ein und drücke enter.
Das geht mit der version 7.0 aber bei der version 9.0 und 10.0 macht er zwar das selbe nur die vorgabe `n` erscheint nicht. Erst wen ich mit dem curser nach links gehe erscheint die vorgabe. Was ist falsch oder was hat sich in der version 9.0 und 10.0 geändert.

Gruß Ralf

Das macro :

define enter_top
edit_part top
inq_env 7
let obname (inq 301)
end_define

define enter_teil
inq_env 7
let tname (inq 301 )
end_define

{ Gesamte Zeichnung mit dem Namen
der aktuellen Obersten Baugruppe
speichern }

DEFINE enter_last_zname1
{enter_top ist zu entfernen wenn store mit maske }
on_error 'ask_for_overwrite'
store MI ALL OBNAME
{on_error ' ' }
END_DEFINE

{ Verzweigung falls der Dateiname bereits
vorhanden ist }

define ask_for_overwrite
local jn
read string 'Datei Ïberschreiben (j/n) ' default 'n' jn
if ( UPC jn = 'J' )
store MI ALL del_old OBNAME
end_if
end_define

{ Aktuelle Namen der Obersten Baugruppe auf
Textdatei im schreiben .}

define write_obname
enter_top
open_outfile 1 del_old './.oberste'
write_file 1 obname
write_file 1 '79'
close_file 1
end_define

{ Store Befehl mit Eingabemaske starten }

define store_with_check
local checker
local input_obname
write_obname

run '/me10/progs/store.out'

open_infile 1 './.eintrag'
read_file 1 checker
read_file 1 input_obname
close_file 1

if (checker='0')
let obname input_obname
edit_part top
rename_part obname
enter_last_zname1
end_if

end_define

[Diese Nachricht wurde von Ralf KB am 10. Dezember 2000 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

DEFINE Enter_top
EDIT_PART TOP
INQ_ENV 7
LET Obname (INQ 301)
END_DEFINE

DEFINE Enter_last_zname1
(IGNORE_BREAK)
(TRAP_ERROR)
STORE MI ALL Obname END

IF (CHECK_ERROR)
Ask_for_overwrite
END_IF
(ENABLE_BREAK)
END_DEFINE

DEFINE Ask_for_overwrite
LOCAL Jn

BEEP
READ STRING 'Datei existiert bereits ! Datei ueberschreiben (j/n) ' DEFAULT 'n' Jn

IF (UPC Jn='J')
STORE MI ALL DEL_OLD Obname END
END_IF
END_DEFINE