---

Hallo!

ich bin neu hier und starte mit folgender Frage:
Zur Kalkulation von Schnittkosten benötige ich die Summe aller Konturlängen eines Blechbauteils. Durch die Forensuche bin ich bei einem Beitrag namens "Physikalische Eigenschaften in Parameterliste benutzen" auf die Lösung gestoßen. Dort wurde ein VBA-Skript gepostet, welches genau das tun sollte, was ich mir vorstelle. (Skript von daywa1k3r):

Code:

---

Public Sub Kontur()
    Dim oPart As PartDocument
    Dim oFace As Face
    Dim oThicknessParam As Parameter
    Dim oSheetMetalCompDef As SheetMetalComponentDefinition
   
    Dim dArea As Double
    Dim dVolume As Double
    Dim dThickness As Double
    Dim dContour As Double
    ' Aktives Dokument holen
    Set oPart = ThisApplication.ActiveDocument
   
    dArea = 0
   
    For Each oFace In oPart.ComponentDefinition.SurfaceBodies(1).Faces
        ' Gesamtfläche berechnen
        dArea = dArea + oFace.Evaluator.Area
    Next
   
    'Volumen berechnen
    dVolume = oPart.ComponentDefinition.SurfaceBodies(1).Volume(0.01)

    Set oSheetMetalCompDef = oPart.ComponentDefinition
    Set oThicknessParam = oSheetMetalCompDef.ActiveSheetMetalStyle.Thickness
   
    ' Blechstärke berechnen
    dThickness = oThicknessParam.ModelValue
   
    ' Kontur berechnen
    dContour = (dArea - (2 * (dVolume / dThickness))) / dThickness
   
    MsgBox ("Fläche: " & dArea & vbCrLf & _
            "Volumen: " & dVolume & vbCrLf & _
            "Blechstärke: " & dThickness & vbCrLf & vbCrLf & _
            "Kontur: " & dContour)
End Sub

---

Leider scheint das aus 2006 stammende Skript mit meiner Inventor-Version (Professional 2015) nicht zu funktionieren. Bei "Set oThicknessParam = oSheetMetalCompDef.ActiveSheetMetalStyle.Thickness"
kommt im VBA-Editor eine Fehlermeldung "Typen unverträglich".
Kann mir jemand dabei helfen, das Skript zum Laufen zu bringen? Ich bin leider nicht so sehr bewandert wenn es um VBA geht..

Vielen Dank im voraus,

Nicola

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

- Inhaltsloser Beitrag -

---

Hallo Jürgen,

vielen Dank für die schnelle Antwort. Das Skript hatte ich auch schon gesehen und getestet, aber bei abgewickelten Blechteilen rechnet es fehlerhaft, wahrscheinlich da die Oberfläche des Teils dann in mehrere Flächen aufgeteilt wird (die man dann auch alle selektieren muss).

Die im alten Beitrag angegebene (ziemlich elegante) Formel greift nur auf Gesamtoberfläche, Volumen und Blechstärke zu, da muss ich nichts selektieren und das Ergebnis passt immer.

Grüße,

Nicola

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

- Inhaltsloser Beitrag -

---

Zitat:

---

Original erstellt von VORTEX59:
Mögliche Lösung:...

---

Hast Du eigentlich gelesen, worum es hier geht?

Oder hattest Du nur wieder Zeit zuviel? 

------------------
Roland  
www.Das-Entwicklungsbuero.de

It's not the hammer - it's the way you hit!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo.

Ich habe zwar keine Ahnung mehr von der neueren Inventor-API, aber hier, in dem unteren Thread, scheint dasselbe Problem gelöst worden zu sein:

http://www.mcadforums.com/forums/viewtopic.php?f=15&t=10689

Ohne Gewehr, Torsten

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Guten Morgen!

Es war nur eine Kleinigkeit - das Objektmodel wurde seitens Autodesk ein wenig geändert.

Code:

---

' Das Makro gibt Fläche, Volumen, Blechstärke und Konturlänge
' eines Blechteils aus. Die Kontur wird nicht über die Summe
' von einzelnen Kanten, sondern mittels Formel berechnen
' (dArea - (2 * (dVolume / dThickness))) / dThickness

' FX64 daywa1k3r, Igor Zupevc, 25.01.2015 >> 2x0, 2x1, 2x2 und 2x5 -> hübsch :) <<

Public Sub BlechteilParameter()
    Dim oPart As PartDocument
    Dim oFace As Face
    Dim oThicknessParam As Parameter
    Dim oSheetMetalCompDef As SheetMetalComponentDefinition
   
    Dim dArea As Double
    Dim dVolume As Double
    Dim dThickness As Double
    Dim dContour As Double
    ' Aktives Dokument holen
    Set oPart = ThisApplication.ActiveDocument
   
    dArea = 0
   
    For Each oFace In oPart.ComponentDefinition.SurfaceBodies(1).Faces
        ' Gesamtfläche berechnen
        dArea = dArea + oFace.Evaluator.Area
    Next
   
    'Volumen berechnen
    dVolume = oPart.ComponentDefinition.SurfaceBodies(1).Volume(0.01)

    Set oSheetMetalCompDef = oPart.ComponentDefinition
    Set oThicknessParam = oSheetMetalCompDef.Thickness
   
    ' Blechstärke berechnen
    dThickness = oThicknessParam.ModelValue
   
    ' Kontur berechnen
    dContour = (dArea - (2 * (dVolume / dThickness))) / dThickness
   
    MsgBox ("Fläche:" & vbTab & vbTab & Round(dArea, 2) & " cm^2" & vbCrLf & _
            "Volumen:" & vbTab & vbTab & Round(dVolume, 2) & " cm^3" & vbCrLf & _
            "Blechstärke:" & vbTab & Round(dThickness, 2) & " cm" & vbCrLf & vbCrLf & _
            "Konturlänge:" & vbTab & Round(dContour, 2) & " cm")
End Sub

---

------------------
Grüße Igor

FX64 Software Solutions - Inventor Tools
FX64 LambdaSpect - Lichtsimulation mit Autodesk Inventor

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Guten Morgen allerseits!

Vielen Dank an alle für die schnelle und freundliche Hilfe und speziell an Igor, das aktualisierte Skript funktioniert perfekt!

Viele Grüße und eine schöne Woche,

Nicola

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Weiss jemand wie man das Makro umstellt dass am schluss mm rauskommen? Ist im VBA gar nicht so einfach wenn man das ned beherscht :-)

Danke

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

bin zwar kein Experte, aber ich würde einfach in den Berechungen mit der entsprechenden 10er Potenz multiplizieren und in der Ausgabe statt "cm" "mm" schreiben

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP