---

Hi, wir haben das Problem, dass es Kollegen gibt, die zum Feierabend immer vergessen, lokal abgelegte Dateien ins PDM einzuchecken.
Nun haben wir aber Kurzarbeit und dann kann es passieren, dass der Kollege tagelang nicht im Haus ist und niemand an diese Dateien ran kommt.
Kann man irgendwie verhindern, dass Dateien lokal abgelegt werden? Oder erzwingen, dass sie eingecheckt werden?

------------------
Kein Mensch ist so beschäftigt, dass er nicht die Zeit hätte, jedem zu erzählen, wie beschäftig er ist.

SWX 2020 SP2 / PDM Professional
Office 2019
Windows 10 Pro 64 bit
Dell Precision T3600
Intel Xeon E5
16 Gb RAM
NVIDIA Quadro P2200
Space Pilot Pro

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Verhindern: Nein
Spontan fällt mir nur ein VB.NET Programm ein, welches nach ausgecheckten Dateien im Tresor sucht und diese eincheckt. Das Programm müsste dann beim Logoff des angemeldeten Benutzers ausgeführt werden:

https://www.matthias-staud.de/2019/05/scripts-beim-starten-herunterfahren-oder-an-und-abmeldung-von-windows-ausfuehren/

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Ab und an schafft unser Konvertierungs-Rechner es nicht die Sekundärformate ein zu checken. Damit ich das nicht von Hand machen muss, habe ich jetzt ein VB.NET-Programm geschrieben, welches genau das erledigt:

Code:

---

Imports EdmLib
Module Module1
    Sub main()
        Dim oVault As IEdmVault21
        oVault = New EdmVault5
        oVault.LoginAuto("PDM", 0)
        Dim objBenutzer As IEdmUserMgr10
        objBenutzer = oVault.CreateUtility(EdmUtility.EdmUtil_UserMgr)
        Dim sBenutzer As IEdmUser10
        sBenutzer = objBenutzer.GetLoggedInUser
        Dim Benutzer As String = sBenutzer.Name
        Console.WriteLine(Benutzer)
        Dim search As IEdmSearch9
        search = oVault.CreateSearch2()
        search.Clear()
        search.FindFolders = False
        search.FindFiles = True
        search.Recursive = True
        search.SetToken(EdmSearchToken.Edmstok_Locked, True)
        search.SetToken(EdmSearchToken.Edmstok_LockedBy, Benutzer)
        Dim result As IEdmSearchResult5
        result = search.GetFirstResult

        Dim sFiles() As EdmSelItem = Nothing
        Dim fileCount As Integer = 0

        While result IsNot Nothing
            Dim swModelPath As String = result.Path
            Console.WriteLine(swModelPath)
            Array.Resize(sFiles, fileCount + 1)
            sFiles(fileCount) = New EdmSelItem
            sFiles(fileCount).mlDocID = result.ID
            sFiles(fileCount).mlProjID = result.ParentFolderID
            fileCount += 1
            result = search.GetNextResult
        End While
        If sFiles IsNot Nothing Then
            Dim ConHand As Integer = Process.GetCurrentProcess().MainWindowHandle
            Dim batchUnlocker As IEdmBatchUnlock2
            batchUnlocker = oVault.CreateUtility(EdmUtility.EdmUtil_BatchUnlock)
            Try
                batchUnlocker.AddSelection(oVault, sFiles)
                Dim bRet As Integer = 0
                bRet = batchUnlocker.CreateTree(ConHand, EdmUnlockBuildTreeFlags.Eubtf_NoCallbackDlgErrors)
                If Not bRet Then
                    Console.WriteLine("Einchecken fehl geschlagen")
                    Exit Sub
                End If
                batchUnlocker.AddSelection(oVault, sFiles)
                batchUnlocker.UnlockFiles(ConHand)
            Catch ex As System.Runtime.InteropServices.COMException
                Console.WriteLine("HRESULT = 0x" + ex.ErrorCode.ToString("X") + " " + ex.Message)
            Catch ex As Exception
                Console.WriteLine(ex.Message)
                Exit Sub
            End Try
        End If
    End Sub
End Module

---

[Diese Nachricht wurde von riesi am 01. Feb. 2021 editiert.]

[Diese Nachricht wurde von riesi am 01. Feb. 2021 editiert.]

[Diese Nachricht wurde von riesi am 01. Feb. 2021 editiert.]

[Diese Nachricht wurde von riesi am 01. Feb. 2021 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP