---

Hallo zusammen,

ich möchte gerne per VBA die Koordinaten von einem Arbeitspunkt in einer Baugruppe heraus bestimmen. So wie wenn ich auf messen gehe und dann den Arbeitspunkt anklicke, erscheinen die x,y,z-Koordinaten.
Folgendes Problem habe zurzeit. Der Arbeitspunkt befindent sich in einem Bauteil, welches in der Baugruppe plaziert ist. Ich kann per VBA auf den Arbeitspunkt zureifen und Koordinaten ermitteln:

Code:

---

dim oPunkt as Workpoint
Set oPunkt = oPart.Definition.WorkPoints(2)
x = oPunkt.Point.x
y = oPunkt.Point.y
z = oPunkt.Point.z

---

Allerdings werden die Koordinaten immer nur zum Koordinatensystem des Bauteil angezeigt und nicht von der Baugruppe. Das Bauteil ist mehrmals verbaut aber an verschiedenen Positionen, berechne ich mir aber nun die Koordinate des Punktes mit dem gezeigten Code kommt immer der gleiche Wert heraus.

Gibt es eine Möglichkeit die Koordinate zum Baugruppen-Koordinatensystem berechnen zu lassen? habe schon verucht die Matrix des Bauteils auszulesen und die Koordinaten vom Punkt umzurechenen funktioniert aber leider nicht.

Hoffe jemand weiß Rat.....

Gruss Dennis

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo

Die Lösung heißt WorkPointProxy. In der Baugruppenumgebung wird dein Arbeitspunkt durch ein ProxyObjekt dargestellt. Du mußt also hier das Proxyobjekt greifen und nicht ins Bauteil gehen (wo es kein Baugruppenkoordinatensystem gibt/geben kann) und den WorkPoint greifen.
Wie selektierst du die Punkte?

EDIT:

Code:

---

Private Sub WP_Koords()

Dim oDoc As AssemblyDocument
Set oDoc = ThisApplication.ActiveDocument

Dim oCompOcc As ComponentOccurrence
Set oCompOcc = oDoc.ComponentDefinition.Occurrences.Item(1)

Dim oPartCompDef As PartComponentDefinition
Set oPartCompDef = oCompOcc.Definition

Dim oWP As WorkPoint
Set oWP = oPartCompDef.WorkPoints.Item(2)

Dim oWPProxy As WorkPointProxy
oCompOcc.CreateGeometryProxy oWP, oWPProxy

Debug.Print oWP.Point.X
Debug.Print oWP.Point.Y
Debug.Print oWP.Point.Z

Debug.Print oWPProxy.Point.X
Debug.Print oWPProxy.Point.Y
Debug.Print oWPProxy.Point.Z

End Sub

---

Für das Beispiel eine BG mit einem Bauteil und darin einen Arbeitspunkt setzen. Im Direktfenster kannste dann die unterschiedlichen Koordinaten sehen.
------------------
MfG
RK

[Diese Nachricht wurde von rkauskh am 23. Okt. 2009 editiert.]

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Hallo RK,

vielen Dank für deine Hilfe, dein Code macht genau das was ich brauche. SUPER!!

Gruss Dennis

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP