---

Ich arbeite in einem Team. Ein anderer Mitarbeiter hat eine große Baugruppe erstellt, in der die Masseeinheit auf kg steht. Alle anderen haben aber g angegeben. Wie kann man die Einheit umstellen, ohne alle Teile einzeln aufzurufen. Gibt es eine Art Tabellenansicht einer Gesammtbaugruppe, in der ich die Einheiten für alle Bauteile ändern kann?

------------------
Gerne,
Volker

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Volker,

wenn Du die baugruppe geöffnet hast, dann steht unter Extra, Dokumenteneinstellung, Einheiten auch die Masse. Stellt Du dort auf Gramm um, dann wird Dir die Masse bei physikalische Eigenschaften in Gramm angezeigt.

Gruß, Uwe

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Probier's mal damit. In der Baugruppe aufgerufen, ändert es auch alle darin verbauten Teile.

Public Sub SetActiveDocUnits()
Dim oActiveDocument As Inventor.Document
Set oActiveDocument = ThisApplication.ActiveDocument
SetUnitsToMetric oActiveDocument
End Sub

Private Sub SetUnitsToMetric(Document As Inventor.Document)
'Get Units of Measure
Dim oUOM As Inventor.UnitsOfMeasure
Set oUOM = Document.UnitsOfMeasure
'Set length units to Metric and save
oUOM.LengthUnits = kMillimeterLengthUnits
oUOM.MassUnits = kGramMassUnits
oUOM.AngleUnits = kDegreeAngleUnits
Document.Dirty = True
Document.Update
Document.Save

'Run recursively for assembly
If TypeOf Document Is Inventor.AssemblyDocument Then
Dim oAssemblyDocument As Inventor.AssemblyDocument
Set oAssemblyDocument = Document
Dim oOccurrence As Inventor.ComponentOccurrence
For Each oOccurrence In oAssemblyDocument.ComponentDefinition.Occurrences
SetUnitsToMetric oOccurrence.Definition.Document
Next oOccurrence
End If
End Sub

Public Sub SetScaleOnParameters()
    Dim partDoc As PartDocument
    Set partDoc = ThisApplication.ActiveDocument
    Dim partDef As PartComponentDefinition
    Set partDef = partDoc.ComponentDefinition
   
    Dim modelParam As ModelParameter
    For Each modelParam In partDef.Parameters.ModelParameters
        ' Check to see that this parameter defines a distance.
        If partDoc.UnitsOfMeasure.CompatibleUnits("1", modelParam.Units, "1", "in") Then
            ' Change the expression to include scale.
            modelParam.Expression = modelParam.Expression & " * Scale"
        End If
    Next
End Sub

[Diese Nachricht wurde von W. Holzwarth am 21. Mai. 2015 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke Holzwarth, für die schnelle Antwort.
Wie rufe ich das auf? Wie kann ich das in unterschiedlichen Baugruppen anwenden?

------------------
Gerne,
Volker

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Danke Uwe,

aber ich brauche das Gewicht für alle Bauteile auch in der Stückliste in g. Wenn ich die Stückliste in alllen Ebenen aufliste, erscheinen die Unterbaugruppen und die darin enthaltenen Teile in kg.

------------------
Gerne,
Volker

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Zitat:

---

Original erstellt von MultipleCADuser:
Wie rufe ich das auf? Wie kann ich das in unterschiedlichen Baugruppen anwenden?

---

- Neue Baugruppe erstellen
- Extras -> VBA-Editor (bei Optionen)
- ApplicationProject (Default.ivb) aufklappen
- Unter Module Modul1 aufklappen (Falls nicht vorhanden, Rechtsmaus auf Module->Einfügen->Modul)
- Kopierten Text dort einfügen
- Datei -> Schließen und zurück ..
- Nun eine kleine Test-BG öffnen
- In Baugruppe Extras -> Makros (bei Optionen)->Makros in: ApplicationProject(Default.ivb)->SetActiveDocUnits wählen->Ausführen

Je nach Baugruppengröße kann es dann etwas dauern, deshalb zuerst mal mit einfacher BG probieren.

P.S.: Makro SetScaleonParameters ist eigentlich nicht nötig. Dadurch kann man alle Längenmaße mit einem festen Wert skalieren, wenn in den Bauteilparametern ein Benutzerparameter Scale (z.B. 1,0 ohne Einheit) definiert ist. Scale=2 macht's dann doppelt so groß. Starten dieses Makros ohne Scale-Definition gibt Laufzeitfehler.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hey, hat super geklappt. Spwohl bei der kleinen als auch bei der großen Baugruppe.
Vielen Dank!

------------------
Gerne,
Volker

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP