---

Guten Morgen ich suche ein gutes dwf Exporttool. Leider finde ich dies nicht im FX Plot oder im mum Inventor muötitools. Nur genau diese Kombination, von "Baugruppendruck" und als dwf exportieren suche ich.

Wir haben nun vieles getestet.

- 3D-pdf kann keine grossen Baugruppen sinnvoll händeln
- direktviewer von step, kann auch keine grossen Baugruppen händeln
- Edrawing ist nicht so der Burner und es gibt hier nur eine versteckte Zeichnung/3D Modell in einer Datei.
- Inventorview - da muss man irgendwie ein Pack&Go machen.

Bei Export habe ich nun Fx Plot, Multitools oder Designassi. die 1. beiden können kein dwf exportieren und der Designassi kann kein Baugruppendruck.

Also welches Tool kann Baugruppedruck mit pdf, step und dwr durchführen?

herzlichen Dank Sascha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Was genau verstehst du bitte unter Baugruppendruck?

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ich denke mal
- idw ausdrucken als PDF
- Step-Export
- DWF-Export.

Da fällt mir in dieser Zusammenstellung nur die DIVA ein, erweitert mit einem VBA-Makro, das den Vorgang automatisiert  

------------------
Der vernünftige Mensch paßt sich der Welt an;
der unvernünftige besteht auf dem Versuch, die Welt sich anzupassen.

Deshalb hängt aller Fortschritt vom unvernünftigen Menschen ab.
(George Bernard Shaw)

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von rkauskh:
Was genau verstehst du bitte unter Baugruppendruck?

---

du öffnest eine Baugruppe und du startest den Druck z.B. mit FX64 oder Multitool, dann werde alle Unterbauteile auf allen Ebenen angeschaut wo es eine dazugehörige idw gibt. Von allen idws, werden nun die pdfs, dwfs, dxfs und von den verknüpften Elmenten das step erzeugt.

mhm Charly, das wäre natürlich richtig geil. Dafür würde ich auch auf den Baugruppendruck verzichten. 

herzlich Sascha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Grundsätzlich geht das per Makro. Je nach Größe der Baugruppe kann das aber ein echter Langläufer werden. Da ist dann einiges an Aufwand nötig, um den Fall abzudecken, das etwas schief geht.
Die drei Funktionen die Charly Setter genannt hat, findest du mit hoher Wahrscheinlichkeit einzeln schon fertig im VBA-Forum. Einfach mal nach Export oder PDF Druck suchen. Für jedes noch einen Button erstellen oder ein kleines Makro das die drei der Reihe nach aufruft.

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

vielleicht findet sich etwas passendes im AppStore von Autodesk
z.B. Drawing Porter (ich kenne das nicht, die Beschreibung liest sich nur halbwegs passend)

------------------
Gruß KraBBy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von freierfall:
Bei Export habe ich nun Fx Plot, Multitools oder Designassi. die 1. beiden können kein dwf exportieren [...]

---

Fx Plot kann kein DWF? aus der Beschreibung

Zitat:

---

FX64 Plot provides converter functions for PDF, TIFF, JPEG, DXF, DWG, DWF and various neutral CAD formats.

---

------------------
Gruß KraBBy

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

- fx64 plot konnte damals kein dwf, aber ist echt schon lange her, dass ich dies mir installiert habe. Da fehlte mir schon damals der dwf exporter. Also auf der Webseite vom Igor sieht man bei den Bilder kein dwf, dass geht dann immer noch nicht.

- der Drawing porter kann kein dwf.

ich werde mich da erst Mal im vba Bereich umschauen   und wer noch einen Tipp hat immer her damit. herzlich Sascha

[Diese Nachricht wurde von freierfall am 23. Feb. 2021 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Ich hab dir quick'n dirty was zusammengeschrieben. In meinem sehr einfachen Test hat's funktioniert. Die Optionen der einzelnen Exporte werden vermutlich noch nicht passen. Es fehlen so ziemlich alle Plausiprüfungen und Fehlerbehandlungen und es gibt sicher eine Reihe Sonderfälle die nicht funktionieren.

Code:

---

Option Explicit

Const strIniFile = "C:\TEMP\dxf_2018.ini" '<-------- GGF. ANPASSEN !!!!!!!!!!!

Private Sub MultiExport()

    Dim oApp As Inventor.Application
    Set oApp = ThisApplication
   
    If (oApp.Documents.Count = 0) Or Not (oApp.ActiveDocument.DocumentType = kAssemblyDocumentObject) Then
        Call MsgBox("Funktion nur in Baugruppen möglich. Abbruch", vbCritical)
        Exit Sub
    End If
   
    Dim oAssDoc As AssemblyDocument
    Set oAssDoc = oApp.ActiveDocument
   
    Dim oRefedDocs As DocumentsEnumerator
    Set oRefedDocs = oAssDoc.AllReferencedDocuments
   
    Dim oRefedDoc As Document
    Dim sFilename As String
    Dim oDrawDoc As DrawingDocument
   
    sFilename = GetFullFileName(oAssDoc)
        Set oDrawDoc = HasDrawing(oAssDoc, sFilename)
       
        If Not oDrawDoc Is Nothing Then
            Call PublishPDF(oDrawDoc, sFilename)
            Call PublishDWF(oDrawDoc, sFilename)
            Call PublishDXF(oDrawDoc, sFilename)
            oDrawDoc.Close (True)
        End If
        Call ExportToSTEP(oAssDoc, sFilename)
       
       
    For Each oRefedDoc In oRefedDocs
        sFilename = GetFullFileName(oRefedDoc)
        Set oDrawDoc = HasDrawing(oRefedDoc, sFilename)
        If Not oDrawDoc Is Nothing Then
            Call PublishPDF(oDrawDoc, sFilename)
            Call PublishDWF(oDrawDoc, sFilename)
            Call PublishDXF(oDrawDoc, sFilename)
            oDrawDoc.Close (True)
        End If
        Call ExportToSTEP(oRefedDoc, sFilename)
    Next

End Sub

Private Function GetFullFileName(ByVal oDoc As Document) As String

    Dim sFullfilename As String
    sFullfilename = oDoc.FullDocumentName
   
    GetFullFileName = Left(sFullfilename, Len(sFullfilename) - 4)
   
End Function

Private Function HasDrawing(ByVal oDoc As Document, ByVal sFilename As String) As DrawingDocument
    On Error Resume Next
   
    Dim oApp As Inventor.Application
    Set oApp = ThisApplication
   
    Set HasDrawing = oApp.Documents.Open(sFilename & ".idw")
   
End Function

Private Sub PublishDWF(ByVal oDoc As Document, ByVal sFilename As String)

    Dim DWFAddIn As TranslatorAddIn
    Set DWFAddIn = ThisApplication.ApplicationAddIns.ItemById("{0AC6FD95-2F4D-42CE-8BE0-8AEA580399E4}")

    Dim oContext As TranslationContext
    Set oContext = ThisApplication.TransientObjects.CreateTranslationContext
    oContext.Type = kFileBrowseIOMechanism

    Dim oOptions As NameValueMap
    Set oOptions = ThisApplication.TransientObjects.CreateNameValueMap

    Dim oDataMedium As DataMedium
    Set oDataMedium = ThisApplication.TransientObjects.CreateDataMedium

    If DWFAddIn.HasSaveCopyAsOptions(oDoc, oContext, oOptions) Then
        oOptions.Value("Launch_Viewer") = 0
        If TypeOf oDocument Is DrawingDocument Then
            oOptions.Value("Publish_Mode") = kCustomDWFPublish
            oOptions.Value("Publish_All_Sheets") = 1
        End If
    End If
   
    oDataMedium.FileName = sFilename & ".dwf"
    Call DWFAddIn.SaveCopyAs(oDoc, oContext, oOptions, oDataMedium)
End Sub

Private Sub PublishDXF(ByVal oDoc As Document, ByVal sFilename As String)

    Dim DXFAddIn As TranslatorAddIn
    Set DXFAddIn = ThisApplication.ApplicationAddIns.ItemById("{C24E3AC4-122E-11D5-8E91-0010B541CD80}")

    Dim oContext As TranslationContext
    Set oContext = ThisApplication.TransientObjects.CreateTranslationContext
    oContext.Type = kFileBrowseIOMechanism

    Dim oOptions As NameValueMap
    Set oOptions = ThisApplication.TransientObjects.CreateNameValueMap

    Dim oDataMedium As DataMedium
    Set oDataMedium = ThisApplication.TransientObjects.CreateDataMedium

    If DXFAddIn.HasSaveCopyAsOptions(oDoc, oContext, oOptions) Then
        oOptions.Value("Export_Acad_IniFile") = strIniFile
    End If

    oDataMedium.FileName = sFilename & ".dxf"
    Call DXFAddIn.SaveCopyAs(oDoc, oContext, oOptions, oDataMedium)
End Sub

Private Sub PublishPDF(ByVal oDoc As Document, ByVal sFilename As String)
   
    Dim PDFAddIn As TranslatorAddIn
    Set PDFAddIn = ThisApplication.ApplicationAddIns.ItemById("{0AC6FD96-2F4D-42CE-8BE0-8AEA580399E4}")

    Dim oContext As TranslationContext
    Set oContext = ThisApplication.TransientObjects.CreateTranslationContext
    oContext.Type = kFileBrowseIOMechanism

    Dim oOptions As NameValueMap
    Set oOptions = ThisApplication.TransientObjects.CreateNameValueMap

    Dim oDataMedium As DataMedium
    Set oDataMedium = ThisApplication.TransientObjects.CreateDataMedium

    If PDFAddIn.HasSaveCopyAsOptions(oDoc, oContext, oOptions) Then
        oOptions.Value("All_Color_AS_Black") = 0
        oOptions.Value("Launch_Viewer") = False
    End If

    oDataMedium.FileName = sFilename & ".pdf"
    Call PDFAddIn.SaveCopyAs(oDoc, oContext, oOptions, oDataMedium)
End Sub

Private Sub ExportToSTEP(ByVal oDoc As Document, ByVal sFilename As String)

    Dim oSTEPTranslator As TranslatorAddIn
    Set oSTEPTranslator = ThisApplication.ApplicationAddIns.ItemById("{90AF7F40-0C01-11D5-8E83-0010B541CD80}")

    If oSTEPTranslator Is Nothing Then
        MsgBox "Could not access STEP translator."
        Exit Sub
    End If

    Dim oContext As TranslationContext
    Set oContext = ThisApplication.TransientObjects.CreateTranslationContext
    Dim oOptions As NameValueMap
    Set oOptions = ThisApplication.TransientObjects.CreateNameValueMap
    If oSTEPTranslator.HasSaveCopyAsOptions(oDoc, oContext, oOptions) Then
        oOptions.Value("ApplicationProtocolType") = 3
        oContext.Type = kFileBrowseIOMechanism

        Dim oData As DataMedium
        Set oData = ThisApplication.TransientObjects.CreateDataMedium
        oData.FileName = sFilename & ".stp"

        Call oSTEPTranslator.SaveCopyAs(oDoc, oContext, oOptions, oData)
    End If
End Sub

---

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Sascha schau mal da :

https://www.mum.de/produkte/mum-multitool-for-inventor

ob das passt

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Cool danke, ja das Multitool nutze ich nun seit einem Jahr nur kann das auch kein dwf. Leider ist es auch nicht auf 4K angepasst.

das für das script, ich werde ich am Wochenende mal testen.  top

herzliche Grüsse Sascha

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,
ich würde mir mal das kostenlose Tool MakroBatch von JürgenWagner ansehen.
Mit den entsprechenden Makros kann man eine Dateiliste in einem Rutsch in die entsprechenden Formate konvertieren. Man braucht natürlich für jedes Format ein eigenes Makro bzw. eine Funktion.
Gruß
Burkhard

Zitat:

---

Original erstellt von Charly Setter:
Ich denke mal
- idw ausdrucken als PDF
- Step-Export
- DWF-Export.

Da fällt mir in dieser Zusammenstellung nur die DIVA ein, erweitert mit einem VBA-Makro, das den Vorgang automatisiert   

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP