---

Hallo Zusammen,

Es gibt ja das iProp Projekt -> Dateiuntergruppe

Ich habe dort (je nach Template) englische und deutsche Werte drin.

(Rührt wahrscheinlich von den ersten (verschieden sprachigen) Templates her,
die irgendwann angepasst und dann immmer nur migriert wurden...)

Und jetzt meine Fragen:

1. Kann man dieses iProp ändern (umbenennen)?

2. Wie kann man dieses iProp in einer Zeichnung
aus der dargestellten Ansicht (z.B. ANSICHT1) aufrufen um es danach
z.B. in ein benutzerdefiniertes iProp zu schreiben?

(Beispiel: die IDW würde erkennen dass ANSICHT1 ein Blech ist und ein iProp in der IDW erstellen das Kategorie = Blech heißt)

------------------
Gruß Georg 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

zu 1.
Das iProp heißt "Document SubType Name" und ist in den normalen Auswahllisten nicht enthalten. Es ist nicht überschreibbar, aber sprachabhängig.
Ich würde für die Klassifizierung eher das iProp "Document SubType" nutzen. Das enthält eindeutige, sprachunabhängige Werte. Was für eine Unterteilung soll es denn sein? Nur Bauteil/Blechteil/Baugruppe oder differenzierter?

mögliche Bauteil Subtypen:
{4D29B490-49B2-11D0-93C3-7E0706000000} = part
{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4} = sheet metal
{92055419-B3FA-11D3-A479-00C04F6B9531} = generic proxy
{9C464204-9BAE-11D3-8BAD-0060B0CE6BB4} = compatibility proxy
{9C88D3AF-C3EB-11D3-B79E-0060B0F159EF} = catalog proxy

mögliche Baugruppen Subtypen:
{E60F81E1-49B3-11D0-93C3-7E0706000000} = assembly

mögliche Präsentations Subtypen:
{76283A80-50DD-11D3-A7E3-00C04F79D7BC} = presentation

zu 2.
Man könnte entweder den User eine Ansicht anklicken lassen oder fix z.B. die erste Ansicht auf dem aktiven Blatt hernehmen. Vom referenzierten Modelldokument der Ansicht das iProp auslesen und in das benutzerdefiniertes iProp der IDW übertragen.

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von rkauskh:

Ich würde für die Klassifizierung eher das iProp "Document SubType" nutzen. Das enthält eindeutige, sprachunabhängige Werte. Was für eine Unterteilung soll es denn sein? Nur Bauteil/Blechteil/Baugruppe oder differenzierter?

[/i]

---

Ja das hört sich schon gut an. Bestenfalls noch "Schweißbaugruppe" und "Zeichnung"

------------------
Gruß Georg 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von rkauskh:

zu 2.
Man könnte entweder den User eine Ansicht anklicken lassen oder fix z.B. die erste Ansicht auf dem aktiven Blatt hernehmen. Vom referenzierten Modelldokument der Ansicht das iProp auslesen und in das benutzerdefiniertes iProp der IDW übertragen.

[/B]

---

Wie genau geht das? 

Bin in iLogic nicht fit...

------------------
Gruß Georg 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Zeichnung sollte als Dokumenttyp in einer Zeichnungsansicht nicht vorkommen oder? Ich habe jetzt Bauteil, Blechteil, Baugruppe, Schweißbaugruppe, Präsentation und Zeichnung.

Code:

---

If Not ThisDoc.Document.DocumentType = DocumentTypeEnum.kDrawingDocumentObject Then
MsgBox("Funktion nur in Zeichnungen verfügbar", MsgBoxStyle.Critical, "iLogic")
Exit Sub
End If

Dim oDrawDoc As DrawingDocument = ThisDoc.Document
Dim oSheet As Sheet = oDrawDoc.ActiveSheet
Dim oDrawView As DrawingView

Dim oRefedDoc As Document

'Variante 1 - Benutzerwählt
oDrawView = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingViewFilter, "Bite Ansicht auswählen... (ESC für Abbruch)")

'Variante 2 - erste Ansicht auf dem Blatt
'oDrawView= oSheet.DrawingViews(1)

If oDrawView Is Nothing Then Exit Sub

oRefedDoc = oDrawView.ReferencedDocumentDescriptor.ReferencedDocument
Dim sValue As String
Select Case oRefedDoc.DocumentType
Case 12290 : 'Bauteil
If oRefedDoc.SubType="{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then 'Blechteil
sValue="Blechteil"
Else 'alle anderen Bauteiltypen sind Bauteile
sValue="Bauteil"
End If
Case 12291 : 'Baugruppe
If oRefedDoc.ComponentDefinition.Type = ObjectTypeEnum.kWeldmentComponentDefinitionObject Then 'Schweißbaugruppe
sValue="Schweißbaugruppe"
Else 'alle anderen Baugruppenypen sind Baugruppen
sValue="Baugruppe"
End If
Case 12293 : 'Präsentation
sValue = "Präsentation"
Case 12292 : 'Zeichnung
sValue = "Zeichnung"
Case Else : 'Sammelobjekt alle anderen Typen
sValue = "Sonstige"
End Select

iProperties.Value("Custom", "Kategorie") = sValue

---

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Prima, vielen Dank, klappt ausgezeichnet.

Kannst du mir noch verraten wie ich diese Regel
in der Bautei- bzw Baugruppenumgebung verwenden kann?
D.h. beim Bauteil soll im IProp "Kategorie" der Wert "Bauteil" stehen, usw.
 

------------------
Gruß Georg 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Wenn das Script in verschiedenen Doklumenttypen laufen und dort jeweils den Typ eintragen soll, dann vielleicht so:

Code:

---

Dim oDoc As Document = ThisDoc.Document
Dim sValue As String

Select Case oDoc.DocumentType
Case 12290 : 'Bauteil
Dim oPartDoc As PartDocument = DirectCast(oDoc, PartDocument)
If oDoc.SubType="{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then 'Blechteil
sValue="Blechteil"
Else 'alle anderen Bauteiltypen sind Bauteile
sValue="Bauteil"
End If
Case 12291 : 'Baugruppe
Dim oAssDoc As AssemblyDocument = DirectCast(oDoc, AssemblyDocument)
If oassDoc.ComponentDefinition.Type = ObjectTypeEnum.kWeldmentComponentDefinitionObject Then 'Schweißbaugruppe
sValue="Schweißbaugruppe"
Else 'alle anderen Baugruppenypen sind Baugruppen
sValue="Baugruppe"
End If
Case 12292 : 'Zeichnung
Dim oDrawDoc As DrawingDocument = DirectCast(oDoc, DrawingDocument)
Dim oSheet As Sheet = oDrawDoc.ActiveSheet
Dim oDrawView As DrawingView

Dim oRefedDoc As Document

'Variante 1 - Benutzer wählt
oDrawView = ThisApplication.CommandManager.Pick(SelectionFilterEnum.kDrawingViewFilter, "Bite Ansicht auswählen... (ESC für Abbruch)")

'Variante 2 - erste Ansicht auf dem Blatt
'oDrawView= oSheet.DrawingViews(1)

If oDrawView Is Nothing Then Exit Sub

oRefedDoc = oDrawView.ReferencedDocumentDescriptor.ReferencedDocument

Select Case oRefedDoc.DocumentType
Case 12290 : 'Bauteil
If oRefedDoc.SubType="{9C464203-9BAE-11D3-8BAD-0060B0CE6BB4}" Then 'Blechteil
sValue="Blechteil"
Else 'alle anderen Bauteiltypen sind Bauteile
sValue="Bauteil"
End If
Case 12291 : 'Baugruppe
If oRefedDoc.ComponentDefinition.Type = ObjectTypeEnum.kWeldmentComponentDefinitionObject Then 'Schweißbaugruppe
sValue="Schweißbaugruppe"
Else 'alle anderen Baugruppenypen sind Baugruppen
sValue="Baugruppe"
End If
Case 12293 : 'Präsentation
sValue = "Präsentation"
Case 12292 : 'Zeichnung
sValue = "Zeichnung"
Case Else : 'Sammelobjekt alle anderen Typen
sValue = "Sonstige"
End Select
Case 12293 : 'Präsentation
sValue = "Präsentation"
End Select

iProperties.Value("Custom", "Kategorie") = sValue

---

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Super!

Vielen Dank für die schnelle und kompetente Hilfe! 

------------------
Gruß Georg 

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP