---

Hallo

gibt es die Möglichkeit in der Baugruppe die Werte aus der I-Propertie "geschätzte Kosten" der Einzelteile mit der entsprechenden Stückzahl zu multiplizieren und dann alle Ergebnisse zusammenzuzählen?
Kurz gesagt, kann Inventor den Gesamtpreis aller verbauten Teile einer Baugruppe ausgeben?

Josef

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

soweit ich weiß nicht...
aber das VBA script das ich geschrieben habe kann das 

kann sein das man bei LOD auf Hauptansicht umschalten muss

Code:

---

Public auflistung As String

Sub BG_Kosten_berechnen()
   
    wert = 0
    auflistung = ""
   
    ' Stüli ansprechen
    Dim oBOM As BOM
    Set oBOM = ThisApplication.ActiveDocument.ComponentDefinition.BOM

    ' ansicht einstellen
    Dim oBOMView As BOMView
    Set oBOMView = oBOM.BOMViews.Item(1) '"Strukturiert")
   
    'funktion aufrufen und in iproperties schreiben
    wert = KOSTEN(oBOMView.BOMRows, True)
   
    ThisApplication.ActiveDocument.PropertySets.Item("Design Tracking Properties").Item("Cost").Value = wert
   
    MsgBox "Kosten: " & wert & vbCrLf & vbCrLf & "Auflistung Baugruppenkosten:" & vbCrLf & auflistung

End Sub

Function KOSTEN(ebene, OG As Boolean)
    KOSTEN = 0
    For i = 1 To ebene.Count 'diese ebene bei alle bauteile durchlaufen
        Dim mehr
        mehr = 0
        Dim oRow As BOMRow
        Set oRow = ebene.Item(i)
       
        'zugriff auf spezielle iproperties ermöglichen
        Dim oPropSet As PropertySet
        Set oPropSet = oRow.ComponentDefinitions.Item(1).Document.PropertySets.Item("Design Tracking Properties")
         
        If oRow.ChildRows Is Nothing And oRow.ReferencedFileDescriptor Is Nothing Then 'virtuele /nicht gespeicherte bauteile filtern
           
        ElseIf oRow.ChildRows Is Nothing Then 'wenn es keine Gruppe ist, dann Preis addieren (multipliziert mit der stückzahl)
            mehr = oPropSet.Item("Cost").Value * oRow.ItemQuantity
            'auflistung = auflistung + oPropSet.Item(2).Value + vbTab + CStr(mehr) + " €" + vbCrLf
           
        Else ' ansonsten die Untergruppe mit dieser Funktion (kosten) nochmals durchlaufen
            mehr = KOSTEN(oRow.ChildRows, False) * oRow.ItemQuantity
            If OG = True Then auflistung = auflistung + CStr(mehr) + " €" + vbTab + oPropSet.Item("Description").Value + vbCrLf
        End If
        KOSTEN = KOSTEN + mehr
    Next
End Function

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo Fons,

ziemlich cooles Makro. Super Überblick, falls man die Kosten pflegt..

Mir ist aufgefallen, dass es bisher für Schweiß-BGs nicht funktioniert:
Alle Baugruppen aus Blechteilen, die wir fertig geschweißt bestellen, sind nicht als Schweiß-BG ausgeführt, sondern normale Baugruppen. Die Baugruppen werden aber als UNTEILBAR definiert, da sie ja als einzelnes Bauteil bestellt werden. Somit haben sie auch nur einen Preis der BG.
Wenn ich nun den Preis der unteilbaren BG definiere, wird er nicht beachtet, sondern stattdessen die Summe der Preise der Einzelteile (alle 0,00€) berücksichtigt.

Wie handhabt ihr Schweiß-BGs?
Hier vielleicht noch ein € einfügen(?)

Code:

---

'funktion aufrufen und in iproperties schreiben
    wert = KOSTEN(oBOMView.BOMRows, True)
   
    ThisApplication.ActiveDocument.PropertySets.Item("Design Tracking Properties").Item("Cost").Value = wert
   
    MsgBox "Kosten: " & wert & " €" &vbCrLf & vbCrLf & "Auflistung Baugruppenkosten:" & vbCrLf & auflistung

---

Schönen Sonntag noch...

------------------
Gruß Roland

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Dann mußt du dir die BOMRow.BOMStructure Eigenschaft ansehen und bei Baugruppen die unteilbar (oder gekauft?) sind, statt in die Rekursion zu springen den BG-Preis hernehmen.

Code:

---

ElseIf oRow.BOMStructure=51974 Then 'wenn es eine unteilbare Gruppe ist, dann Preis addieren (multipliziert mit der stückzahl)
mehr = oPropSet.Item("Cost").Value * oRow.ItemQuantity
'auflistung = auflistung + oPropSet.Item(2).Value + vbTab + CStr(mehr) + " €" + vbCrLf

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

(fast)genau was ich suche ...

... kann das für Virtuelle Teile erweitert werden?

Viele Grüße
Martin

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

ACHTUNG! Sie antworten auf einen Beitrag der älter als 1 Jahr ist!

...Ja weiß ich doch...

Wie bekomme ich das in meine Baugruppe?

Gruß, Axel

------------------
In übereinstimmung mit der Prophezeiung!

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP