---

Hallo vba-ler,

gerne würde ich in einer idw eine vorhandene Revisionstabelle mit den Revisionsbezeichnungen löschen....

Also die Tabelle lösche ich mit

Code:

---

        If oDrawDoc.ActiveSheet.RevisionTables.count > 0 Then
            Call oDrawDoc.ActiveSheet.RevisionTables.Item(1).Delete
        End If

---

nur die Revisionsbezeichnungen bleiben noch Zeichnung.

Wie kann ich die alle löschen?

Danke für einen Tipp,
Stefan

------------------
IV2008

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Meines Wissens gibt es bis einschließlich Inventor 2014 keine API für Revisionsbezeichnungen. Mir ist kein Weg bekannt (außer anklicken und Entf drücken) die zu löschen.

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo,

man kann meines Wissens auf die Symbole bzw. Revisionsbezeichnungen mittels API nicht direkt zugreifen. Irgendwo in der Programmierungshilfe steht jedoch, dass Revisionsbezeichnungen mit der Revisionstabelle (mit den Zeilen der Revisionstabelle um genau zu sein) verknüpft sind. Man sollte also zuerst jede Zeile einzeln entfernen. Die mit jeweiliger Zeile referenzierte Revisionssymbole werden mitgelöscht. Da die aktive Zeile nicht gelöscht werden kann, sollte logischerweise zuvor eine "leere" hinzugefügt werden (diese ist dann automatisch aktiv, hat keine Referenzen und bleibt bis zum Schluss). Erst danach kann die Revisionstabelle gelöscht werden.

Folgendes funktioniert unter 2014:

Code:

---

Option Explicit

Public Sub Revision_entfernen()

    '' Referenz zur .idw
    Dim Zeichnung As DrawingDocument
    Set Zeichnung = ThisApplication.ActiveDocument
   
    '' Referenz zum Blatt.
    Dim Blatt As Sheet
    Set Blatt = Zeichnung.ActiveSheet
   
    '' Referenz zur Rev.-iProperty.
    Dim RevProp As Property
    Set RevProp = Zeichnung.PropertySets("{F29F85E0-4FF9-1068-AB91-08002B27B3D9}").ItemByPropId(9)
   
    '' Revision aus iProperties entfernen.
    If RevProp.Expression <> "" Then: RevProp.Expression = ""
     
    '' Rückgängig-Funktion.
    Dim Undo As Inventor.Transaction
    Set Undo = ThisApplication.TransactionManager.StartTransaction(Zeichnung, "Revision löschen.")
   
    On Error GoTo ErrHndl
   
    '' Referenz zur Revisionstabelle.
    Dim RevTab As RevisionTable
    If Blatt.RevisionTables.Count > 0 Then
        Set RevTab = Blatt.RevisionTables(1)
    '' Tabelle erzeugen, falls nicht vorhanden.
    ElseIf Blatt.RevisionTables.Count = 0 Then
        Dim einfuegeP As Point2d
        Set einfuegeP = ThisApplication.TransientGeometry.CreatePoint2d(0, 0)
        Set RevTab = Blatt.RevisionTables.Add(einfuegeP)
    End If

    '' Alle Zeilen in der Rev.-Tabelle löschen.
    RevTab.RevisionTableRows.Add '' <- Diese zeile hat kein referenziertes Revisionssymbol und wird mit der Rev.-Tabelle gelöscht!
    Dim TabellenZeile As RevisionTableRow
    For Each TabellenZeile In RevTab.RevisionTableRows
        If Not TabellenZeile.IsActiveRow Then TabellenZeile.Delete
    Next
   
    '' Rev.-Tabelle löschen.
    RevTab.Delete

ErrHndl:    '' Bei Fehlschlag wird Undo abgebrochen.
    If Err.Number <> 0 Then
        Undo.Abort
        Call MsgBox("Fehler!" & vbNewLine & Err.Number, vbOKOnly Or vbCritical)
    Else
        Undo.End
    End If

End Sub

---

------------------
alexander

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP