---

Hallo,

ich erzeuge mit VBA neue Layouts und möchte diese gleich richtig einrichten.
Da es ja nun zu Problemen kommt wenn ich ein CanonicalMediaName zuweisen möchte
das es bei dem eingestellten Plotter nicht gibt versuche ich das zu umgehen.
Ich frage also erst alle verfügberen Drucker ab und schreib die in eine Liste
in ein Userform sodass der Benutzer erstmal einen Drucker auswählen muss.
Nun das Problem:
Ich möchte jetzt die verfügbaren CanonicalMediaName's nur für diesen ausgewählten Drucker
in einer neuen Auswahlliste anzeige oder weiter untersuchen ob das von mir gewünschte Format verfügbar ist.
Ich kann irgendwie nur alle verfügbaren formate für alle Drucker auslesen.

Wie bekomme ich die Formate für den ausgewählten Drucker?

Danke
Andreas

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

1.aktives Layout ermitteln
2.Drucker und Paper des aktiven Layout merken
3.zu untersuchenden Drucker im aktiven Layout setzen
4.RefreshPlotDeviceInfo fürs aktive Layout aufrufen
5.Medianames mit GetCanonicalMediaNames auswerten
6.für jedes Medianame
-Papiername mit GetLocaleMediaName auslesen
  mit RefreshPlotDeviceInfo System refreshen
-Papiergröße mit GetPaperSize auslesen
7.Einstellungen aus 2. zurückspeichern
fertig

------------------
  - Thomas -
"Bei 99% aller Probleme ist die umfassende Beschreibung des Problems bereits mehr als die Hälfte der Lösung desselben."

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Vielen Dank.
Hat funktioniert.
Ich habe es halt so gelöst dass ich temporär ein neues Layout anlege
die Einstellungen abfrage und das Layout wieder lösche.

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Kannst ja mal deinen code für den nächsten suchenden posten.

------------------
  - Thomas -
"Bei 99% aller Probleme ist die umfassende Beschreibung des Problems bereits mehr als die Hälfte der Lösung desselben."

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Klar gerne.
Ich wähle einen anderen Plotter aus der Combobox in meinem Formular
dann werden in der Combobox für verfügbare Papiergrössen die Einträge erstellt:

Code:

---

Private Sub cbo_plotters_Change()
 
Dim Layout As AcadLayout
Dim ACADPref As AcadPreferencesDisplay
Dim originalCreateViewport As Variant, newCreateViewport As Variant
Dim originalShowPlotSetup As Variant, newShowPlotSetup As Variant
Dim mediaNames As Variant
   
    ' in den Papierbereich wechseln
    ThisDrawing.ActiveSpace = acPaperSpace

    ' Combobox leeren
    frm_RahmenWahl.cbo_papier.Clear

    ' unterdrückt automatisches Anlegen eines Ansichtsfensters
    ' und die Anzeige des Plotsetups für neues Ansichtsfenster
    ' Wert wird zum Schluss wieder auf vorher eingestellten zurückgesetzt

    ' derzeitige Werte Preferences.Display auslesen
    Set ACADPref = ThisDrawing.Application.Preferences.Display
    originalCreateViewport = ACADPref.LayoutCreateViewport
    originalShowPlotSetup = ACADPref.LayoutShowPlotSetup
   
    ' neue Werte setzen
    ACADPref.LayoutCreateViewport = False
    ' unterdrückt automatisches Anlegen eines Ansichtsfensters
    newCreateViewport = ACADPref.LayoutCreateViewport
   
    ACADPref.LayoutShowPlotSetup = False
    ' unterdrückt Anzeige des Plotsetupdialogs für neues Ansichtsfenster
    newShowPlotSetup = ACADPref.LayoutShowPlotSetup

    'neues Layout anlegen und Format zuordnen
    ThisDrawing.Layouts.Add ("kanngeloeschtwerden")
    ThisDrawing.ActiveLayout = ThisDrawing.Layouts.Item("kanngeloeschtwerden")
   
    'Plottername von Auswahldialog zuweisen
    Set Layout = ThisDrawing.ActiveLayout
    Layout.ConfigName = cbo_plotters.Text
   
    ' Mediennamen auslesen und in Combobox eintragen
    mediaNames = Layout.GetCanonicalMediaNames()
    For x = LBound(mediaNames) To UBound(mediaNames)
        cbo_papier.AddItem mediaNames(x)
    Next
   
    ' in den Modellbereich wechseln
    ThisDrawing.ActiveSpace = acModelSpace

    ' LayoutCreateViewport auf originalwert zurücksetzen
    ACADPref.LayoutCreateViewport = originalCreateViewport
    ACADPref.LayoutShowPlotSetup = originalShowPlotSetup

    ' Layout wieder löschen
    Call modRahmen.SearchDelLayoutName("kanngeloeschtwerden")

End Sub

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP