---

24-07-2025_14-31-02.jpg

Hallo, ist es möglich, in einer Ebene die platzierten iFeatures automatisch mit Namen(Benannte Objekte)zu versehen?
Sowohl in der IPT- als auch in der DWG-Datei können die Namen manuell vergeben werden.
Die Abfrage funktioniert hervorragend, sobald die Namen einmal vergeben sind.
Der Hintergrund meiner Frage ist erneut die automatische Platzierung der Bemaßung.
Gruß Bernd

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP

---

Moin

An ein iFeature kann kein Name gehangen werden, du musst eine der erzeugten Flächen/Kanten/Vertex benutzen.
Wenn du das iFeature mit iFeatures.Add gerade erzeugt hast, kannst du das zurückgegebene Objekt auch als Argument an eine Funktion übergeben. Dann muss nicht wie im Beispiel das letzte iFeature in der Liste geholt werden und der Code kürzt sich auf die Hälfte. Welche Fläche du nimmst und wie die Namenskonvention aussieht, deine Entscheidung.

Code:

---

Option Explicit

Private Sub AddNamedGeometry()
    Const iLogicAddinGuid As String = "{3BDD8D79-2179-4B11-8A5A-257B1C0263AC}"

    Dim oPartDoc As PartDocument
    Set oPartDoc = ThisApplication.ActiveDocument

    Dim oCompDef As PartComponentDefinition
    Set oCompDef = oPartDoc.ComponentDefinition
   
    Dim oFeats As PartFeatures
    Set oFeats = oCompDef.Features
   
    Dim oiFeats As iFeatures
    Set oiFeats = oFeats.iFeatures
       
    Dim oiFeat As iFeature
    Set oiFeat = oiFeats.Item(oiFeats.Count)
   
    Dim oFace As Face
    Set oFace = oiFeat.Faces.Item(1)
   
    Dim oAddin As ApplicationAddIn
    Set oAddin = ThisApplication.ApplicationAddIns.ItemById(iLogicAddinGuid)

    Dim iLogicAuto As Object
    Set iLogicAuto = oAddin.Automation

    Dim oNamedEntities As Object
    Set oNamedEntities = iLogicAuto.GetNamedEntities(oPartDoc)

    Call oNamedEntities.SetName(oFace, oiFeat.Name & "_Face")
End Sub

---

------------------
MfG
Ralf

Eine Antwort auf diesen Beitrag verfassen (mit Zitat/Zitat des Beitrags) IP