---

Hallo,

gibt es die Möglichkeit über ein Makro die Detailgenauigkeit in allen Baugruppen und Unterbaugruppen auf Hauptansicht zu stellen?

Danke

Grüße Thomas

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Ich kann mich jetzt falsch erinnern, aber stellt nicht das Aktivieren der Hauptansicht in der Baugruppe alle Unterbaugruppen automatisch auf Hauptansicht? Wobei das natürlich nur auf das jeweilige Exemplar der Unterbaugruppe in der Baugruppe Einfluss hat. Die zuletzt aktive Detailgenauigkeit der Unterbaugruppe beim Speichern wird dadurch nicht verändert.

Was genau möchtest du denn bezwecken?

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Modellbaum.JPG

Hallo Ralf,

du hast Recht, ich habe das gerade probiert wenn ich in der obersten Baugruppe die Hauptansicht auswähle wird in den Unterbaugruppen auch die Hauptansicht ausgewählt (das ist schonmal sehr gut).

Ich habe eine Makro wo in die Kategorie von jeder Unterbaugruppe und Bauteil eine Zuordnung eingetragen wird. Wenn eine Konturvereinfachung erstellt wurde und aktiviert wurde kann nicht auf die enthaltenen Bauteile zugriffen werden.

Ist es möglich zu prüfen das in der obersten Baugruppe die Hauptansicht eingestellt wurde bzw. wenn nicht eingestellt wird?

Danke, und Grüße Thomas

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

Das sollte so gehen. Du könntest in deinem anderen Makro am Anfang ein "Call ActivateMainDesignViewRep" einfügen, um das Makro von dort aufzurufen.

Code:

---

Private Sub ActivateMainLOD()

Dim oApp As Inventor.Application
Set oApp = ThisApplication

If oApp.Documents.Count = 0 Then
    MsgBox "geöffnete Baugruppendatei erforderlich.", vbCritical
    Exit Sub
End If

If Not oApp.ActiveDocumentType = kAssemblyDocumentObject Then
    MsgBox "geöffnete Baugruppendatei erforderlich.", vbCritical
    Exit Sub
End If

Dim oAssDoc As AssemblyDocument
Set oAssDoc = oApp.ActiveDocument

Dim oCompDef As AssemblyComponentDefinition
Set oCompDef = oAssDoc.ComponentDefinition

Dim oRepMngr As RepresentationsManager
Set oRepMngr = oCompDef.RepresentationsManager

If Not oRepMngr.ActiveLevelOfDetailRepresentation.Name = "Hauptansicht" Then
    oRepMngr.LevelOfDetailRepresentations.Item("Hauptansicht").Activate
End If

End Sub

---

Alternativ kannst du in deinem Makro unterhalb von "Set oAssDoc = oApp.ActiveDocument" mit

Code:

---

If ActivateMainLOD(oAssDoc) = False Then
        MsgBox "Aktivieren der Detailgenauigkeit Hauptansicht fehlgeschlagen." & vbCrLf & "Bitte manuell prüfen.", vbCritical
        Exit Sub
    End If

---

eine Funktion aufrufen, die dir ermöglicht auf ein fehlgeschlagenes Aktivieren der Hauptansicht zu reagieren.

Code:

---

Private Function ActivateMainLOD(ByVal oAssDoc As AssemblyDocument) As Boolean

On Error GoTo Fail

Dim oCompDef As AssemblyComponentDefinition
Set oCompDef = oAssDoc.ComponentDefinition

Dim oRepMngr As RepresentationsManager
Set oRepMngr = oCompDef.RepresentationsManager

If Not oRepMngr.ActiveLevelOfDetailRepresentation.Name = "Hauptansicht" Then
    oRepMngr.LevelOfDetailRepresentations.Item("Hauptansicht").Activate
End If

ActivateMainLOD = True
Exit Function

Fail:
ActivateMainLOD = False

End Function

---

------------------
MfG
Ralf

RKW Solutions GmbH
www.RKW-Solutions.com

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,
Hauptansicht setzen (vorher fragen unnötig - es sei denn, du willst nach der Operation die Detailgenauigkeit (LOD) wieder zurücksetzen):

Code:

---

Call ThisApplication.ActiveDocument.ComponentDefinition.RepresentationsManager.LevelOfDetailRepresentations.Item(1).Activate

---

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

@ Ralf: ich habe den Cod probiert, funktioniert, vielen Dank
@ bkrüger: probiere ich morgen aus, vielen Dank

Grüße Thomas

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP